code.vuplus.com Git - vuplus_openembedded/blob - packages/wireshark/wireshark_1.0.5.bb

   1 DESCRIPTION = "wireshark - a popular network protocol analyzer"
   2 HOMEPAGE = "http://www.wireshark.org"
   3 SECTION = "network"
   4 LICENSE = "GPL"
   5 DEPENDS = "perl-native gnutls libpcap pcre expat glib-2.0 libsmi gtk+"
   6 EXTRA_OECONF = "--disable-usrlocal --with-pcap=${STAGING_DIR_HOST}${layout_prefix} \
   7                 --with-libsmi=${STAGING_DIR_HOST}${layout_prefix} --enable-tshark --enable-wireshark"
   8
   9 PR = "r5"
  10
  11 SRC_URI = "${SOURCEFORGE_MIRROR}/wireshark/wireshark-${PV}.tar.bz2 \
  12            file://ieee80215.4.patch;patch=1"
  13
  14 ARM_INSTRUCTION_SET = "arm"
  15
  16 PACKAGES += "libwireshark1-dev libwireshark1 libwireshark1-dbg"
  17 FILES_libwireshark1 = "${libdir}/*.so*"
  18 FILES_libwireshark1-dev += "${libdir}/*.la ${libdir}/*.a ${libdir}/*.so ${includedir}"
  19 FILES_libwireshark1-dbg += "${libdir}/.debug"
  20 LEAD_SONAME_libwireshark1 = "libwireshark.so.0"
  21
  22 PACKAGES += "${PN}-wireshark ${PN}-wireshark-dbg ${PN}-tshark ${PN}-tshark-dbg"
  23 FILES_${PN}-wireshark = "${bindir}/wireshark"
  24 FILES_${PN}-wireshark-dbg = "${bindir}/.debug/wireshark"
  25 FILES_${PN}-tshark = "${bindir}/tshark"
  26 FILES_${PN}-tshark-dbg = "${bindir}/.debug/tshark"
  27 RDEPENDS_${PN}-tshark += "libsmi-mibs libsmi-pibs ${PN}-data"
  28 RDEPENDS_${PN}-wireshark += "libsmi-mibs libsmi-pibs ${PN}-data"
  29 RCONFLICTS_${PN}-tshark = "tshark wireshark (<1.0.5)"
  30 RREPLACES_${PN}-tshark = "tshark wireshark (<1.0.5)"
  31 RCONFLICTS_${PN}-wireshark = "tshark wireshark (<1.0.5)"
  32 RREPLACES_${PN}-wireshark = "tshark wireshark (<1.0.5)"
  33
  34 PACKAGES += "${PN}-plugins-dbg ${PN}-plugins"
  35 FILES_${PN}-plugins = "${libdir}/wireshark/plugins/${PV}/*.so ${libdir}/wireshark/plugins/${PV}/*.la"
  36 FILES_${PN}-plugins-dbg += "${libdir}/wireshark/plugins/${PV}/.debug"
  37
  38 PACKAGES += "${PN}-data"
  39 FILES_${PN}-data = "${datadir}/wireshark"
  40
  41 PACKAGES += "${PN}-utils ${PN}-utils-dbg"
  42 FILES_${PN}-utils = "${bindir}/text2pcap ${bindir}/dumpcap \
  43                      ${bindir}/rawshark ${bindir}/editcap  \
  44                      ${bindir}/mergecap ${bindir}/idl2wrs  \
  45                      ${bindir}/dftest ${bindir}/capinfos   \
  46                      ${bindir}/randpkt"
  47 FILES_${PN}-utils-dbg = "${bindir}/.debug"
  48
  49 FILES_${PN} = ""
  50 FILES_${PN}-dev = ""
  51 FILES_${PN}-dbg = ""
  52 ALLOW_EMPTY_${PN} = "1"
  53 RDEPENDS_${PN} = "${PN}-tshark ${PN}-wireshark ${PN}-plugins ${PN}-data"
  54 RCONFLICTS_${PN} = "tshark wireshark (<1.0.5)"
  55 RREPLACES_${PN} = "tshark wireshark (<1.0.5)"
  56
  57 inherit autotools
  58
  59 do_compile_prepend() {
  60          find . -type f -name Makefile \
  61                 -exec sed -e 's@-I/usr/include @@g' \
  62                           -e 's@-I$(includedir)@@g' \
  63                           -e 's@-I/usr/local/include @@g' \
  64                           -e "s@-I${includedir} @@g" -i '{}' ';'
  65
  66          ${BUILD_CC} ${BUILD_CFLAGS} -o rdps rdps.c
  67          oe_runmake -C tools/lemon CC="${BUILD_CC} ${BUILD_CFLAGS}" \
  68          CC_FOR_BUILD="${BUILD_CC} ${BUILD_CFLAGS}" LDFLAGS="${BUILD_LDFLAGS}"
  69 }
  70