code.vuplus.com Git - vuplus_openembedded/blob - recipes/dropbear/dropbear.inc

   1 DESCRIPTION = "Dropbear is a lightweight SSH and SCP implementation"
   2 HOMEPAGE = "http://matt.ucc.asn.au/dropbear/dropbear.html"
   3 SECTION = "console/network"
   4 LICENSE = "MIT"
   5 DEPENDS = "zlib"
   6 PROVIDES = "ssh sshd"
   7 RPROVIDES = "ssh sshd"
   8
   9 SRC_URI = "\
  10   http://matt.ucc.asn.au/dropbear/dropbear-${PV}.tar.bz2 \
  11   file://urandom-xauth-changes-to-options.h.patch;patch=1 \
  12   file://configure.patch;patch=1 \
  13   file://fix-2kb-keys.patch;patch=1 \
  14   file://allow-nopw.patch \
  15   file://init \
  16 "
  17 SRC_URI_append_openmoko = "\
  18   file://default \
  19 "
  20
  21 inherit autotools update-rc.d
  22
  23 INITSCRIPT_NAME = "dropbear"
  24 INITSCRIPT_PARAMS = "defaults 10"
  25
  26 CFLAGS =+ "-I."
  27 LD = "${CC}"
  28
  29 SBINCOMMANDS = "dropbear dropbearkey dropbearconvert"
  30 BINCOMMANDS = "dbclient ssh scp"
  31 EXTRA_OEMAKE = 'MULTI=1 SCPPROGRESS=1 PROGRAMS="${SBINCOMMANDS} ${BINCOMMANDS}"'
  32
  33 do_configure_prepend() {
  34         if [ "x${DISTRO_TYPE}" = "xdebug" ]; then
  35                 oenote "WARNING: applying allow-nopw.patch which allows password-less logins!"
  36                 patch -p1 < ${WORKDIR}/allow-nopw.patch
  37         fi
  38 }
  39
  40 do_install() {
  41         install -d ${D}${sysconfdir}
  42         install -d ${D}${sysconfdir}/init.d
  43         install -d ${D}${sysconfdir}/default
  44         install -d ${D}${sysconfdir}/dropbear
  45         install -d ${D}${bindir}
  46         install -d ${D}${sbindir}
  47         install -d ${D}${localstatedir}
  48
  49         install -m 0755 dropbearmulti ${D}${sbindir}/
  50         ln -s ${sbindir}/dropbearmulti ${D}${bindir}/dbclient
  51
  52         for i in ${SBINCOMMANDS}
  53         do
  54                 ln -sf ./dropbearmulti ${D}${sbindir}/$i
  55         done
  56         cat ${WORKDIR}/init | sed -e 's,/etc,${sysconfdir},g' \
  57                                   -e 's,/usr/sbin,${sbindir},g' \
  58                                   -e 's,/var,${localstatedir},g' \
  59                                   -e 's,/usr/bin,${bindir},g' \
  60                                   -e 's,/usr,${prefix},g' > ${D}${sysconfdir}/init.d/dropbear
  61         chmod 755 ${D}${sysconfdir}/init.d/dropbear
  62         if test -e ${WORKDIR}/default ; then
  63                 install -m 0644 ${WORKDIR}/default ${D}${sysconfdir}/default/dropbear
  64         fi
  65 }
  66
  67 pkg_postinst () {
  68         update-alternatives --install ${bindir}/scp scp ${sbindir}/dropbearmulti 20
  69         update-alternatives --install ${bindir}/ssh ssh ${sbindir}/dropbearmulti 20
  70 }
  71
  72 pkg_postrm_append () {
  73         if [ -f "${sysconfdir}/dropbear/dropbear_rsa_host_key" ]; then
  74                 rm ${sysconfdir}/dropbear/dropbear_rsa_host_key
  75         fi
  76         if [ -f "${sysconfdir}/dropbear/dropbear_dss_host_key" ]; then
  77                 rm ${sysconfdir}/dropbear/dropbear_dss_host_key
  78         fi
  79         update-alternatives --remove ssh ${bindir}/dropbearmulti
  80         update-alternatives --remove scp ${bindir}/dropbearmulti
  81 }
  82
  83 CONFFILES_${PN}_openmoko += "${sysconfdir}/default/dropbear"