code.vuplus.com Git - vuplus_openembedded/blob - packages/net-snmp/net-snmp_5.4.1.bb

   1 DESCRIPTION = "Various tools relating to the Simple Network Management Protocol"
   2 HOMEPAGE = "http://www.net-snmp.org/"
   3 LICENSE = "BSD"
   4 DEPENDS = "openssl"
   5 RDEPENDS_${PN}-server += "net-snmp-mibs"
   6 RDEPENDS_${PN}-client += "net-snmp-mibs"
   7 PR = "r1"
   8
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.tar.gz \
  10         file://configure-tail.patch;patch=1 \
  11         file://init \
  12         file://snmpd.conf \
  13         file://snmptrapd.conf"
  14
  15 inherit autotools update-rc.d
  16
  17 EXTRA_OECONF = "--enable-shared --disable-manuals --with-defaults \
  18                 --disable-embedded-perl --with-perl-modules=no"
  19 EXTRA_OEMAKE = "INSTALL_PREFIX=${D}"
  20
  21 do_configure() {
  22         # Additional flag based on target endiness (see siteinfo.bbclass)
  23         ENDIANESS="${@base_conditional('SITEINFO_ENDIANESS', 'le', '--with-endianness=little', '--with-endianness=big', d)}"
  24         oenote Determined endianess as: $ENDIANESS
  25         libtoolize --force
  26         oe_runconf $ENDIANESS
  27 }
  28 do_install_append() {
  29         install -d ${D}${sysconfdir}/snmp
  30         install -d ${D}${sysconfdir}/init.d
  31         install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/snmpd
  32         install -m 644 ${WORKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
  33         install -m 644 ${WORKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
  34 }
  35
  36 PACKAGES = "net-snmp-dbg net-snmp-doc net-snmp-dev net-snmp-libs \
  37             net-snmp-mibs net-snmp-server net-snmp-client"
  38
  39 FILES_${PN}-libs = "${libdir}/*"
  40 FILES_${PN}-mibs = "${datadir}/snmp/mibs"
  41 FILES_${PN}-server = "${sbindir}/* ${sysconfdir}"
  42 FILES_${PN}-client = "${bindir}/* ${datadir}/snmp/"
  43 FILES_${PN}-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
  44
  45 CONFFILES_${PN}-server = "${sysconfdir}/snmp/snmpd.conf \
  46                           ${sysconfdir}/snmp/snmptrapd.conf"
  47
  48 INITSCRIPT_PACKAGES = "${PN}-server"
  49 INITSCRIPT_NAME_${PN}-server = "snmpd"
  50 INITSCRIPT_PARAMS_${PN}-server = "defaults"
  51
  52 LEAD_SONAME = "libnetsnmp.so"
  53
  54 PARALLEL_MAKE = ""