code.vuplus.com Git - vuplus_openembedded/blob - packages/mc/mc.inc

   1 DESCRIPTION = "GNU Midnight Commander is a file \
   2 manager for free operating systems."
   3 HOMEPAGE = "http://www.ibiblio.org/mc/"
   4 LICENSE = "GPLv2"
   5 SECTION = "console/utils"
   6 PRIORITY = "optional"
   7 DEPENDS = "ncurses glib-2.0"
   8 RDEPENDS = "ncurses-terminfo"
   9
  10 SRC_URI = "http://www.ibiblio.org/pub/Linux/utils/file/managers/mc/mc-${PV}.tar.gz"
  11
  12 inherit autotools
  13
  14 EXTRA_OECONF = "--disable-glibtest --without-x --without-samba \
  15 --without-nfs --without-gpm-mouse --with-screen=ncurses"
  16
  17 PACKAGES += "${PN}-extfs ${PN}-hilite"
  18 FILES_${PN} = "${bindir}/ ${libdir}/ ${datadir}/mc/*.*"
  19 FILES_${PN}-extfs = "${datadir}/mc/extfs/"
  20 FILES_${PN}-hilite = "${datadir}/mc/syntax/"
  21 RRECOMMENDS_${PN} += "${PN}-extfs ${PN}-hilite"
  22 RDEPENDS_${PN}-extfs = "${PN}"
  23 RDEPENDS_${PN}-hilite = "${PN}"
  24 PACKAGE_ARCH_${PN}-extfs = "all"
  25 PACKAGE_ARCH_${PN}-hilite = "all"
  26
  27
  28 do_configure() {
  29         gnu-configize
  30         oe_runconf
  31 }
  32
  33 do_install() {
  34         cd src
  35         oe_runmake 'DESTDIR=${D}' install
  36         cd ../syntax
  37         oe_runmake 'DESTDIR=${D}' install
  38         cd ../po
  39         oe_runmake 'DESTDIR=${D}' install
  40         cd ../vfs
  41         oe_runmake 'DESTDIR=${D}' install
  42         cd ..
  43
  44         install -m 0644 lib/cedit.menu ${D}${datadir}/mc/
  45         install -m 0644 lib/edit.indent.rc ${D}${datadir}/mc/
  46         install -m 0644 lib/edit.spell.rc ${D}${datadir}/mc/
  47         install -m 0644 lib/mc.charsets ${D}${datadir}/mc/
  48         install -m 0644 lib/mc.ext ${D}${datadir}/mc/
  49         install -m 0644 lib/mc.lib ${D}${datadir}/mc/
  50         install -m 0644 lib/mc.menu ${D}${datadir}/mc/
  51         install -m 0644 lib/mc.menu.sr ${D}${datadir}/mc/
  52 }