code.vuplus.com Git - vuplus_openembedded/blob - recipes/matchbox-keyboard/matchbox-keyboard-inputmethod_svn.bb

   1 DESCRIPTION = "Matchbox virtual keyboard for X11"
   2 LICENSE = "GPL"
   3 DEPENDS = "libfakekey expat libxft gtk+ matchbox-panel-2"
   4 RCONFLICTS_${PN} = "matchbox-keyboard"
   5 RPROVIDES_${PN} = "matchbox-keyboard"
   6 SECTION = "x11"
   7 PV = "0.0+svnr${SRCPV}"
   8 PR = "r10"
   9
  10 SRC_URI = "svn://svn.o-hand.com/repos/matchbox/trunk;module=matchbox-keyboard;proto=http \
  11             file://smallscreen-fontsize.patch;patch=1 \
  12         file://2-Add-new-modifier--layout--Used-to-cycle-thru-all-available-layouts.patch;patch=1 \
  13         file://3-Changes-to-improve-layout-rendering--especially-after-adding-support-for.patch;patch=1 \
  14         file://4-Add-rendering-debug-logging.patch;patch=1 \
  15         file://5-Add-support-for-loading-multiple-independent-layouts.patch;patch=1 \
  16         file://6-Add-layout-switch-key-to-all-layouts.patch;patch=1 \
  17             file://80matchboxkeyboard"
  18
  19 SRC_URI_append_om-gta01 = " file://fic-gta01-font-size.patch;patch=1"
  20 SRC_URI_append_om-gta02 = " file://fic-gta01-font-size.patch;patch=1"
  21
  22 S = "${WORKDIR}/matchbox-keyboard"
  23
  24 inherit autotools pkgconfig gettext
  25
  26 EXTRA_OECONF = "--disable-cairo --enable-gtk-im --enable-applet"
  27
  28 PACKAGES += "matchbox-keyboard-im matchbox-keyboard-im-dbg \
  29              matchbox-keyboard-applet matchbox-keyboard-applet-dbg"
  30
  31 FILES_${PN} = "${bindir}/* \
  32                ${sysconfdir} \
  33                ${datadir}/applications \
  34                ${datadir}/pixmaps \
  35                ${datadir}/matchbox-keyboard"
  36
  37 FILES_matchbox-keyboard-im = "${libdir}/gtk-2.0/*/immodules/*.so"
  38 FILES_matchbox-keyboard-im-dbg += "${libdir}/gtk-2.0/*/immodules/.debug"
  39
  40 FILES_matchbox-keyboard-applet = "${libdir}/matchbox-panel/*.so"
  41 FILES_matchbox-keyboard-applet-dbg += "${libdir}/matchbox-panel/.debug"
  42
  43 do_install_append () {
  44         install -d ${D}/${sysconfdir}/X11/Xsession.d/
  45         install -m 755 ${WORKDIR}/80matchboxkeyboard ${D}/${sysconfdir}/X11/Xsession.d/
  46 }
  47
  48 pkg_postinst_matchbox-keyboard-im () {
  49 if [ "x$D" != "x" ]; then
  50   exit 1
  51 fi
  52
  53 gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules
  54 }
  55
  56 pkg_postrm_matchbox-keyboard-im () {
  57 if [ "x$D" != "x" ]; then
  58   exit 1
  59 fi
  60
  61 gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules
  62 }