code.vuplus.com Git - vuplus_openembedded/blob - recipes/lighttpd/lighttpd.inc

   1 DESCRIPTION = "Web server"
   2 SECTION = "net"
   3 LICENSE = "BSD"
   4 DEPENDS = "libpcre"
   5 RDEPENDS_${PN} += " \
   6                     lighttpd-module-access \
   7                     lighttpd-module-accesslog \
   8                     lighttpd-module-indexfile \
   9                     lighttpd-module-dirlisting \
  10                     lighttpd-module-staticfile \
  11                   "
  12
  13 INC_PR = "r7"
  14
  15 SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.gz \
  16            file://index.html \
  17            file://lighttpd.conf \
  18            file://lighttpd \
  19           "
  20
  21 EXTRA_OECONF=" \
  22               --without-bzip2 \
  23               --without-ldap \
  24               --without-lua \
  25               --without-memcache \
  26               --with-pcre \
  27               --without-webdav-props \
  28               --without-webdav-locks \
  29               --without-openssl \
  30               --disable-static \
  31              "
  32
  33 inherit autotools pkgconfig update-rc.d gettext
  34
  35 INITSCRIPT_NAME = "lighttpd"
  36 INITSCRIPT_PARAMS = "defaults 70"
  37
  38 do_install_append() {
  39         install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
  40         install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
  41         install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
  42         install -m 0644 ${WORKDIR}/index.html ${D}/www/pages/
  43 }
  44
  45 do_stage() {
  46         autotools_stage_all
  47 }
  48
  49 FILES_${PN} += "${sysconfdir} /www"
  50
  51 PACKAGES_DYNAMIC = "lighttpd-module-*"
  52
  53 python populate_packages_prepend () {
  54         lighttpd_libdir = bb.data.expand('${libdir}', d)
  55         do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
  56 }