code.vuplus.com Git - vuplus_openembedded/blob - recipes/initscripts/initscripts-opendreambox_1.0.bb

   1 DESCRIPTION = "SysV init scripts (stripped) for opendreambox"
   2 MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
   3 SECTION = "base"
   4 PRIORITY = "required"
   5 PROVIDES = "initscripts"
   6 RPROVIDES_${PN} = "initscripts"
   7 LICENSE = "GPL"
   8 PR = "r29"
   9
  10 FILESPATHPKG = "initscripts-${PV}:initscripts:files"
  11 PACKAGE_ARCH = "${MACHINE_ARCH}"
  12
  13 BOOTUP_dm7025 = "${@base_contains('PREFERRED_VERSION_linux-dm7025', '2.6.12.6', 'bootup_old', 'bootup', d)}"
  14 BOOTUP ?= "bootup"
  15
  16 SRC_URI = "file://halt \
  17            file://umountfs \
  18            file://devpts.sh \
  19            file://devpts \
  20            file://reboot \
  21            file://single \
  22            file://sendsigs \
  23            file://rmnologin \
  24            file://umountnfs.sh \
  25            file://sysfs.sh \
  26            file://netmount.sh \
  27            file://var.tar.gz.default \
  28            file://${BOOTUP}"
  29
  30 SRC_URI_append_dm8000 = " file://fscking.raw"
  31
  32 do_install () {
  33 #
  34 # Create directories and install device independent scripts
  35 #
  36         install -d ${D}${sysconfdir}/init.d
  37         install -d ${D}${sysconfdir}/rcS.d
  38         install -d ${D}${sysconfdir}/rc0.d
  39         install -d ${D}${sysconfdir}/rc1.d
  40         install -d ${D}${sysconfdir}/rc2.d
  41         install -d ${D}${sysconfdir}/rc3.d
  42         install -d ${D}${sysconfdir}/rc4.d
  43         install -d ${D}${sysconfdir}/rc5.d
  44         install -d ${D}${sysconfdir}/rc6.d
  45         install -d ${D}${sysconfdir}/default
  46         install -d ${D}${sysconfdir}/default/volatiles
  47
  48         install -m 0755    ${WORKDIR}/halt              ${D}${sysconfdir}/init.d
  49         install -m 0755    ${WORKDIR}/reboot            ${D}${sysconfdir}/init.d
  50         install -m 0755    ${WORKDIR}/rmnologin         ${D}${sysconfdir}/init.d
  51         install -m 0755    ${WORKDIR}/sendsigs          ${D}${sysconfdir}/init.d
  52         install -m 0755    ${WORKDIR}/single            ${D}${sysconfdir}/init.d
  53         install -m 0755    ${WORKDIR}/devpts.sh         ${D}${sysconfdir}/init.d
  54         install -m 0755    ${WORKDIR}/devpts            ${D}${sysconfdir}/default
  55         install -m 0755    ${WORKDIR}/sysfs.sh          ${D}${sysconfdir}/init.d
  56         install -m 0755    ${WORKDIR}/${BOOTUP}         ${D}${sysconfdir}/init.d/bootup
  57         install -m 0755    ${WORKDIR}/var.tar.gz.default ${D}${sysconfdir}/var.tar.gz
  58 #
  59 # Install device dependent scripts
  60 #
  61         if [ "${MACHINE}" = "dm600pvr" -o "${MACHINE}" = "dm500plus" ]; then
  62                 head -n 4 ${WORKDIR}/umountfs > ${D}${sysconfdir}/init.d/umountfs
  63                 echo "cd /tmp" >> ${D}${sysconfdir}/init.d/umountfs
  64                 tail -n 14 ${WORKDIR}/umountfs >> ${D}${sysconfdir}/init.d/umountfs
  65                 chmod 0755 ${D}${sysconfdir}/init.d/umountfs
  66                 ln -sf /usr/bin/showshutdownpic ${D}${sysconfdir}/rc0.d/S89showshutdownpic
  67         else
  68                 install -m 0755 ${WORKDIR}/umountfs     ${D}${sysconfdir}/init.d/umountfs
  69                 install -d ${D}${sysconfdir}/network/if-up.d
  70                 install -m 0755 ${WORKDIR}/netmount.sh  ${D}${sysconfdir}/network/if-up.d/02netmount
  71                 install -d ${D}${sysconfdir}/network/if-down.d
  72                 install -m 0755 ${WORKDIR}/umountnfs.sh ${D}${sysconfdir}/network/if-down.d/02umountnfs
  73         fi
  74
  75         if [ "${MACHINE}" = "dm8000" ]; then
  76                 install -m 0755 ${WORKDIR}/fscking.raw ${D}${sysconfdir}/
  77         fi
  78
  79         #hack for non working "passwd" call when no /etc/shadow exist
  80         echo "[ -f /etc/shadow ] && /bin/true || touch /etc/shadow" >> ${D}${sysconfdir}/init.d/bootup
  81
  82 #
  83 # Create runlevel links
  84 #
  85         ln -sf          ../init.d/rmnologin     ${D}${sysconfdir}/rc2.d/S99rmnologin
  86         ln -sf          ../init.d/rmnologin     ${D}${sysconfdir}/rc3.d/S99rmnologin
  87         ln -sf          ../init.d/rmnologin     ${D}${sysconfdir}/rc4.d/S99rmnologin
  88         ln -sf          ../init.d/rmnologin     ${D}${sysconfdir}/rc5.d/S99rmnologin
  89         ln -sf          ../init.d/sendsigs      ${D}${sysconfdir}/rc6.d/S20sendsigs
  90         ln -sf          ../init.d/umountfs      ${D}${sysconfdir}/rc6.d/S40umountfs
  91         ln -sf          ../init.d/reboot        ${D}${sysconfdir}/rc6.d/S90reboot
  92         ln -sf          ../init.d/sendsigs      ${D}${sysconfdir}/rc0.d/S20sendsigs
  93         ln -sf          ../init.d/umountfs      ${D}${sysconfdir}/rc0.d/S40umountfs
  94         ln -sf          ../init.d/halt          ${D}${sysconfdir}/rc0.d/S90halt
  95         # udev will run at S03 if installed
  96         ln -sf          ../init.d/sysfs.sh      ${D}${sysconfdir}/rcS.d/S02sysfs
  97         ln -sf          ../init.d/devpts.sh     ${D}${sysconfdir}/rcS.d/S38devpts.sh
  98         ln -sf          ../init.d/bootup        ${D}${sysconfdir}/rcS.d/S04bootup
  99 }