code.vuplus.com Git - vuplus_openembedded/blob - packages/tasks/task-base.bb

   1 DESCRIPTION = "Merge machine and distro options to create a basic machine task/package"
   2 PR = "r13"
   3
   4 PACKAGES = "task-base \
   5             task-base-minimal \
   6             task-base-oh-minimal \
   7             task-base-core-default"
   8
   9 ALLOW_EMPTY = "1"
  10
  11 PACKAGE_ARCH = "${MACHINE_ARCH}"
  12
  13 # Valid only in MACHINE_FEATURES:
  14 #
  15 # kernel24
  16 # kernel26
  17 # apm
  18 # keyboard
  19 # touchscreen
  20 # screen
  21 # pci
  22
  23 # Valid only in DISTRO_FEATURES:
  24 #
  25 # nfs
  26 # smbfs
  27 # ipsec
  28 # wifi
  29 # ppp
  30
  31 # Valid COMBINED_FEATURES:
  32 # (These features need to be supported by both the machine and the distro)
  33 #
  34 # alsa
  35 # bluetooth
  36 # ext2
  37 # irda
  38 # pci
  39 # pcmcia
  40 # usbgadget
  41 # usbhost
  42
  43
  44 MACHINE_FEATURES ?= "kernel26"
  45 DISTRO_FEATURES ?= ""
  46 DISTRO_CORE_PACKAGE ?= "task-base-core-default"
  47
  48 DISTRO_EXTRA_RDEPENDS ?= ""
  49 DISTRO_EXTRA_RRECOMMENDS ?= ""
  50 MACHINE_EXTRA_RDEPENDS ?= ""
  51 MACHINE_EXTRA_RRECOMMENDS ?= ""
  52 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
  53 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
  54
  55
  56 COMBINED_FEATURES = "\
  57     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
  58     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
  59     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
  60     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
  61     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
  62     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
  63     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
  64     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)}"
  65
  66
  67 #
  68 # task-base
  69 #
  70 RDEPENDS_task-base = "\
  71     ${DISTRO_CORE_PACKAGE} \
  72     kernel \
  73     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-rdepends}", "",d)} \
  74     ${@base_contains("MACHINE_FEATURES", "apm", "${task-base-apm-rdepends}", "",d)} \
  75     ${@base_contains("MACHINE_FEATURES", "keyboard", "${task-base-keyboard-rdepends}", "",d)} \
  76     ${@base_contains("COMBINED_FEATURES", "alsa", "${task-base-alsa-rdepends}", "",d)} \
  77     ${@base_contains("COMBINED_FEATURES", "ext2", "${task-base-ext2-rdepends}", "",d)} \
  78     ${@base_contains("COMBINED_FEATURES", "irda", "${task-base-irda-rdepends}", "",d)} \
  79     ${@base_contains("COMBINED_FEATURES", "pci", "${task-base-pci-rdepends}", "",d)} \
  80     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${task-base-pcmcia-rdepends}", "",d)} \
  81     ${@base_contains("COMBINED_FEATURES", "usbhost", "${task-base-usbhost-rdepends}", "",d)} \
  82     ${@base_contains("DISTRO_FEATURES", "nfs", "${task-distro-nfs-rdepends}", "",d)} \
  83     ${@base_contains("DISTRO_FEATURES", "ipsec", "${task-distro-ipsec-rdepends}", "",d)} \
  84     ${@base_contains("DISTRO_FEATURES", "ppp", "${task-distro-ppp-rdepends}", "",d)} \
  85     ${@base_contains("DISTRO_FEATURES", "wifi", "${task-distro-wifi-rdepends}", "",d)} \
  86     ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS} \
  87     ${MACHINE_EXTRA_RDEPENDS} \
  88     ${DISTRO_EXTRA_RDEPENDS}"
  89
  90 RRECOMMENDS_task-base = "\
  91     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-extras-rrecommends}", "",d)} \
  92     ${@base_contains("COMBINED_FEATURES", "alsa", "${task-base-alsa-rrecommends}", "",d)} \
  93     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${task-base-pcmcia-rrecommends}", "",d)} \
  94     ${@base_contains("COMBINED_FEATURES", "bluetooth", "${task-base-bluetooth-rrecommends}", "",d)} \
  95     ${@base_contains("COMBINED_FEATURES", "irda", "${task-base-irda-rrecommends}", "",d)} \
  96     ${@base_contains("COMBINED_FEATURES", "usbgadget", "${task-base-usbgadget-rrecommends}", "",d)} \
  97     ${@base_contains("COMBINED_FEATURES", "usbhost", "${task-base-usbhost-rrecommends}", "",d)} \
  98     ${@base_contains("DISTRO_FEATURES", "ppp", "${task-distro-ppp-rrecommends}", "",d)} \
  99     ${@base_contains("DISTRO_FEATURES", "nfs", "${task-distro-nfs-rrecommends}", "",d)} \
 100     ${@base_contains("DISTRO_FEATURES", "ipsec", "${task-distro-ipsec-rrecommends}", "",d)} \
 101     ${@base_contains("DISTRO_FEATURES", "wifi", "${task-distro-wifi-rrecommends}", "",d)} \
 102     ${@base_contains("DISTRO_FEATURES", "cramfs", "${task-distro-cramfs-rrecommends}", "",d)} \
 103     ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS} \
 104     ${MACHINE_EXTRA_RRECOMMENDS} \
 105     ${DISTRO_EXTRA_RRECOMMENDS}"
 106
 107
 108 #
 109 # task-base-oh-minimal
 110 # An example of a small cut down machine configuration
 111 #
 112 RDEPENDS_task-base-oh-minimal = "\
 113     kernel \
 114     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-rdepends}", "",d)} \
 115     ${@base_contains("MACHINE_FEATURES", "apm", "${task-base-apm-rdepends}", "",d)} \
 116     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${PCMCIA_MANAGER}", "",d)} \
 117     ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
 118
 119 RRECOMMENDS_task-base-minimal = "\
 120     ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
 121
 122
 123
 124 HOTPLUG ?= "linux-hotplug"
 125
 126 RDEPENDS_task-base-core-default = '\
 127     base-files \
 128     base-passwd \
 129     busybox \
 130     initscripts \
 131     netbase \
 132     sysvinit \
 133     sysvinit-pidof \
 134     tinylogin \
 135     modutils-initscripts \
 136     fuser \
 137     setserial'
 138 # Lets see if we can kill off hotplug...
 139 #    ${HOTPLUG}
 140 #    ${@bootstrap_modutils_rdepends(d)}
 141
 142
 143 RRECOMMENDS_task-base-core-default = '\
 144     dropbear '
 145
 146
 147 task-base-kernel26-rdepends = "\
 148     udev \
 149     sysfsutils \
 150     module-init-tools"
 151
 152 task-base-keyboard-rdepends = "\
 153     keymaps"
 154
 155 task-base-pci-rdepends = "\
 156     pciutils"
 157
 158 task-base-kernel26-extras-rrecommends = "\
 159     kernel-module-input \
 160     kernel-module-uinput"
 161
 162 task-base-apm-rdepends = "\
 163     apm \
 164     apmd \
 165     ${@base_contains("MACHINE_FEATURES", "kernel24", "network-suspend-scripts", "",d)}"
 166
 167 task-base-ext2-rdepends = "\
 168     hdparm \
 169     e2fsprogs \
 170     e2fsprogs-e2fsck \
 171     e2fsprogs-mke2fs"
 172
 173 task-base-alsa-rdepends = "\
 174     alsa-utils-alsactl \
 175     alsa-utils-alsamixer \
 176     alsa-conf"
 177
 178 task-base-alsa-rrecommends = "\
 179     kernel-module-snd-mixer-oss \
 180     kernel-module-snd-pcm-oss"
 181
 182 task-base-pcmcia-rdepends = "\
 183     ${PCMCIA_MANAGER} \
 184     ${@base_contains("DISTRO_FEATURES", "wifi", "prism3-firmware", "",d)} \
 185     ${@base_contains("DISTRO_FEATURES", "wifi", "prism3-support", "",d)} \
 186     ${@base_contains("DISTRO_FEATURES", "wifi", "spectrum-fw", "",d)} \
 187     ${@base_contains("DISTRO_FEATURES", "wifi", "hostap-conf", "",d)} \
 188     ${@base_contains("DISTRO_FEATURES", "wifi", "orinoco-conf", "",d)}"
 189
 190 task-base-pcmcia-rrecommends = "\
 191     kernel-module-pcmcia \
 192     kernel-module-airo-cs \
 193     kernel-module-pcnet-cs \
 194     kernel-module-serial-cs \
 195     kernel-module-ide-cs \
 196     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-hostap-cs", "",d)} \
 197     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-orinoco-cs", "",d)} \
 198     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-spectrum-cs", "",d)}"
 199
 200 task-base-bluetooth-rrecommends = "\
 201     kernel-module-bluetooth \
 202     kernel-module-l2cap \
 203     kernel-module-rfcomm \
 204     kernel-module-hci-vhci \
 205     kernel-module-bnep \
 206     kernel-module-hidp \
 207     kernel-module-hci-uart \
 208     kernel-module-sco \
 209     ${@base_contains("COMBINED_FEATURES", "usbhost", "kernel-module-hci-usb", "",d)} \
 210     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluetooth3c-cs", "",d)} \
 211     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluecard-cs", "",d)} \
 212     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluetoothuart-cs", "",d)} \
 213     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-dtl1-cs", "",d)}"
 214
 215 task-base-irda-rdepends = "\
 216     irda-utils"
 217
 218 task-base-irda-rrecommends = "\
 219     kernel-module-pxaficp-ir \
 220     kernel-module-irda \
 221     kernel-module-ircomm \
 222     kernel-module-ircomm-tty \
 223     kernel-module-irlan \
 224     ${@base_contains("DISTRO_FEATURES", "ppp", "kernel-module-irnet", "",d)} \
 225     kernel-module-irport \
 226     kernel-module-irtty \
 227     ${@base_contains("COMBINED_FEATURES", "usbhost", "kernel-module-ir-usb", "",d)} "
 228
 229 task-base-usbgadget-rrecommends = "\
 230     kernel-module-pxa27x_udc \
 231     kernel-module-gadgetfs \
 232     kernel-module-g-file-storage \
 233     kernel-module-g-serial \
 234     kernel-module-g-ether"
 235
 236 task-base-usbhost-rdepends = "\
 237     usbutils "
 238
 239 task-base-usbhost-rrecommends = "\
 240     kernel-module-ohci-hcd \
 241     kernel-module-usbcore \
 242     kernel-module-usbhid \
 243     kernel-module-usbnet \
 244     kernel-module-sd-mod \
 245     kernel-module-scsi-mod \
 246     kernel-module-usbmouse \
 247     kernel-module-mousedev \
 248     kernel-module-usbserial \
 249     kernel-module-usb-storage "
 250
 251 task-distro-ppp-rdepends = "\
 252     ppp \
 253     ppp-dialin"
 254
 255 task-distro-ppp-rrecommends = "\
 256     kernel-module-ppp-async \
 257     kernel-module-ppp-deflate \
 258     kernel-module-ppp-mppe"
 259
 260 task-distro-ipsec-rdepends = "\
 261     openswan"
 262
 263 task-distro-ipsec-rrecommends = "\
 264     kernel-module-ipsec"
 265
 266 task-distro-wifi-rdepends = "\
 267     wireless-tools \
 268     ${@base_contains("COMBINED_FEATURES", "pcmcia", "hostap-utils", "",d)} \
 269     ${@base_contains("COMBINED_FEATURES", "pci", "hostap-utils", "",d)} \
 270     wpa-supplicant"
 271
 272 task-distro-wifi-rrecommends = "\
 273     kernel-module-ieee80211-crypt \
 274     kernel-module-ieee80211-crypt-ccmp \
 275     kernel-module-ieee80211-crypt-tkip \
 276     kernel-module-ieee80211-crypt-wep \
 277     kernel-module-arc4 \
 278     kernel-module-michael-mic \
 279     kernel-module-aes"
 280
 281 task-distro-smbfs-rrecommends = "\
 282     kernel-module-cifs \
 283     kernel-module-smbfs"
 284
 285 task-distro-cramfs-rrecommends = "\
 286     kernel-module-cramfs"
 287
 288 task-distro-nfs-rdepends = "\
 289     portmap"
 290
 291 task-distro-nfs-rrecommends = "\
 292     kernel-module-nfs \
 293     kernel-module-lockd \
 294     kernel-module-sunrpc"
 295
 296
 297 # Tosort
 298 # kernel-module-ipv6
 299 # kernel-module-nvrd
 300 # kernel-module-mip6-mn
 301 # kernel-module-tun
 302 # kernel-module-ide-disk
 303 # kernel-module-ide-probe-mo
 304 # kernel-module-loop
 305 # kernel-module-vfat
 306 # kernel-module-ext2
 307 # kernel-module-sco
 308 # kernel-module-af_packet
 309 # kernel-module-ip-gre
 310 # kernel-module-ip-tables
 311 # kernel-module-ipip
 312 # kernel-module-des
 313 # kernel-module-md5
 314 # kernel-module-8250
 315 # Should be DISTRO_EXTRA_RRECOMMENDS: lrzsz
 316