code.vuplus.com Git - vuplus_openembedded/blob - recipes/mc/mc.inc

   1 DESCRIPTION = "GNU Midnight Commander is a file \
   2 manager for free operating systems."
   3 HOMEPAGE = "http://www.ibiblio.org/mc/"
   4 LICENSE = "GPLv2"
   5 SECTION = "console/utils"
   6 PRIORITY = "optional"
   7 DEPENDS = "ncurses glib-2.0 glib-2.0-native"
   8 #RDEPENDS = "ncurses-terminfo"
   9
  10 SRC_URI = "http://www.ibiblio.org/pub/Linux/utils/file/managers/mc/mc-${PV}.tar.gz"
  11
  12 inherit autotools
  13
  14 EXTRA_OECONF = "--disable-glibtest --without-x --without-samba \
  15 --without-nfs --without-gpm-mouse --with-screen=ncurses \
  16 ac_cv_path_PERL=${bindir}/perl \
  17 ac_cv_path_ZIP=${bindir}/zip \
  18 ac_cv_path_UNZIP=${bindir}/unzip \
  19 "
  20
  21 PACKAGES += "${PN}-extfs ${PN}-hilite"
  22 FILES_${PN} = "${bindir}/ ${libexecdir}/mc ${datadir}/mc/*.charsets ${datadir}/mc/*.ext ${datadir}/mc/*.hint ${datadir}/mc/*.hlp ${datadir}/mc/*.lib ${datadir}/mc/*.menu ${datadir}/mc/*.rc ${datadir}/mc/bin /etc/profile.d"
  23 FILES_${PN}-extfs = "${datadir}/mc/extfs/"
  24 FILES_${PN}-hilite = "${datadir}/mc/syntax/"
  25 FILES_${PN}-dbg += "${libexecdir}/mc/.debug"
  26 RRECOMMENDS_${PN} += "${PN}-extfs ${PN}-hilite"
  27 RDEPENDS_${PN}-extfs = "${PN}"
  28 RDEPENDS_${PN}-hilite = "${PN}"
  29 PACKAGE_ARCH_${PN}-extfs = "all"
  30 PACKAGE_ARCH_${PN}-hilite = "all"
  31
  32 export CC_FOR_BUILD = "${BUILD_CC}"
  33 export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
  34 export LD_FOR_BUILD = "${BUILD_CC}"
  35 do_compile_prepend() {
  36         export GLIB_CFLAGS_FOR_BUILD="`${STAGING_BINDIR_NATIVE}/pkg-config --cflags glib-2.0`"
  37         export GLIB_LIBS_FOR_BUILD="`${STAGING_BINDIR_NATIVE}/pkg-config --libs glib-2.0`"
  38 }
  39
  40 do_install_append() {
  41         if test -f ${D}${datadir}/mc/bin/mc.sh ; then
  42                 mkdir -p ${D}/etc/profile.d
  43                 mv ${D}${datadir}/mc/bin/mc.*sh ${D}/etc/profile.d
  44         fi
  45 }
  46
  47 python populate_packages_prepend () {
  48         mcdir   = bb.data.expand('${datadir}/mc', d)
  49         do_split_packages(d, mcdir, '^mc\.[hm][ile][npn].*\.(.*)$',
  50                 output_pattern='mc-locale-%s',
  51                 description='%s translation for mc')
  52 }