code.vuplus.com Git - vuplus_openembedded/blob - recipes/avetanabt/avetanabt_cvs.bb

   1 DESCRIPTION = "avetanaBT: Bluetooth API implementation for Java (JSR-82)"
   2 SECTION = "devel"
   3 DEPENDS = "findutils-native virtual/javac-native kaffeh-native fastjar-native bluez-libs classpath"
   4 LICENSE = "GPL"
   5 HOMEPAGE = "http://sourceforge.net/projects/avetanabt/"
   6
   7 DEFAULT_PREFERENCE = "-1"
   8
   9 PV = "20060413+cvs${SRCDATE}"
  10 PR = "r5"
  11
  12 SRC_URI = "cvs://anonymous@avetanabt.cvs.sourceforge.net/cvsroot/avetanabt;module=avetanabt"
  13
  14 S = "${WORKDIR}/avetanabt"
  15
  16 FILES_${PN} = "${libdir}/libavetanaBT.so ${datadir}/avetanabt/avetanaBT.jar"
  17
  18 do_compile() {
  19
  20   # doing nearly the same as in Makefile written...
  21
  22   # clean build directory
  23   mkdir -p build
  24   rm -fr build/*
  25
  26   # generate classes
  27   ${STAGING_BINDIR_NATIVE}/find {de,javax,com} -iname *.java > file.list
  28   ${STAGING_BINDIR_NATIVE}/javac -verbose -bootclasspath ${STAGING_DATADIR_NATIVE}/kaffeh/rt.jar -d build @file.list
  29
  30   # create own version.xml (add version information available at runtime)
  31   head -n 4 version.xml >> build/version.xml
  32   echo "    <build value=\"cvs${SRCDATE}\" date=\"${SRCDATE}\" time=\"${@time.strftime('%H:%M',time.gmtime())}\"/>" >> build/version.xml
  33   tail -n 3 version.xml >> build/version.xml
  34
  35   # move classes into jar archive
  36   # jar -> fastjar
  37   ${STAGING_BINDIR_NATIVE}/fastjar -v -cf avetanaBT.jar -C build de -C build javax -C build com -C build version.xml
  38
  39   # JNI generated header file - de_avetana_bluetooth_stack_BlueZ.h
  40   # javah -> kaffeh
  41   ${STAGING_BINDIR_NATIVE}/kaffeh -jni -classpath avetanaBT.jar:${STAGING_DATADIR_NATIVE}/kaffeh/rt.jar -d c de.avetana.bluetooth.stack.BlueZ
  42
  43   # Native language (C) library - libavetanaBT.so
  44   ${CXX} ${CXXFLAGS}  -shared -lbluetooth -I${STAGING_INCDIR}/classpath c/BlueZ.cpp -o libavetanaBT.so ${LDFLAGS}
  45
  46 }
  47
  48 do_stage() {
  49
  50   install -d ${STAGING_DATADIR_NATIVE}/avetanabt
  51   install avetanaBT.jar ${STAGING_DATADIR_NATIVE}/avetanabt/
  52
  53 }
  54
  55 do_install() {
  56
  57   install -d ${D}${libdir}
  58   install -m 0755 libavetanaBT.so ${D}${libdir}/
  59
  60   install -d ${D}${datadir}/avetanabt
  61   install avetanaBT.jar ${D}${datadir}/avetanabt/
  62
  63 }