code.vuplus.com Git - vuplus_openembedded/blob - recipes/gpephone/gpe-session-scripts-phone_0.67.bb

   1 inherit gpe
   2
   3 DESCRIPTION = "GPE session startup scripts hack for GPE Phone Edition"
   4 LICENSE = "GPL"
   5 SECTION = "gpe"
   6 PRIORITY = "optional"
   7 RDEPENDS_${PN} = "gpe-applauncher gpe-phonepanel gpe-session-starter gpe-question xmodmap xdpyinfo xserver-common esd esd-utils"
   8 DEPENDS = "matchbox-wm gpe-applauncher gpe-phonepanel gpe-question xmodmap xdpyinfo xserver-common esound"
   9
  10 SRC_URI = "${GPE_MIRROR}/gpe-session-scripts-${PV}.tar.gz \
  11            file://matchbox-session \
  12            file://matchbox-session.vm \
  13            file://phonesession \
  14            file://disable-composite.xsettings \
  15            file://standard-apps.patch;patch=1"
  16
  17 PR = "r10"
  18
  19 S = "${WORKDIR}/gpe-session-scripts-${PV}"
  20
  21
  22 # We assume that x86 means we are building an emulation image
  23 do_install_append() {
  24         install -d ${D}${sysconfdir}/gpe/xsettings-default.d
  25         if [ "${GUI_MACHINE_CLASS}" != "bigscreen" ]; then
  26                 echo "Gtk/ToolbarStyle:S:icons" > ${D}${sysconfdir}/gpe/xsettings-default.d/toolbar
  27         fi
  28         install -d ${D}${sysconfdir}/matchbox
  29         install ${WORKDIR}/matchbox-session ${D}${sysconfdir}/matchbox/session
  30
  31         install -d ${D}${sysconfdir}/gpe/xsettings-default.d
  32         install -m 0644 ${WORKDIR}/disable-composite.xsettings ${D}${sysconfdir}/gpe/xsettings-default.d/disable-composite
  33
  34         mv ${D}/usr/bin/gpe-logout ${D}/usr/bin/gpe-logout.matchbox
  35
  36         install -d ${D}${sysconfdir}/X11
  37         install -m 755 ${WORKDIR}/phonesession ${D}${sysconfdir}/X11/phonesession
  38 }
  39
  40 do_install_append_x86() {
  41         install ${WORKDIR}/matchbox-session.vm ${D}${sysconfdir}/matchbox/session
  42 }
  43
  44 pkg_postinst_${PN}() {
  45         update-alternatives --install /usr/bin/gpe-logout gpe-logout /usr/bin/gpe-logout.matchbox 10
  46 }
  47
  48 pkg_postrm_${PN}() {
  49        update-alternatives --remove gpe-logout /usr/bin/gpe-logout.matchbox
  50 }
  51
  52 # This makes use of GUI_MACHINE_CLASS, so set PACKAGE_ARCH appropriately
  53 PACKAGE_ARCH = "${MACHINE_ARCH}"