code.vuplus.com Git - vuplus_openembedded/blob - packages/webkit/webkit-gtk_svn.bb

   1 DESCRIPTION = "WebKit browser engine, GTK+ edition"
   2 DEPENDS = "curl icu libxml2 cairo libxslt libxt libidn gnutls gtk+ gstreamer gst-plugins-base gnome-vfs bison-native flex-native gperf-native perl-native sqlite3"
   3
   4 SRCREV_FORMAT = "webcore-rwebkit"
   5
   6 # Yes, this is wrong...
   7 PV = "0.1+svnr${SRCREV}"
   8 PR = "r7"
   9
  10 SRC_URI = "\
  11   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptCore;proto=http \
  12   svn://svn.webkit.org/repository/webkit/trunk/;module=JavaScriptGlue;proto=http \
  13   svn://svn.webkit.org/repository/webkit/trunk/;module=WebCore;proto=http;name=webcore \
  14   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKit;proto=http;name=webkit \
  15   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitLibraries;proto=http \
  16   svn://svn.webkit.org/repository/webkit/trunk/;module=WebKitTools;proto=http \
  17   file://acinclude.m4 \
  18   file://Makefile \
  19   file://Makefile.shared \
  20   file://autogen.sh \
  21   file://configure.ac \
  22   file://symbols.filter \
  23   file://GNUmakefile.am \
  24  "
  25
  26 S = "${WORKDIR}/"
  27
  28 inherit autotools pkgconfig lib_package
  29
  30 # FIXME: Segfaulting without --with-http-backend=curl
  31 EXTRA_OECONF = "\
  32                 --enable-debug=no \
  33                 --enable-svg \
  34                 --enable-icon-database=yes \
  35                 --with-http-backend=curl \
  36                "
  37
  38 # Dolt gets used on x86 and ppc and hardcodes 'libtool'
  39 do_configure_append() {
  40         cp ${TARGET_PREFIX}libtool libtool || true
  41 }
  42
  43 do_compile_prepend() {
  44         mkdir -p ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  45         mkdir -p ${S}/Programs/
  46         cd ${S}/JavaScriptCore/pcre
  47         if test -e dftables.c
  48         then
  49             ${BUILD_CC} dftables.c -o dftables -I. -I../wtf
  50         elif test -e dftables.cpp
  51         then
  52             ${BUILD_CXX} dftables.cpp -o dftables -I. -I../wtf
  53         fi
  54         cp dftables ${S}/WebKitBuilds/Debug/JavaScriptCore/pcre/tmp/
  55         cp dftables ${S}/Programs/
  56         cd ${S}
  57 }
  58
  59 do_stage() {
  60         autotools_stage_all
  61 }
  62
  63 PACKAGES =+ "${PN}launcher-dbg ${PN}launcher libjavascriptcore"
  64 FILES_${PN}launcher = "${bindir}/GtkLauncher"
  65 FILES_${PN}launcher-dbg = "${bindir}/.debug/GtkLauncher"
  66 FILES_libjavascriptcore = "${libdir}/libJavaScriptCore.so.*"
  67
  68
  69