code.vuplus.com Git - vuplus_openembedded/blob - packages/udev/udev_124.bb

   1 DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
   2 /dev/, handles hotplug events and loads drivers at boot time. It replaces \
   3 the hotplug package and requires a kernel not older than 2.6.12."
   4 RPROVIDES_${PN} = "hotplug"
   5
   6 PR = "r8"
   7
   8 SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
   9            file://noasmlinkage.patch;patch=1 \
  10            file://flags.patch;patch=1 \
  11            file://vol_id_ld.patch;patch=1 \
  12            file://udevtrigger_add_devname_filtering.patch;patch=1 \
  13            file://mount.blacklist \
  14            file://run.rules \
  15            "
  16
  17 SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
  18 PACKAGE_ARCH_h2200 = "h2200"
  19
  20 require udev.inc
  21
  22 DEFAULT_PREFERENCE = "-999"
  23
  24 INITSCRIPT_PARAMS = "start 03 S ."
  25
  26 FILES_${PN} += "${base_libdir}/udev/*"
  27 FILES_${PN}-dbg += "${base_libdir}/udev/.debug"
  28 UDEV_EXTRAS = "extras/firmware/ extras/scsi_id/ extras/volume_id/"
  29 EXTRA_OEMAKE += "libudevdir=/lib/udev libdir=${base_libdir} prefix="
  30
  31 do_install () {
  32         install -d ${D}${usrsbindir} \
  33                    ${D}${sbindir}
  34         oe_runmake 'DESTDIR=${D}' INSTALL=install install
  35         install -d ${D}${sysconfdir}/init.d
  36         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
  37
  38         install -d ${D}${sysconfdir}/udev/rules.d/
  39
  40         install -m 0644 ${WORKDIR}/mount.blacklist     ${D}${sysconfdir}/udev/
  41         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
  42         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
  43         install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
  44         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
  45         install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
  46         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
  47                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
  48         fi
  49
  50         install -d ${D}${sysconfdir}/udev/scripts/
  51
  52         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
  53         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
  54
  55         install -d ${D}${base_libdir}/udev/
  56 }
  57
  58 do_install_append_h2200() {
  59         install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
  60 }