code.vuplus.com Git - vuplus_openembedded/blob - recipes/glib-2.0/glib-2.0_2.22.4.bb

   1 DESCRIPTION = "GLib is a general-purpose utility library, \
   2 which provides many useful data types, macros, \
   3 type conversions, string utilities, file utilities, a main \
   4 loop abstraction, and so on. It works on many \
   5 UNIX-like platforms, Windows, OS/2 and BeOS."
   6 LICENSE = "LGPL"
   7 SECTION = "libs"
   8 PRIORITY = "optional"
   9 DEPENDS = "glib-2.0-native gtk-doc virtual/libiconv virtual/libintl"
  10
  11 SRC_URI = "\
  12   http://ftp.gnome.org/pub/GNOME/sources/glib/2.22/glib-${PV}.tar.bz2;name=archive \
  13   file://glibconfig-sysdefs.h \
  14   file://configure-libtool.patch;patch=1 \
  15   file://g_once_init_enter.patch;patch=1 \
  16   file://uclibc-res_query.patch;patch=1 \
  17 "
  18 SRC_URI[archive.md5sum] = "d91bcbe27556430ddecce65086355708"
  19 SRC_URI[archive.sha256sum] = "0d1f6bf8aaeab772f2370229eefda45bef434e3f29a7d1d8e5dfafeaa1d8ad14"
  20
  21 SRC_URI_append_arm = " file://atomic-thumb.patch;patch=1"
  22 SRC_URI_append_armv6 = " file://gatomic_armv6.patch;patch=1"
  23 SRC_URI_append_armv7a = " file://gatomic_armv6.patch;patch=1"
  24
  25 PR = "r0"
  26
  27 inherit autotools gettext
  28
  29 S = "${WORKDIR}/glib-${PV}"
  30
  31 EXTRA_OECONF = "--disable-debug "
  32
  33 # Add and entry for your favourite arch if your (g)libc has a sane printf
  34 EXTRA_OECONF_append_glibc_arm = "  --enable-included-printf=no "
  35
  36 do_configure_prepend () {
  37         install -m 0644 ${WORKDIR}/glibconfig-sysdefs.h .
  38 }
  39
  40 do_install_append() {
  41         sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g ${D}${bindir}/glib-mkenums || true
  42 }
  43
  44 DEPENDS_virtclass-native = "gettext-native gtk-doc-native"
  45 EXTRA_OECONF_virtclass-native = ""
  46
  47 do_configure_prepend_virtclass-native() {
  48     if [ -e ${S}/${TARGET_SYS}-libtool ] ; then
  49                 echo "${TARGET_SYS}-libtool already present"
  50     else
  51         cp ${STAGING_BINDIR}/${TARGET_SYS}-libtool ${S}
  52     fi
  53
  54 }
  55
  56 BBCLASSEXTEND = "native"
  57
  58 PACKAGES =+ "gobject-2.0 gmodule-2.0 gthread-2.0 gio-2.0 glib-2.0-utils "
  59 LEAD_SONAME = "libglib-2.0.*"
  60 FILES_glib-2.0-utils = "${bindir}/*"
  61 FILES_${PN} = "${libdir}/lib*so.* ${libdir}/gio/modules/*.so"
  62 FILES_${PN}-dev += "${libdir}/glib-2.0 ${datadir}/glib-2.0 ${libdir}/gio/modules/*.la"
  63 FILES_${PN}-dbg += "${libdir}/gio/modules/.debug"
  64 FILES_gmodule-2.0 = "${libdir}/libgmodule-2.0.so.*"
  65 FILES_gobject-2.0 = "${libdir}/libgobject-2.0.so.*"
  66 FILES_gio-2.0 = "${libdir}/libgio-2.0.so.*"
  67 FILES_gthread-2.0 = "${libdir}/libgthread-2.0.so.*"
  68
  69 # Let various glib components end up in glib package
  70 # for compatibility (with binary packages from Maemo).
  71 FILES_gthread-2.0_chinook-compat = ""
  72 FILES_gmodule-2.0_chinook-compat = ""
  73 FILES_gobject-2.0_chinook-compat = ""
  74 FILES_gio-2.0_chinook-compat = ""