code.vuplus.com Git - vuplus_openembedded/blob - packages/udev/udev.inc

   1 DESCRIPTION ?= "udev is a program which dynamically creates and removes device nodes from \
   2 /dev/. It responds to /sbin/hotplug device events and requires a 2.6 kernel."
   3 LICENSE = "GPL"
   4
   5 SRC_URI += " \
   6            file://udev.rules \
   7            file://devfs-udev.rules \
   8            file://links.conf \
   9            file://permissions.rules \
  10            file://mount.sh \
  11            file://network.sh \
  12            file://local.rules \
  13            file://init"
  14
  15 UDEV_DEVFS_RULES ?= "0"
  16
  17 PACKAGES =+ "udev-utils"
  18 FILES_udev-utils = "${usrbindir}/udevinfo ${usrbindir}/udevtest"
  19
  20 inherit update-rc.d
  21
  22 INITSCRIPT_NAME = "udev"
  23 INITSCRIPT_PARAMS = "start 04 S ."
  24
  25 export CROSS = "${TARGET_PREFIX}"
  26 export HOSTCC = "${BUILD_CC}"
  27 export udevdir ?= "/dev"
  28 export usrbindir := "${bindir}"
  29 export usrsbindir := "${sbindir}"
  30 export etcdir = "${sysconfdir}"
  31 LD = "${CC}"
  32 bindir = "/bin"
  33 sbindir = "/sbin"
  34
  35 UDEV_EXTRAS = "<override me>"
  36 FILES_${PN} += "${usrbindir}/* ${usrsbindir}/*"
  37 FILES_${PN}-dbg += "${usrbindir}/.debug ${usrsbindir}/.debug"
  38 EXTRA_OEMAKE = "-e \
  39                 'EXTRAS=${UDEV_EXTRAS}' \
  40                 'STRIP=echo'"
  41
  42 do_install () {
  43         install -d ${D}${usrsbindir} \
  44                    ${D}${sbindir}
  45         oe_runmake 'DESTDIR=${D}' INSTALL=install install
  46         install -d ${D}${sysconfdir}/init.d
  47         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
  48
  49         install -d ${D}${sysconfdir}/udev/rules.d/
  50
  51         install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
  52         install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
  53         install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
  54         if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
  55                 install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
  56         fi
  57
  58         install -d ${D}${sysconfdir}/udev/scripts/
  59
  60         install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
  61         install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
  62 }