code.vuplus.com Git - vuplus_openembedded/blob - packages/wpa-supplicant/wpa-supplicant_0.5.5.bb

   1 DESCRIPTION = "A Client for Wi-Fi Protected Access (WPA)."
   2 SECTION = "network"
   3 LICENSE = "GPL"
   4 HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/"
   5 DEPENDS = "gnutls ${@base_contains("COMBINED_FEATURES", "pci", "madwifi-ng", "",d)}"
   6
   7 #we introduce MY_ARCH to get 'armv5te' as arch instead of the misleading 'arm' on armv5te builds
   8 MY_ARCH := "${PACKAGE_ARCH}"
   9 PACKAGE_ARCH = "${@base_contains('COMBINED_FEATURES', 'pci', '${MACHINE_ARCH}', '${MY_ARCH}', d)}"
  10
  11 DEFAULT_PREFERENCE = "-2"
  12
  13 SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \
  14         file://defconfig-gnutls \
  15         file://init.sh \
  16         file://gnutlsfix.patch;patch=1 \
  17         file://defaults-sane \
  18         file://wpa_supplicant.conf \
  19         file://wpa_supplicant.conf-sane"
  20
  21 S = "${WORKDIR}/wpa_supplicant-${PV}"
  22
  23 PACKAGES_prepend = "wpa-supplicant-passphrase wpa-supplicant-cli "
  24 FILES_wpa-supplicant-passphrase = "/usr/sbin/wpa_passphrase"
  25 FILES_wpa-supplicant-cli = "/usr/sbin/wpa_cli"
  26
  27 RRECOMMENDS_${PN} = "wpa-supplicant-passphrase wpa-supplicant-cli"
  28
  29 INITSCRIPT_NAME = "wpa"
  30 INITSCRIPT_PARAMS = "defaults 10"
  31 inherit update-rc.d
  32
  33 export HAS_PCI = "${@base_contains('COMBINED_FEATURES', 'pci', 1, 0,d)}"
  34
  35 do_configure () {
  36         install -m 0755 ${WORKDIR}/defconfig-gnutls  .config
  37
  38         if [ "x$HAS_PCI" == "x1" ] ; then
  39                 echo "CONFIG_DRIVER_MADWIFI=y" >> .config
  40                 echo "CFLAGS += -I${STAGING_INCDIR}/madwifi-ng" >> .config
  41         fi
  42 }
  43
  44 do_compile () {
  45         make
  46 }
  47
  48 do_install () {
  49         install -d ${D}${sbindir}
  50         install -m 755 wpa_supplicant ${D}${sbindir}
  51         install -m 755 wpa_passphrase ${D}${sbindir}
  52         install -m 755 wpa_cli        ${D}${sbindir}
  53
  54         install -d ${D}${localstatedir}/run/wpa_supplicant
  55
  56         install -d ${D}${docdir}/wpa_supplicant
  57         install -m 644 README ${WORKDIR}/wpa_supplicant.conf ${D}${docdir}/wpa_supplicant
  58
  59         install -d ${D}${sysconfdir}/init.d
  60         install -m 700 ${WORKDIR}/init.sh ${D}${sysconfdir}/init.d/wpa
  61
  62         install -d ${D}${sysconfdir}/default
  63         install -m 600 ${WORKDIR}/defaults-sane ${D}${sysconfdir}/default/wpa
  64         install -m 600 ${WORKDIR}/wpa_supplicant.conf-sane ${D}${sysconfdir}/wpa_supplicant.conf
  65 }