code.vuplus.com Git - vuplus_openembedded/blob - recipes/kexecboot/linux-kexecboot.inc

   1 # We set PR here, since a change in the kexecboot recipe will need to get picked up by *all* the kernels:
   2 PR = "r12"
   3
   4 SRC_URI = "file://defconfig"
   5
   6 LOGO_SIZE = '${@base_conditional("GUI_MACHINE_CLASS", "bigscreen", "vga", "qvga", d)}'
   7 SRC_URI += "file://${LOGO_SIZE}/logo_linux_clut224.ppm.bz2"
   8
   9 require recipes/linux/linux.inc
  10
  11 DONT_CHECK_KERNELSIZE = ""
  12 INITRAMFS_IMAGE = "initramfs-kexecboot-image"
  13
  14 CMDLINE = "console=ttyS0,115200n8 console=tty1"
  15 CMDLINE_poodle = "console=ttyS0,115200n8 console=tty1 fbcon=rotate:1"
  16 CMDLINE_akita = "console=ttyS0,115200n8 console=tty1 fbcon=rotate:1"
  17 CMDLINE_collie = "console=ttySA0,115200n8 console=tty1 mem=64M fbcon=rotate:1"
  18 CMDLINE_spitz = "console=ttyS0,115200n8 console=tty1 fbcon=rotate:1"
  19 CMDLINE_hx4700 = "console=ttyS0,115200n8 console=tty1 fbcon=rotate:1"
  20
  21 PACKAGES = ""
  22 PROVIDES = ""
  23
  24 DOSRC = "http://www.do13.de/openzaurus/patches"
  25 JLSRC = "http://www.cs.wisc.edu/~lenz/zaurus/files"
  26 BASRC = "http://www.orca.cx/zaurus/patches"
  27 CHSRC = "http://oz.drigon.com/patches"
  28 TKSRC = "http://www.informatik.hu-berlin.de/~tkunze/zaurus/patches"
  29
  30 KERNEL_IMAGE_BASE_NAME = "${KERNEL_IMAGETYPE}-kexecboot-${PV}-${PR}-${MACHINE}"
  31 KERNEL_IMAGE_SYMLINK_NAME = "${KERNEL_IMAGETYPE}-kexecboot-${MACHINE}"
  32
  33 do_configure[depends] += "${INITRAMFS_IMAGE}:do_rootfs"
  34
  35 do_configure_append() {
  36 sed -i -e /CONFIG_BLK_DEV_INITRD/d \
  37        -e /CONFIG_INITRAMFS_SOURCE/d \
  38        -e /=m/d \
  39        -e /CONFIG_MODULES/d \
  40        -e /CONFIG_DEBUG_ERRORS/d \
  41        -e /CONFIG_DEBUG_BUGVERBOSE/d \
  42        -e /CONFIG_DEBUG_KERNEL/d \
  43        ${S}/.config
  44
  45 # Remove last tag appended by linux.inc (output messes screen)
  46 sed -i -e /CONFIG_CMDLINE/s/quiet/loglevel=3/1 ${S}/.config
  47 sed -i -e /CONFIG_CMDLINE/s/debug/loglevel=3/1 ${S}/.config
  48
  49 echo 'CONFIG_BLK_DEV_INITRD=y
  50 CONFIG_INITRAMFS_SOURCE="initramfs.cpio.gz"
  51 CONFIG_MODULES=n' >> ${S}/.config
  52
  53         yes '' | oe_runmake oldconfig
  54 }
  55
  56 do_stage() {
  57 }
  58
  59 do_install() {
  60 }
  61
  62 python do_package() {
  63 }