code.vuplus.com Git - vuplus_openembedded/blob - recipes/abiword/abiword-plugins_2.6.8.bb

   1 DESCRIPTION = "AbiWord is a free word processing program similar to Microsoft(r) Word"
   2 HOMEPAGE = "http://www.abiword.org"
   3 SECTION = "x11/office"
   4 LICENSE = "GPLv2"
   5 DEPENDS = "asio boost loudmouth libwpd librsvg goffice poppler libglade"
   6 RDEPENDS = "abiword"
   7
   8
   9 SRC_URI = "http://www.abiword.org/downloads/abiword/${PV}/source/abiword-plugins-${PV}.tar.gz \
  10            http://www.abiword.org/downloads/abiword/${PV}/source/abiword-${PV}.tar.gz \
  11 #           file://abiword-cxx-for-ld-fix.patch;patch=1 \
  12            "
  13
  14 DEFAULT_PREFERENCE = "2"
  15
  16 inherit autotools
  17
  18 PARALLEL_MAKE=""
  19
  20 #export LDFLAGS += " -lstdc++ "
  21
  22 EXTRA_OECONF = " --enable-shared=yes \
  23                  --enable-static \
  24                  --without-libwmf \
  25                  --without-inter7eps \
  26                  --with-abiword=${WORKDIR}/abiword-${PV} \
  27                  --with-boost=${STAGING_DIR_HOST} \
  28                  --with-boost-thread=boost_thread-mt \
  29                "
  30
  31 PACKAGES_DYNAMIC = "abiword-plugin-*"
  32
  33 python populate_packages_prepend () {
  34         abiword_libdir    = bb.data.expand('${libdir}/abiword-2.6/plugins', d)
  35         do_split_packages(d, abiword_libdir, '^libAbi(.*)\.so$', 'abiword-plugin-%s', 'Abiword plugin for %s', extra_depends='')
  36         do_split_packages(d, abiword_libdir, '^libAbi(.*)\.la$', 'abiword-plugin-%s-dev', 'Abiword plugin for %s', extra_depends='')
  37
  38         metapkg = "abiword-plugins"
  39         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
  40         bb.data.setVar('FILES_' + metapkg, "", d)
  41         blacklist = [ 'abiword-plugins-dbg', 'abiword-plugins', 'abiword-plugins-doc', 'abiword-plugins-dev', 'abiword-plugins-locale' ]
  42         metapkg_rdepends = []
  43         packages = bb.data.getVar('PACKAGES', d, 1).split()
  44         for pkg in packages[1:]:
  45                 if not pkg in blacklist and not pkg in metapkg_rdepends:
  46                         print "Modifying ", pkg
  47                         metapkg_rdepends.append(pkg)
  48         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
  49         bb.data.setVar('DESCRIPTION_' + metapkg, 'abiword-plugin meta package', d)
  50         packages.append(metapkg)
  51         bb.data.setVar('PACKAGES', ' '.join(packages), d)
  52 }
  53
  54
  55 PACKAGES =+ "abiword-plugin-collab-glade"
  56
  57 FILES_abiword-plugin-collab-glade += "${datadir}"
  58 RDEPENDS_abiword-plugin-collab-glade = "abiword-plugin-collab"
  59
  60 FILES_${PN}-dbg += "${libdir}/abiword-2.6/plugins/.debug"
  61