code.vuplus.com Git - vuplus_openembedded/blob - recipes/images/gpe-image.bb

   1 LICENSE = "MIT"
   2
   3 # Set some defaults
   4
   5 MACHINE_TASK_PROVIDER = "task-base-extended"
   6 GUI_MACHINE_CLASS ?= "none"
   7 XSERVER ?= "xserver-kdrive-fbdev"
   8 GPE_EXTRA_THEMES = "gpe-theme-industrial"
   9
  10 # Select bootsplash
  11 SPLASH ?= ' ${@base_contains("MACHINE_FEATURES", "screen", "psplash-angstrom", "",d)}'
  12
  13 # Select some useful things depending on the device capabilities
  14
  15 GPE_EXTRA_INSTALL_none = ""
  16 GPE_EXTRA_INSTALL_bigscreen = "task-gpe-games ${GPE_EXTRA_THEMES}"
  17 GPE_EXTRA_INSTALL_smallscreen = "task-gpe-games ${GPE_EXTRA_THEMES}"
  18
  19 GPE_EXTRA_INSTALL += "${GPE_EXTRA_INSTALL_${GUI_MACHINE_CLASS}}"
  20
  21 #ship more stuff with devices with >16MB of flash
  22 GPE_BIGFLASH_INSTALL := '${@base_conditional("ROOT_FLASH_SIZE", "16", "", "\
  23     task-gpe-connectivity \
  24     gpe-theme-clearlooks \
  25     figment \
  26 ",d)}'
  27
  28 GPE_EXTRA_INSTALL += "${GPE_BIGFLASH_INSTALL}"
  29
  30
  31 DEPENDS = "${MACHINE_TASK_PROVIDER} \
  32            ${SPLASH} \
  33            task-gpe-base \
  34            task-gpe-apps \
  35            task-gpe-pim \
  36            task-gpe-settings \
  37            task-gpe-games \
  38            virtual/xserver"
  39
  40 IMAGE_INSTALL = "\
  41     ${MACHINE_TASK_PROVIDER} \
  42     task-gpe-base \
  43     task-gpe-pim \
  44     task-gpe-settings \
  45     task-gpe-apps \
  46     ${XSERVER} \
  47     ${SPLASH} \
  48     ${GPE_EXTRA_INSTALL}"
  49
  50 ROOTFS_POSTPROCESS_COMMAND += '${@base_conditional("DISTRO_TYPE", "release", "zap_root_password; ", "",d)}'
  51 ROOTFS_POSTPROCESS_COMMAND += '${@base_conditional("DISTRO_TYPE", "demo", "set_image_autologin; ", "",d)}'
  52
  53 inherit image