code.vuplus.com Git - vuplus_openembedded/blob - recipes/lirc/lirc_0.8.1+cvs20070307.bb

   1 DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls."
   2 DESCRIPTION_append_lirc = " This package contains the lirc daemon, libraries and tools."
   3 DESCRIPTION_append_lirc-x = " This package contains lirc tools for X11."
   4 DESCRIPTION_append_lirc-exec = " This package contains a daemon that runs programs on IR signals."
   5 DESCRIPTION_append_lirc-remotes = " This package contains some config files for remotes."
   6 DESCRIPTION_append_lirc-nslu2example = " This package contains a working config for RC5 remotes and a modified NSLU2."
   7 SECTION = "console/network"
   8 PRIORITY = "optional"
   9 HOMEPAGE = "http://www.lirc.org"
  10 LICENSE = "GPL"
  11 DEPENDS = "virtual/kernel virtual/libx11 libxau libsm libice"
  12 DEPENDS_nslu2 = "virtual/kernel lirc-modules"
  13 RDEPENDS = "lirc-modules"
  14 RDEPENDS_lirc-x = "lirc"
  15 RDEPENDS_lirc-exec = "lirc"
  16 RDEPENDS_lirc-nslu2example = "lirc lirc-exec"
  17 RRECOMMENDS_lirc = "lirc-exec"
  18 PR = "r2"
  19
  20 # enable cvs version since until compilation issues for other packages have been fixed (cf. bug 2284 et al).
  21 #DEFAULT_PREFERENCE = "-1"
  22
  23 SRCDATE=${@bb.data.getVar('PV', d, 1)[9:]}
  24
  25 SRC_URI = "cvs://anonymous@lirc.cvs.sourceforge.net/cvsroot/lirc;module=lirc;method=pserver;cvsdate=${SRCDATE} \
  26            file://lircd.init file://lircmd.init file://lircexec.init"
  27 SRC_URI_append_nslu2 = " file://lircd.conf_nslu2 file://lircrc_nslu2"
  28
  29 S = "${WORKDIR}/lirc"
  30
  31 inherit autotools module-base update-rc.d
  32
  33 INITSCRIPT_PACKAGES = "lirc lirc-exec"
  34 INITSCRIPT_NAME = "lircd"
  35 INITSCRIPT_PARAMS = "defaults 20"
  36 INITSCRIPT_NAME_lirc-exec = "lircexec"
  37 INITSCRIPT_PARAMS_lirc-exec = "defaults 21"
  38
  39 require lirc-config.inc
  40
  41 EXTRA_OEMAKE = 'SUBDIRS="daemons tools"'
  42
  43 do_stage() {
  44         oe_libinstall -so -C tools liblirc_client ${STAGING_LIBDIR}
  45         install -d ${STAGING_INCDIR}/lirc/
  46         install -m 0644 tools/lirc_client.h ${STAGING_INCDIR}/lirc/
  47 }
  48
  49 do_install_append() {
  50         install -d ${D}${sysconfdir}/init.d
  51         install ${WORKDIR}/lircd.init ${D}${sysconfdir}/init.d/lircd
  52         install ${WORKDIR}/lircexec.init ${D}${sysconfdir}/init.d/lircexec
  53         install -d ${D}${datadir}/lirc/
  54         cp -pPR ${S}/remotes ${D}${datadir}/lirc/
  55         rm -rf ${D}/dev
  56 }
  57
  58 do_install_append_nslu2() {
  59         install -d ${D}${sysconfdir}
  60         install ${WORKDIR}/lircd.conf_nslu2 ${D}${sysconfdir}/lircd.conf
  61         install ${WORKDIR}/lircrc_nslu2 ${D}${sysconfdir}/lircrc
  62 }
  63
  64 PACKAGES =+ "lirc-x lirc-exec lirc-remotes"
  65 PACKAGES_prepend_nslu2 = "lirc-nslu2example "
  66
  67 FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug"
  68 FILES_${PN} = "${bindir} ${sbindir} ${libdir}/*.so.* ${sysconfdir}/init.d"
  69 FILES_lirc-x = "${bindir}/irxevent ${bindir}/xmode2"
  70 FILES_lirc-exec = "${bindir}/irexec ${sysconfdir}/init.d/lircexec"
  71 FILES_lirc-remotes = "${datadir}/lirc/remotes"
  72 FILES_lirc-nslu2example = "${sysconfdir}/lircd.conf ${sysconfdir}/lircrc"
  73 CONFFILES_lirc-nslu2example = "${FILES_lirc-nslu2example}"