code.vuplus.com Git - vuplus_openembedded/blob - recipes/mc/mc.inc

   1 DESCRIPTION = "GNU Midnight Commander is a file \
   2 manager for free operating systems."
   3 HOMEPAGE = "http://www.ibiblio.org/mc/"
   4 LICENSE = "GPLv2"
   5 SECTION = "console/utils"
   6 PRIORITY = "optional"
   7 DEPENDS = "ncurses glib-2.0 glib-2.0-native"
   8 #RDEPENDS = "ncurses-terminfo"
   9
  10 SRC_URI = "http://www.ibiblio.org/pub/Linux/utils/file/managers/mc/mc-${PV}.tar.gz"
  11
  12 inherit autotools gettext
  13
  14 EXTRA_OECONF = "--disable-glibtest --without-x --without-samba \
  15 --without-nfs --without-gpm-mouse --with-screen=ncurses \
  16 ac_cv_path_PERL=${bindir}/perl \
  17 ac_cv_path_ZIP=${bindir}/zip \
  18 ac_cv_path_UNZIP=${bindir}/unzip \
  19 "
  20 EXTRA_OEMAKE = 'GLIB_CFLAGS_FOR_BUILD="$GLIB_CFLAGS_FOR_BUILD" GLIB_LIBS_FOR_BUILD="$GLIB_LIBS_FOR_BUILD" CC_FOR_BUILD="$CC_FOR_BUILD"'
  21
  22 PACKAGES += "${PN}-extfs ${PN}-hilite"
  23 FILES_${PN} = "${bindir}/ ${libexecdir}/mc ${datadir}/mc/*.charsets ${datadir}/mc/*.ext ${datadir}/mc/*.hint ${datadir}/mc/*.hlp ${datadir}/mc/*.lib ${datadir}/mc/*.menu ${datadir}/mc/*.rc ${datadir}/mc/bin /etc/profile.d"
  24 FILES_${PN}-extfs = "${datadir}/mc/extfs/"
  25 FILES_${PN}-hilite = "${datadir}/mc/syntax/"
  26 FILES_${PN}-dbg += "${libexecdir}/mc/.debug"
  27 RRECOMMENDS_${PN} += "${PN}-extfs ${PN}-hilite"
  28 RDEPENDS_${PN}-extfs = "${PN}"
  29 RDEPENDS_${PN}-hilite = "${PN}"
  30 PACKAGE_ARCH_${PN}-extfs = "all"
  31 PACKAGE_ARCH_${PN}-hilite = "all"
  32
  33 export CC_FOR_BUILD = "${BUILD_CC}"
  34 export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
  35 export LD_FOR_BUILD = "${BUILD_CC}"
  36 do_compile_prepend() {
  37         # FIXME: Ugly! Should be done globally with respect to the host system (in classes) instead of NATIVE_PKGCONFIG_PATH:
  38         export HOST_PKG_CONFIG_PATH=
  39         export GLIB_CFLAGS_FOR_BUILD="`PKG_CONFIG_PATH="$HOST_PKG_CONFIG_PATH" PKG_CONFIG_SYSROOT_DIR="" pkg-config --cflags glib-2.0`"
  40         export GLIB_LIBS_FOR_BUILD="`PKG_CONFIG_PATH="$HOST_PKG_CONFIG_PATH" PKG_CONFIG_SYSROOT_DIR="" pkg-config --libs glib-2.0`"
  41 }
  42
  43 do_install_append() {
  44         if test -f ${D}${datadir}/mc/bin/mc.sh ; then
  45                 mkdir -p ${D}/etc/profile.d
  46                 mv ${D}${datadir}/mc/bin/mc.*sh ${D}/etc/profile.d
  47         fi
  48 }
  49
  50 do_install_append_opendreambox() {
  51         rm -R ${D}/etc/profile.d
  52 }
  53
  54 do_install_append_vuplus() {
  55         rm -R ${D}/etc/profile.d
  56 }
  57
  58 python populate_packages_prepend () {
  59         mcdir   = bb.data.expand('${datadir}/mc', d)
  60         do_split_packages(d, mcdir, '^mc\.[hm][ile][npn].*\.(.*)$',
  61                 output_pattern='mc-locale-%s',
  62                 description='%s translation for mc')
  63 }