code.vuplus.com Git - vuplus_openembedded/blob - recipes/base-files/base-files_3.0.14.bb

   1 DESCRIPTION = "Miscellaneous files for the base system."
   2 SECTION = "base"
   3 PRIORITY = "required"
   4 PR = "r91"
   5 PR_dm7025 = "r92"
   6 LICENSE = "GPL"
   7
   8 FSTAB_dm7025 = "${@base_contains('PREFERRED_VERSION_linux-dm7025', '2.6.12.6', 'fstab_old', 'fstab', d)}"
   9 FSTAB ?= "fstab"
  10
  11 SRC_URI = " \
  12            file://nsswitch.conf \
  13            file://motd \
  14            file://inputrc \
  15            file://host.conf \
  16            file://profile \
  17            file://${FSTAB} \
  18            file://filesystems \
  19            file://issue.net \
  20            file://issue \
  21            file://usbd \
  22            file://share/dot.bashrc \
  23            file://share/dot.profile \
  24            file://licenses/BSD \
  25            file://licenses/GPL-2 \
  26            file://licenses/GPL-3 \
  27            file://licenses/LGPL-2 \
  28            file://licenses/LGPL-2.1 \
  29            file://licenses/LGPL-3 \
  30            file://licenses/GFDL-1.2 \
  31            file://licenses/Artistic "
  32 S = "${WORKDIR}"
  33
  34 docdir_append = "/${P}"
  35 dirs1777 = "/tmp ${localstatedir}/volatile/lock ${localstatedir}/volatile/tmp"
  36 dirs2775 = "/home ${prefix}/src ${localstatedir}/local"
  37 dirs755 = "/bin /boot /dev ${sysconfdir} ${sysconfdir}/default \
  38            ${sysconfdir}/skel /lib /mnt /proc /home/root /sbin \
  39            ${prefix} ${bindir} ${docdir} /usr/games ${includedir} \
  40            ${libdir} ${sbindir} ${datadir} \
  41            ${datadir}/common-licenses ${datadir}/dict ${infodir} \
  42            ${mandir} ${datadir}/misc ${localstatedir} \
  43            ${localstatedir}/backups ${localstatedir}/lib \
  44            /sys ${localstatedir}/lib/misc ${localstatedir}/spool \
  45            ${localstatedir}/volatile ${localstatedir}/volatile/cache \
  46            ${localstatedir}/volatile/lock/subsys \
  47            ${localstatedir}/volatile/log \
  48            ${localstatedir}/volatile/run \
  49            /mnt /media /media/card /media/cf /media/net /media/ram \
  50            /media/union /media/realroot /media/hdd \
  51            /media/mmc1"
  52 dirs755_micro = "/dev /proc /sys ${sysconfdir}"
  53 dirs2775_micro = ""
  54 dirs1777_micro = "/tmp"
  55
  56 media = "card cf net ram"
  57 media_micro = ""
  58
  59 volatiles = "cache run log lock tmp"
  60 conffiles = "${sysconfdir}/debian_version ${sysconfdir}/host.conf \
  61              ${sysconfdir}/inputrc ${sysconfdir}/issue /${sysconfdir}/issue.net \
  62              ${sysconfdir}/nsswitch.conf ${sysconfdir}/profile \
  63              ${sysconfdir}/default"
  64
  65 #
  66 # set standard hostname, might be a candidate for a DISTRO variable? :M:
  67 #
  68 hostname = "openembedded"
  69 hostname_slugos = "nslu2"
  70 hostname_mnci = "MNCI"
  71 hostname_rt3000 = "MNRT"
  72 hostname_jlime = "JLime"
  73
  74 do_install () {
  75         for d in ${dirs755}; do
  76                 install -m 0755 -d ${D}$d
  77         done
  78         for d in ${dirs1777}; do
  79                 install -m 1777 -d ${D}$d
  80         done
  81         for d in ${dirs2775}; do
  82                 install -m 2755 -d ${D}$d
  83         done
  84         for d in ${volatiles}; do
  85                 if [ -d ${D}${localstatedir}/volatile/$d ]; then
  86                         ln -sf volatile/$d ${D}/${localstatedir}/$d
  87                 fi
  88         done
  89         for d in ${media}; do
  90                 ln -sf /media/$d ${D}/mnt/$d
  91         done
  92
  93         if [ -n "${MACHINE}" -a "${hostname}" = "openembedded" ]; then
  94                 echo ${MACHINE} > ${D}${sysconfdir}/hostname
  95         else
  96                 echo ${hostname} > ${D}${sysconfdir}/hostname
  97         fi
  98
  99         if [ "${DISTRO}" != "micro" -a "${DISTRO}" != "micro-uclibc" ]; then
 100                 install -m 644 ${WORKDIR}/issue*  ${D}${sysconfdir}
 101
 102                 if [ -n "${DISTRO_NAME}" ]; then
 103                         echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue
 104                         echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue.net
 105                         if [ -n "${DISTRO_VERSION}" ]; then
 106                                 echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue
 107                                 echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue.net
 108                         fi
 109                         echo "\n \l" >> ${D}${sysconfdir}/issue
 110                         echo >> ${D}${sysconfdir}/issue
 111                         echo "%h"    >> ${D}${sysconfdir}/issue.net
 112                         echo >> ${D}${sysconfdir}/issue.net
 113                 else
 114                         install -m 0644 ${WORKDIR}/issue ${D}${sysconfdir}/issue
 115                         install -m 0644 ${WORKDIR}/issue.net ${D}${sysconfdir}/issue.net
 116                 fi
 117
 118                 install -m 0644 ${WORKDIR}/${FSTAB} ${D}${sysconfdir}/fstab
 119                 install -m 0644 ${WORKDIR}/filesystems ${D}${sysconfdir}/filesystems
 120                 install -m 0644 ${WORKDIR}/usbd ${D}${sysconfdir}/default/usbd
 121                 install -m 0644 ${WORKDIR}/profile ${D}${sysconfdir}/profile
 122                 install -m 0755 ${WORKDIR}/share/dot.profile ${D}${sysconfdir}/skel/.profile
 123                 install -m 0755 ${WORKDIR}/share/dot.bashrc ${D}${sysconfdir}/skel/.bashrc
 124                 install -m 0644 ${WORKDIR}/inputrc ${D}${sysconfdir}/inputrc
 125                 install -m 0644 ${WORKDIR}/motd ${D}${sysconfdir}/motd
 126                 for license in BSD GPL-2 LGPL-2 LGPL-2.1 Artistic GPL-3 LGPL-3 GFDL-1.2; do
 127                         install -m 0644 ${WORKDIR}/licenses/$license ${D}${datadir}/common-licenses/
 128                 done
 129
 130                 ln -sf /proc/mounts ${D}${sysconfdir}/mtab
 131                 install -m 0644 ${WORKDIR}/host.conf ${D}${sysconfdir}/host.conf
 132         fi
 133
 134         install -m 0644 ${WORKDIR}/nsswitch.conf ${D}${sysconfdir}/nsswitch.conf
 135 }
 136
 137 do_install_append_mnci () {
 138         rmdir ${D}/tmp
 139         ln -s var/tmp ${D}/tmp
 140 }
 141
 142 do_install_append_nylon() {
 143         printf "" "" >${D}${sysconfdir}/resolv.conf
 144         rm -r ${D}/mnt/*
 145         rm -r ${D}/media
 146         rm -rf ${D}/tmp
 147         ln -sf /var/tmp ${D}/tmp
 148 }
 149
 150 do_install_append_slugos() {
 151         printf "" "" >${D}${sysconfdir}/resolv.conf
 152         rm -r ${D}/mnt/*
 153         rmdir ${D}/home/root
 154         install -m 0755 -d ${D}/root
 155         ln -s ../root ${D}/home/root
 156 }
 157
 158 do_install_append_netbook-pro () {
 159         mkdir -p ${D}/initrd
 160 }
 161
 162 do_install_append_opendreambox() {
 163         rm -rf ${D}/mnt
 164         rm -rf ${D}/hdd
 165         ln -sf media/hdd ${D}/hdd
 166         ln -sf media ${D}/mnt
 167 }
 168
 169 do_install_append_vuplus() {
 170         rm -rf ${D}/mnt
 171         rm -rf ${D}/hdd
 172         ln -sf media/hdd ${D}/hdd
 173         ln -sf media ${D}/mnt
 174 }
 175
 176 PACKAGES = "${PN}-dbg ${PN}-doc ${PN}"
 177 FILES_${PN} = "/*"
 178 FILES_${PN}-doc = "${docdir} ${datadir}/common-licenses"
 179
 180 # M&N specific packaging
 181 PACKAGE_ARCH_mnci = "mnci"
 182 PACKAGE_ARCH_rt3000 = "rt3000"
 183
 184 PACKAGE_ARCH = "${MACHINE_ARCH}"
 185
 186 CONFFILES_${PN} = "${sysconfdir}/fstab ${sysconfdir}/hostname"
 187 CONFFILES_${PN}_micro = ""
 188 CONFFILES_${PN}_nylon = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 189 CONFFILES_${PN}_slugos = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 190