code.vuplus.com Git - vuplus_openembedded/blob - recipes/libopie/libopie2.inc

   1 DESCRIPTION = "Base libraries for the Open Palmtop Integrated Environment"
   2 HOMEPAGE = "http://opie.handhelds.org"
   3 SECTION = "opie/libs"
   4 LICENSE = "LGPL"
   5 I18N_FILES = "libopiecore2.ts libopiesecurity2.ts"
   6 DEPENDS = "libqpe-opie libpcap sqlite3 bluez-libs"
   7 PROVIDES = "libopiecore2 libopiedb2 libopiemm2 libopiesecurity2 libopienet2 libopiepim2 libopieui2"
   8
   9 S = "${WORKDIR}/libopie2"
  10
  11 inherit opie
  12
  13 PARALLEL_MAKE = ""
  14
  15 #FIXME: Add machine specific bits here. Best use oe_machinstall and read from a given file
  16
  17 EXTRA_QMAKEVARS_POST += 'DEFINES+=OPIE_NEW_MALLOC \
  18                         DEFINES+="OPIE_SOUND_FRAGMENT_SHIFT=16" \
  19                         DEFINES+=OPIE_NO_ERASE_RECT_HACKFIX \
  20                         LIBS+=-L${S} LIBS+="-Wl,-rpath-link,${S}"'
  21
  22 ENABLE_SQL_PIM_BACKEND = "y"
  23 # NOTE: Machines with too little amount of flash may want to disable SQL backend support
  24 # (known not to fit in 16MB). Also, XML backend is still used by default, as SQL doesn't
  25 # support sync yet.
  26 #ENABLE_SQL_PIM_BACKEND_smallmachine = "n"
  27 EXTRA_QMAKEVARS_PRE += 'ENABLE_SQL_PIM_BACKEND=${ENABLE_SQL_PIM_BACKEND}'
  28
  29 MODULES = "opiecore opiedb opiemm opienet opiepim opiesecurity opieui opiebluez"
  30 LIBS    = "core2    db2    mm2    net2    pim2    security2    ui2 bluez2"
  31 PRIVATE = "opimcontactsortvector.h opimoccurrence_p.h opimsortvector.h opimtodosortvector.h vobject_p.h opimeventsortvector.h"
  32
  33 # uclibc doesn't have backtrace()
  34 python __anonymous () {
  35     import bb, re
  36     if (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None):
  37         bb.data.setVar("EXTRA_QMAKEVARS_POST_append", " DEFINES+=OPIE_NO_BACKTRACE ", d)
  38 }
  39
  40 do_compile() {
  41         install -d ${STAGING_INCDIR}/opie2
  42         install -d ${STAGING_INCDIR}/opie2/private
  43         for module in ${MODULES}
  44         do
  45             cd $module
  46             for i in `find . -name "*.h"`
  47             do
  48                 install -m 0644 $i ${STAGING_INCDIR}/opie2/`basename $i`
  49             done
  50             cd ..
  51         done
  52
  53         for header in ${PRIVATE}
  54         do
  55                 install -m 0644 opiepim/private/$header ${STAGING_INCDIR}/opie2/private/
  56         done
  57
  58         oe_runmake MOC=${STAGING_BINDIR_NATIVE}/moc UIC=${STAGING_BINDIR_NATIVE}/uic DESTDIR=${S}
  59 }
  60
  61 do_stage() {
  62         for f in ${LIBS}
  63         do
  64                 oe_libinstall -so libopie$f ${STAGING_LIBDIR}/
  65         done
  66         install -m 0644 ${WORKDIR}/include.pro ${OPIEDIR}/include.pro
  67         # special case for uic-created header files
  68         install -m 0644 opiepim/ui/opimrecurrencebase.h ${STAGING_INCDIR}/opie2/
  69         install -m 0644 opieui/otimepickerbase.h ${STAGING_INCDIR}/opie2/
  70         install -m 0644 opiepim/core/opimtemplatebase.h ${STAGING_INCDIR}/opie2/
  71 }
  72
  73 do_install() {
  74         install -d ${D}${libdir}
  75         for f in ${LIBS}
  76         do
  77                 oe_libinstall -so libopie$f ${D}${libdir}
  78         done
  79 }
  80
  81 PACKAGES_prepend = " libopiecore2 libopiedb2 libopiesecurity2 libopiemm2 libopienet2 libopiepim2 libopieui2 libopiebluez2 "
  82
  83 DESCRIPTION_libopiecore2 = "Opie Development Platform 1.x Core Library"
  84 FILES_libopiecore2 = "${libdir}/libopiecore2.so.*"
  85 DESCRIPTION_libopiedb2 = "Opie Development Platform 1.x Database Library"
  86 FILES_libopiedb2 = "${libdir}/libopiedb2.so.*"
  87 DESCRIPTION_libopiemm2 = "Opie Development Platform 1.x Multimedia Library"
  88 FILES_libopiemm2 = "${libdir}/libopiemm2.so.*"
  89 DESCRIPTION_libopienet2 = "Opie Development Platform 1.x Network Library"
  90 FILES_libopienet2 = "${libdir}/libopienet2.so.*"
  91 DESCRIPTION_libopiepim2 = "Opie Development Platform 1.x PIM Library"
  92 FILES_libopiepim2 = "${libdir}/libopiepim2.so.*"
  93 DESCRIPTION_libopieui2 = "Opie Development Platform 1.x User Interface Library"
  94 FILES_libopieui2 = "${libdir}/libopieui2.so.*"
  95 DESCRIPTION_libopiesecurity2 = "Opie Development Platform 1.x Security Library"
  96 FILES_libopiesecurity2 = "${libdir}/libopiesecurity2.so.*"
  97 DESCRIPTION_libopiebluez2 = "Opie Development Platform 1.x Bluetooth Library"
  98 FILES_libopiebluez2 = "${libdir}/libopiebluez2.so.*"
  99