code.vuplus.com Git - vuplus_openembedded/blob - packages/webkit/webkit-gtk_svn.bb

   1 DESCRIPTION = "WebKit browser engine, GTK+ edition"
   2 DEPENDS = "libsoup-2.4 curl icu libxml2 cairo libxslt libxt libidn gnutls gtk+ gstreamer gst-plugins-base gnome-vfs bison-native flex-native gperf-native perl-native sqlite3"
   3
   4 SRCREV_FORMAT = "webcore-rwebkit"
   5
   6 # Yes, this is wrong...
   7 PV = "0.1+svnr${SRCREV}"
   8 PR = "r8"
   9
  10 SRC_URI = "\
  11   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptCore;proto=http \
  12   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptGlue;proto=http \
  13   svn://svn.webkit.org/repository/webkit/trunk/;module=WebCore;proto=http;name=webcore \
  14   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKit;proto=http;name=webkit \
  15   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitLibraries;proto=http \
  16   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitTools;proto=http \
  17   svn://svn.webkit.org/repository/webkit/trunk/;module=autotools;proto=http \
  18   file://Makefile \
  19   file://Makefile.shared \
  20   file://autogen.sh \
  21   file://configure.ac \
  22   file://symbols.filter \
  23   file://GNUmakefile.am \
  24  "
  25
  26 S = "${WORKDIR}/"
  27
  28 inherit autotools pkgconfig lib_package
  29
  30 export BISON="${STAGING_BINDIR_NATIVE}/bison"
  31 ARM_INSTRUCTION_SET = "arm"
  32 EXTRA_OECONF = "\
  33                 --enable-debug=no \
  34                 --enable-svg \
  35                 --enable-icon-database=yes \
  36                 --with-http-backend=soup \
  37                "
  38 EXTRA_AUTORECONF = " -I autotools "
  39
  40 # Dolt gets used on x86 and ppc and hardcodes 'libtool'
  41 do_configure_append() {
  42         cp ${TARGET_PREFIX}libtool libtool || true
  43 }
  44
  45 do_compile_prepend() {
  46         mkdir -p ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  47         mkdir -p ${S}/Programs/
  48         cd ${S}/JavaScriptCore/pcre
  49         if test -e dftables.c
  50         then
  51             ${BUILD_CC} dftables.c -o dftables -I. -I../wtf
  52         elif test -e dftables.cpp
  53         then
  54             ${BUILD_CXX} dftables.cpp -o dftables -I. -I../wtf
  55         fi
  56         cp dftables ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  57         cp dftables ${S}/Programs/
  58         cd ${S}
  59 }
  60
  61 do_stage() {
  62         autotools_stage_all
  63 }
  64
  65 PACKAGES =+ "${PN}-webinspector ${PN}launcher-dbg ${PN}launcher libjavascriptcore"
  66 FILES_${PN}launcher = "${bindir}/GtkLauncher"
  67 FILES_${PN}launcher-dbg = "${bindir}/.debug/GtkLauncher"
  68 FILES_libjavascriptcore = "${libdir}/libJavaScriptCore.so.*"
  69 FILES_${PN}-webinspector = "${datadir}/webkit-1.0/webinspector/"
  70
  71