code.vuplus.com Git - vuplus_openembedded/blob - recipes/emacs/emacs.inc

   1 DESCRIPTION = "Emacs"
   2 HOMEPAGE = "http://www.gnu.org/software/emacs/"
   3 LICENSE = "GPLv2"
   4 SECTION = "editor"
   5 # and it needs to run some generated binaries..
   6 DEPENDS += "qemu-native"
   7
   8 DEPENDS +=" liblockfile"
   9
  10 inherit autotools
  11
  12 PACKAGES =+ "${PN}-el"
  13
  14 FILES_${PN}-el = "${datadir}/emacs/*/*/*.el.gz \
  15                   ${datadir}/emacs/*/*/*/*.el.gz"
  16
  17 FILES_${PN} += "${datadir}/emacs"
  18
  19 FILES_${PN}-dbg += "${libexecdir}/emacs/*/*/.debug ${datadir}/emacs/*/*/.debug"
  20
  21 TREEDIR = "${WORKDIR}/qemu-treedir"
  22
  23 QEMUARCH= "${TARGET_ARCH}"
  24 QEMUARCH_i486 = "i386"
  25 QEMUARCH_i586 = "i386"
  26 QEMUARCH_i686 = "i386"
  27
  28 # Large stack is required at least on x86_64 host, otherwise random segfaults appear:
  29 QEMU = "qemu-${QEMUARCH} ${QEMU_OPTIONS} -s 1048576 -L ${TREEDIR} "
  30
  31 export LOGNAME = "$(whoami)"
  32
  33 do_compile_prepend() {
  34         sed -i ':1;s:\(START.* \|LIB_STANDARD.* \|LIBES.* \)/usr/lib:\1${STAGING_LIBDIR}:;t1' ${S}/src/s/gnu-linux.h `find "${S}" -name Makefile`
  35         export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${CROSS_DIR}/${TARGET_SYS}/lib"
  36 # Ugly hack, see files/use-qemu.patch for more:
  37         ln -sf ../src/emacs lisp/emacs
  38         ln -sf ../src/emacs lib-src/emacs
  39         ln -sf ../src/emacs leim/emacs
  40 #copy STAGING_DIR_TARGET and libgcc_s.so* to WORKDIR/qemu-treedir #copied code from glibc-package.bbclass
  41         treedir=${TREEDIR}
  42         if [ -e $treedir ];then
  43                 rm -rf $treedir
  44         fi
  45         mkdir $treedir
  46         cp -pPR ${STAGING_DIR_TARGET}/* $treedir
  47         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so ]; then
  48                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so $treedir/lib
  49         fi
  50         if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* ]; then
  51                 cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.so.* $treedir/lib
  52         fi
  53 }
  54
  55 EXTRA_OEMAKE += 'QEMU="${QEMU}"'