code.vuplus.com Git - vuplus_openembedded/blob - recipes/angstrom/angstrom-feed-configs.bb

   1 DESCRIPTION = "Configuration files for online package repositories aka feeds"
   2
   3 RRECOMMENDS_${PN} += "opkg-nogpg-nocurl"
   4
   5 #PV = "${DISTRO_VERSION}"
   6 PR = "r9"
   7 PACKAGE_ARCH = "${MACHINE_ARCH}"
   8
   9 FEED_BASEPATH ?= "unstable/feed/"
  10
  11 IWMMXT_FEED = "${@base_contains('MACHINE_FEATURES', 'iwmmxt', 'iwmmxt', '',d)}"
  12
  13 do_compile() {
  14         mkdir -p ${S}/${sysconfdir}/opkg
  15
  16         rm ${S}/${sysconfdir}/opkg/arch.conf || true
  17         ipkgarchs="${PACKAGE_ARCHS}"
  18         priority=1
  19         for arch in $ipkgarchs; do
  20                 echo "arch $arch $priority" >> ${S}/${sysconfdir}/opkg/arch.conf
  21                 priority=$(expr $priority + 5)
  22         done
  23
  24         for feed in base debug perl python gstreamer ; do
  25                   echo "src/gz ${feed} ${ANGSTROM_URI}/${FEED_BASEPATH}${FEED_ARCH}/${feed}" > ${S}/${sysconfdir}/opkg/${feed}-feed.conf
  26         done
  27
  28                 echo "src/gz ${MACHINE_ARCH} ${ANGSTROM_URI}/${FEED_BASEPATH}${FEED_ARCH}/machine/${MACHINE_ARCH}" >  ${S}/${sysconfdir}/opkg/${MACHINE_ARCH}-feed.conf
  29         echo "src/gz no-arch ${ANGSTROM_URI}/${FEED_BASEPATH}/all" > ${S}/${sysconfdir}/opkg/noarch-feed.conf
  30
  31         # iwmmxt is a special case, add the iwmmxt feed for machine that have 'iwmmxt' in MACHINE_FEATURES
  32                 if [ "${IWMMXT_FEED}" = "iwmmxt" ] ; then
  33           echo "src/gz iwmmxt ${ANGSTROM_URI}/${FEED_BASEPATH}iwmmxt/base" > ${S}/${sysconfdir}/opkg/iwmmxt-feed.conf
  34         fi
  35
  36
  37         for localepkg in a af am an ang ar as ast ay az be bg bn br bs byn ca co crh cs csb cy da de dv dz el en eo es et eu fa ff fi fo fr fur fy ga gd gez gl gn gu gv ha haw he hi hr hsb ht hu hy ia id ig io is it iu iw ja ka kk kl km kn ko kok ks ku kw ky la lg li lo locale lt lv mai mg mi mk ml mn mr ms mt mvo my nb ne nl nn no nr nso oc om or pa pap pis pl ps pt qu ro ru rw sa sd se si sid sk sl so sp sq sr ss st sv sw syr ta te tet tg th ti tig tk tl tn tpi tr ts tt ug uk ur uz ve vi wa wal wo xh yi yo zh zu ; do
  38                 echo "src/gz locale-${localepkg}-feed ${ANGSTROM_URI}/${FEED_BASEPATH}${FEED_ARCH}/locales/${localepkg}" > ${S}/${sysconfdir}/opkg/locale-${localepkg}-feed.conf
  39         done
  40 }
  41
  42
  43 do_install () {
  44         install -d ${D}${sysconfdir}/opkg
  45         install -m 0644  ${S}/${sysconfdir}/opkg/* ${D}${sysconfdir}/opkg/
  46 }
  47
  48 FILES_${PN} = "${sysconfdir}/opkg/base-feed.conf \
  49                                         ${sysconfdir}/opkg/debug-feed.conf \
  50                                         ${sysconfdir}/opkg/perl-feed.conf \
  51                                         ${sysconfdir}/opkg/python-feed.conf \
  52                                         ${sysconfdir}/opkg/gstreamer-feed.conf \
  53                                         ${sysconfdir}/opkg/${MACHINE_ARCH}-feed.conf \
  54                                         ${sysconfdir}/opkg/noarch-feed.conf \
  55                                         ${sysconfdir}/opkg/iwmmxt-feed.conf \
  56                                         ${sysconfdir}/opkg/arch.conf \
  57                                         "
  58
  59 CONFFILES_${PN} += "${sysconfdir}/opkg/base-feed.conf \
  60                                         ${sysconfdir}/opkg/debug-feed.conf \
  61                                         ${sysconfdir}/opkg/perl-feed.conf \
  62                                         ${sysconfdir}/opkg/python-feed.conf \
  63                                         ${sysconfdir}/opkg/gstreamer-feed.conf \
  64                                         ${sysconfdir}/opkg/${MACHINE_ARCH}-feed.conf \
  65                                         ${sysconfdir}/opkg/noarch-feed.conf \
  66                                     ${sysconfdir}/opkg/arch.conf \
  67                                         "
  68
  69 python populate_packages_prepend () {
  70         etcdir = bb.data.expand('${sysconfdir}/opkg', d)
  71         do_split_packages(d, etcdir, '^locale-(.*)\.conf$', 'angstrom-locale-%s-config', 'Angstrom feed config for the %s locale', extra_depends='', allow_links=True)
  72 }
  73