code.vuplus.com Git - vuplus_openembedded/blob - recipes/freesmartphone/frameworkd_git.bb

   1 DESCRIPTION = "The reference implementation of the freesmartphone.org framework APIs"
   2 HOMEPAGE = "http://www.freesmartphone.org"
   3 AUTHOR = "FreeSmartphone.Org Development Team"
   4 SECTION = "console/network"
   5 DEPENDS = "python-cython-native python-pyrex-native"
   6 LICENSE = "GPL"
   7 PV = "0.9.5.9+gitr${SRCREV}"
   8 PR = "r2"
   9
  10 inherit distutils update-rc.d
  11
  12 INITSCRIPT_NAME = "frameworkd"
  13 INITSCRIPT_PARAMS = "defaults 29"
  14
  15 SRC_URI = "${FREESMARTPHONE_GIT}/framework.git;protocol=git;branch=master \
  16            file://frameworkd \
  17            file://frameworkd.conf \
  18            "
  19 SRC_URI_append_shr = "file://oeventsd-use-opimd-signals.patch;patch=1"
  20
  21 S = "${WORKDIR}/git"
  22
  23 do_configure_append() {
  24         echo "version=\"${PV}\"" >framework/__version__.py
  25 }
  26
  27 do_install_append() {
  28         install -d ${D}${sysconfdir}/init.d/
  29         install -m 0755 ${WORKDIR}/frameworkd ${D}${sysconfdir}/init.d/
  30         install -m 0644 ${WORKDIR}/frameworkd.conf ${D}${sysconfdir}
  31 }
  32
  33 pkg_postinst_${PN} () {
  34         echo "NOTE: if you have old contacts without field types and the"
  35         echo "      tel: prefix instead please use the remove-tel script"
  36 }
  37
  38 RDEPENDS_${PN} += "\
  39   fsousaged \
  40 "
  41
  42 RDEPENDS_${PN} += "\
  43   python-ctypes \
  44   python-dbus \
  45   python-datetime \
  46   python-difflib \
  47   python-logging \
  48   python-pprint \
  49   python-pyalsaaudio \
  50   python-pygobject \
  51   python-pyrtc \
  52   python-pyserial \
  53   python-pyyaml \
  54   python-shell \
  55   python-subprocess \
  56   python-syslog \
  57   python-textutils \
  58   python-multiprocessing \
  59   ${PN}-config \
  60 "
  61
  62 RRECOMMENDS_${PN} += "\
  63   alsa-utils-amixer \
  64   python-gst \
  65   python-phoneutils \
  66   python-vobject \
  67   ppp \
  68 "
  69
  70 PACKAGES =+ "${PN}-config"
  71 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
  72
  73 # machine specific stuff, should ideally be elsewhere
  74 # - recommend MUXer on platforms that require one
  75 RDEPENDS_${PN}-config_append_om-gta01 = " fso-abyss"
  76 RDEPENDS_${PN}-config_append_om-gta02 = " fso-abyss"
  77 # - add wmiconfig for wireless configuration
  78 RDEPENDS_${PN}-config_append_om-gta02 = " wmiconfig"
  79
  80 FILES_${PN}-config = "\
  81   ${sysconfdir}/frameworkd.conf \
  82   ${sysconfdir}/freesmartphone \
  83   "
  84 CONFFILES_${PN}-config = "\
  85   ${sysconfdir}/frameworkd.conf \
  86   ${sysconfdir}/freesmartphone/opreferences/conf/phone/silent.yaml \
  87   ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml \
  88   ${sysconfdir}/freesmartphone/opreferences/conf/profiles/default.yaml \
  89   ${sysconfdir}/freesmartphone/opreferences/conf/rules/silent.yaml \
  90   ${sysconfdir}/freesmartphone/opreferences/conf/rules/default.yaml \
  91   ${sysconfdir}/freesmartphone/oevents/rules.yaml \
  92   ${sysconfdir}/freesmartphone/ogsmd/networks.tab \
  93   "
  94
  95 PACKAGE_ARCH_${PN} = "${BASE_PACKAGE_ARCH}"
  96 FILES_${PN} += "${sysconfdir}/dbus-1 ${sysconfdir}/freesmartphone ${sysconfdir}/init.d ${datadir}"
  97 FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/framework/subsystems/*/.debug"