code.vuplus.com Git - vuplus_openembedded/blob - packages/tasks/task-base.bb

   1 DESCRIPTION = "Merge machine and distro options to create a basic machine task/package"
   2 PR = "r15"
   3
   4 PACKAGES = "task-base \
   5             task-base-minimal \
   6             task-base-oh-minimal \
   7             task-base-core-default"
   8
   9 ALLOW_EMPTY = "1"
  10
  11 PACKAGE_ARCH = "${MACHINE_ARCH}"
  12
  13 # Valid only in MACHINE_FEATURES:
  14 #
  15 # kernel24
  16 # kernel26
  17 # apm
  18 # keyboard
  19 # touchscreen
  20 # screen
  21 # pci
  22 # acpi
  23
  24 # Valid only in DISTRO_FEATURES:
  25 #
  26 # nfs
  27 # smbfs
  28 # ipsec
  29 # wifi
  30 # ppp
  31
  32 # Valid COMBINED_FEATURES:
  33 # (These features need to be supported by both the machine and the distro)
  34 #
  35 # alsa
  36 # bluetooth
  37 # ext2
  38 # irda
  39 # pci
  40 # pcmcia
  41 # usbgadget
  42 # usbhost
  43
  44 DISTRO_CORE_PACKAGE ?= "task-base-core-default"
  45
  46 #
  47 # task-base
  48 #
  49 RDEPENDS_task-base = "\
  50     ${DISTRO_CORE_PACKAGE} \
  51     kernel \
  52     ${@base_contains("MACHINE_FEATURES", "kernel24", "${task-base-kernel24-rdepends}", "",d)} \
  53     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-rdepends}", "",d)} \
  54     ${@base_contains("MACHINE_FEATURES", "apm", "${task-base-apm-rdepends}", "",d)} \
  55     ${@base_contains("MACHINE_FEATURES", "acpi", "${task-base-acpi-rdepends}", "",d)} \
  56     ${@base_contains("MACHINE_FEATURES", "keyboard", "${task-base-keyboard-rdepends}", "",d)} \
  57     ${@base_contains("COMBINED_FEATURES", "alsa", "${task-base-alsa-rdepends}", "",d)} \
  58     ${@base_contains("COMBINED_FEATURES", "ext2", "${task-base-ext2-rdepends}", "",d)} \
  59     ${@base_contains("COMBINED_FEATURES", "irda", "${task-base-irda-rdepends}", "",d)} \
  60     ${@base_contains("COMBINED_FEATURES", "pci", "${task-base-pci-rdepends}", "",d)} \
  61     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${task-base-pcmcia-rdepends}", "",d)} \
  62     ${@base_contains("COMBINED_FEATURES", "usbhost", "${task-base-usbhost-rdepends}", "",d)} \
  63     ${@base_contains("DISTRO_FEATURES", "nfs", "${task-distro-nfs-rdepends}", "",d)} \
  64     ${@base_contains("DISTRO_FEATURES", "ipsec", "${task-distro-ipsec-rdepends}", "",d)} \
  65     ${@base_contains("DISTRO_FEATURES", "ppp", "${task-distro-ppp-rdepends}", "",d)} \
  66     ${@base_contains("DISTRO_FEATURES", "wifi", "${task-distro-wifi-rdepends}", "",d)} \
  67     ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS} \
  68     ${MACHINE_EXTRA_RDEPENDS} \
  69     ${DISTRO_EXTRA_RDEPENDS}"
  70
  71 RRECOMMENDS_task-base = "\
  72     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-extras-rrecommends}", "",d)} \
  73     ${@base_contains("COMBINED_FEATURES", "alsa", "${task-base-alsa-rrecommends}", "",d)} \
  74     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${task-base-pcmcia-rrecommends}", "",d)} \
  75     ${@base_contains("COMBINED_FEATURES", "bluetooth", "${task-base-bluetooth-rrecommends}", "",d)} \
  76     ${@base_contains("COMBINED_FEATURES", "irda", "${task-base-irda-rrecommends}", "",d)} \
  77     ${@base_contains("COMBINED_FEATURES", "usbgadget", "${task-base-usbgadget-rrecommends}", "",d)} \
  78     ${@base_contains("COMBINED_FEATURES", "usbhost", "${task-base-usbhost-rrecommends}", "",d)} \
  79     ${@base_contains("DISTRO_FEATURES", "ppp", "${task-distro-ppp-rrecommends}", "",d)} \
  80     ${@base_contains("DISTRO_FEATURES", "nfs", "${task-distro-nfs-rrecommends}", "",d)} \
  81     ${@base_contains("DISTRO_FEATURES", "ipsec", "${task-distro-ipsec-rrecommends}", "",d)} \
  82     ${@base_contains("DISTRO_FEATURES", "wifi", "${task-distro-wifi-rrecommends}", "",d)} \
  83     ${@base_contains("DISTRO_FEATURES", "cramfs", "${task-distro-cramfs-rrecommends}", "",d)} \
  84     ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS} \
  85     ${MACHINE_EXTRA_RRECOMMENDS} \
  86     ${DISTRO_EXTRA_RRECOMMENDS}"
  87
  88
  89 #
  90 # task-base-oh-minimal
  91 # An example of a small cut down machine configuration
  92 #
  93 RDEPENDS_task-base-oh-minimal = "\
  94     kernel \
  95     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-kernel26-rdepends}", "",d)} \
  96     ${@base_contains("MACHINE_FEATURES", "apm", "${task-base-apm-rdepends}", "",d)} \
  97     ${@base_contains("COMBINED_FEATURES", "pcmcia", "${PCMCIA_MANAGER}", "",d)} \
  98     ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
  99
 100 RRECOMMENDS_task-base-minimal = "\
 101     ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
 102
 103
 104
 105 HOTPLUG ?= "linux-hotplug"
 106
 107 RDEPENDS_task-base-core-default = '\
 108     base-files \
 109     base-passwd \
 110     busybox \
 111     initscripts \
 112     netbase \
 113     sysvinit \
 114     sysvinit-pidof \
 115     tinylogin \
 116     modutils-initscripts \
 117     fuser \
 118     setserial'
 119 # Lets see if we can kill off hotplug...
 120 #    ${HOTPLUG}
 121 #    ${@bootstrap_modutils_rdepends(d)}
 122
 123
 124 RRECOMMENDS_task-base-core-default = '\
 125     dropbear '
 126
 127 task-base-kernel24-rdepends = "\
 128     linux-hotplug "
 129
 130 task-base-kernel26-rdepends = "\
 131     udev \
 132     sysfsutils \
 133     module-init-tools"
 134
 135 task-base-keyboard-rdepends = "\
 136     keymaps"
 137
 138 task-base-pci-rdepends = "\
 139     pciutils"
 140
 141 task-base-kernel26-extras-rrecommends = "\
 142     kernel-module-input \
 143     kernel-module-uinput"
 144
 145 task-base-acpi-rdepends = "\
 146     acpid"
 147
 148 task-base-apm-rdepends = "\
 149     apm \
 150     apmd \
 151     ${@base_contains("MACHINE_FEATURES", "kernel24", "network-suspend-scripts", "",d)}"
 152
 153 task-base-ext2-rdepends = "\
 154     hdparm \
 155     e2fsprogs \
 156     e2fsprogs-e2fsck \
 157     e2fsprogs-mke2fs"
 158
 159 task-base-alsa-rdepends = "\
 160     alsa-utils-alsactl \
 161     alsa-utils-alsamixer \
 162     alsa-conf"
 163
 164 task-base-alsa-rrecommends = "\
 165     kernel-module-snd-mixer-oss \
 166     kernel-module-snd-pcm-oss"
 167
 168 task-base-pcmcia-rdepends = "\
 169     ${PCMCIA_MANAGER} \
 170     ${@base_contains("DISTRO_FEATURES", "wifi", "prism3-firmware", "",d)} \
 171     ${@base_contains("DISTRO_FEATURES", "wifi", "prism3-support", "",d)} \
 172     ${@base_contains("DISTRO_FEATURES", "wifi", "spectrum-fw", "",d)} \
 173     ${@base_contains("DISTRO_FEATURES", "wifi", "hostap-conf", "",d)} \
 174     ${@base_contains("DISTRO_FEATURES", "wifi", "orinoco-conf", "",d)}"
 175
 176 task-base-pcmcia-rrecommends = "\
 177     kernel-module-pcmcia \
 178     kernel-module-airo-cs \
 179     kernel-module-pcnet-cs \
 180     kernel-module-serial-cs \
 181     kernel-module-ide-cs \
 182     ${@base_contains("MACHINE_FEATURES", "kernel26", "${task-base-pcmcia26-rrecommends}", "${task-base-pcmcia24-rrecommends}",d)} "
 183
 184 task-base-pcmcia24-rrecommends = "\
 185     ${@base_contains("DISTRO_FEATURES", "wifi", "hostap-modules-cs", "",d)} \
 186     ${@base_contains("DISTRO_FEATURES", "wifi", "orinoco-modules-cs", "",d)}"
 187
 188 task-base-pcmcia26-rrecommends = "\
 189     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-hostap-cs", "",d)} \
 190     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-orinoco-cs", "",d)} \
 191     ${@base_contains("DISTRO_FEATURES", "wifi", "kernel-module-spectrum-cs", "",d)}"
 192
 193 task-base-bluetooth-rrecommends = "\
 194     kernel-module-bluetooth \
 195     kernel-module-l2cap \
 196     kernel-module-rfcomm \
 197     kernel-module-hci-vhci \
 198     kernel-module-bnep \
 199     kernel-module-hidp \
 200     kernel-module-hci-uart \
 201     kernel-module-sco \
 202     ${@base_contains("COMBINED_FEATURES", "usbhost", "kernel-module-hci-usb", "",d)} \
 203     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluetooth3c-cs", "",d)} \
 204     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluecard-cs", "",d)} \
 205     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-bluetoothuart-cs", "",d)} \
 206     ${@base_contains("COMBINED_FEATURES", "pcmcia", "kernel-module-dtl1-cs", "",d)}"
 207
 208 task-base-irda-rdepends = "\
 209     irda-utils"
 210
 211 task-base-irda-rrecommends = "\
 212     kernel-module-pxaficp-ir \
 213     kernel-module-irda \
 214     kernel-module-ircomm \
 215     kernel-module-ircomm-tty \
 216     kernel-module-irlan \
 217     ${@base_contains("DISTRO_FEATURES", "ppp", "kernel-module-irnet", "",d)} \
 218     kernel-module-irport \
 219     kernel-module-irtty \
 220     ${@base_contains("COMBINED_FEATURES", "usbhost", "kernel-module-ir-usb", "",d)} "
 221
 222 task-base-usbgadget-rrecommends = "\
 223     kernel-module-pxa27x_udc \
 224     kernel-module-gadgetfs \
 225     kernel-module-g-file-storage \
 226     kernel-module-g-serial \
 227     kernel-module-g-ether"
 228
 229 task-base-usbhost-rdepends = "\
 230     usbutils "
 231
 232 task-base-usbhost-rrecommends = "\
 233     kernel-module-ohci-hcd \
 234     kernel-module-usbcore \
 235     kernel-module-usbhid \
 236     kernel-module-usbnet \
 237     kernel-module-sd-mod \
 238     kernel-module-scsi-mod \
 239     kernel-module-usbmouse \
 240     kernel-module-mousedev \
 241     kernel-module-usbserial \
 242     kernel-module-usb-storage "
 243
 244 task-distro-ppp-rdepends = "\
 245     ppp \
 246     ppp-dialin"
 247
 248 task-distro-ppp-rrecommends = "\
 249     kernel-module-ppp-async \
 250     kernel-module-ppp-deflate \
 251     kernel-module-ppp-mppe"
 252
 253 task-distro-ipsec-rdepends = "\
 254     openswan"
 255
 256 task-distro-ipsec-rrecommends = "\
 257     kernel-module-ipsec"
 258
 259 task-distro-wifi-rdepends = "\
 260     wireless-tools \
 261     ${@base_contains("COMBINED_FEATURES", "pcmcia", "hostap-utils", "",d)} \
 262     ${@base_contains("COMBINED_FEATURES", "pci", "hostap-utils", "",d)} \
 263     wpa-supplicant"
 264
 265 task-distro-wifi-rrecommends = "\
 266     kernel-module-ieee80211-crypt \
 267     kernel-module-ieee80211-crypt-ccmp \
 268     kernel-module-ieee80211-crypt-tkip \
 269     kernel-module-ieee80211-crypt-wep \
 270     kernel-module-arc4 \
 271     kernel-module-michael-mic \
 272     kernel-module-aes"
 273
 274 task-distro-smbfs-rrecommends = "\
 275     kernel-module-cifs \
 276     kernel-module-smbfs"
 277
 278 task-distro-cramfs-rrecommends = "\
 279     kernel-module-cramfs"
 280
 281 task-distro-nfs-rdepends = "\
 282     portmap"
 283
 284 task-distro-nfs-rrecommends = "\
 285     kernel-module-nfs \
 286     kernel-module-lockd \
 287     kernel-module-sunrpc"
 288
 289
 290 # Tosort
 291 # kernel-module-ipv6
 292 # kernel-module-nvrd
 293 # kernel-module-mip6-mn
 294 # kernel-module-tun
 295 # kernel-module-ide-disk
 296 # kernel-module-ide-probe-mo
 297 # kernel-module-loop
 298 # kernel-module-vfat
 299 # kernel-module-ext2
 300 # kernel-module-sco
 301 # kernel-module-af_packet
 302 # kernel-module-ip-gre
 303 # kernel-module-ip-tables
 304 # kernel-module-ipip
 305 # kernel-module-des
 306 # kernel-module-md5
 307 # kernel-module-8250
 308 # Should be DISTRO_EXTRA_RRECOMMENDS: lrzsz
 309