code.vuplus.com Git - vuplus_openembedded/blob - packages/ppp/ppp_2.4.3.bb

   1 SECTION = "console/network"
   2 DESCRIPTION = "Point-to-Point Protocol (PPP) daemon"
   3 HOMEPAGE = "http://samba.org/ppp/"
   4 DEPENDS = "libpcap"
   5 LICENSE = "BSD GPLv2"
   6 PR = "r1"
   7
   8 SRC_URI = "ftp://ftp.samba.org/pub/ppp/ppp-${PV}.tar.gz \
   9         file://makefile.patch;patch=1 \
  10         file://cifdefroute.patch;patch=1 \
  11         file://pppd-resolv-varrun.patch;patch=1 \
  12         file://plugins-fix-CC.patch;patch=1 \
  13         file://pppoatm-makefile.patch;patch=1 \
  14         file://enable-ipv6.patch;patch=1 \
  15         file://makefile-remove-hard-usr-reference.patch;patch=1 \
  16         file://pon \
  17         file://poff \
  18         file://init \
  19         file://ip-up \
  20         file://ip-down \
  21         file://08setupdns \
  22         file://92removedns"
  23
  24
  25 inherit autotools
  26
  27 EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}/usr/include LIBDIR=${D}/usr/lib/pppd/${PV} BINDIR=${D}/usr/sbin"
  28 EXTRA_OECONF = --disable-strip
  29
  30 do_install_append () {
  31         make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
  32         mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
  33         mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
  34         mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
  35         install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
  36         install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
  37         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
  38         install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
  39         install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
  40         install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
  41         install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
  42         rm -rf ${D}/${mandir}/man8/man8
  43 }
  44
  45 CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
  46 PACKAGES += "ppp-oa ppp-oe ppp-radius ppp-winbind ppp-minconn ppp-password ppp-tools"
  47 FILES_${PN}        = "/etc /usr/bin /usr/sbin/chat /usr/sbin/pppd"
  48 FILES_ppp-oa       = "/usr/lib/pppd/2.4.3/pppoatm.so"
  49 FILES_ppp-oe       = "/usr/sbin/pppoe-discovery /usr/lib/pppd/2.4.3/rp-pppoe.so"
  50 FILES_ppp-radius   = "/usr/lib/pppd/2.4.3/radius.so /usr/lib/pppd/2.4.3/radattr.so /usr/lib/pppd/2.4.3/radrealms.so"
  51 FILES_ppp-winbind  = "/usr/lib/pppd/2.4.3/winbind.so"
  52 FILES_ppp-minconn  = "/usr/lib/pppd/2.4.3/minconn.so"
  53 FILES_ppp-password = "/usr/lib/pppd/2.4.3/pass*.so"
  54 FILES_ppp-tools    = "/usr/sbin/pppstats /usr/sbin/pppdump"
  55 DESCRIPTION_ppp-oa       = "Plugin for PPP needed for PPP-over-ATM"
  56 DESCRIPTION_ppp-oe       = "Plugin for PPP needed for PPP-over-Ethernet"
  57 DESCRIPTION_ppp-radius   = "Plugin for PPP that are related to RADIUS"
  58 DESCRIPTION_ppp-winbind  = "Plugin for PPP to authenticate against Samba or Windows"
  59 DESCRIPTION_ppp-minconn  = "Plugin for PPP to specify a minimum connect time before the idle timeout applies"
  60 DESCRIPTION_ppp-password = "Plugin for PPP to get passwords via a pipe"
  61 DESCRIPTION_ppp-tools    = "The pppdump and pppstats utitilities"
  62 RDEPENDS_ppp_minconn    += "libpcap0.8"
  63
  64 pkg_postinst() {
  65 if test "x$D" != "x"; then
  66         exit 1
  67 else
  68         chmod u+s ${sbindir}/pppd
  69 fi
  70 }