code.vuplus.com Git - vuplus_openembedded/blob - packages/maemo4/osso-gnome-vfs2_2.16.3.bb

   1 LICENSE = "GPL"
   2 DEPENDS = "libxml2 gconf gnutls avahi dbus bzip2 gnome-mime-data zlib"
   3 RRECOMMENDS = "gnome-vfs-plugin-file gnome-mime-data shared-mime-info"
   4
   5 DESCRIPTION = "gnomevfs - osso variant"
   6
   7 PR = "r0"
   8
   9 inherit gnome
  10
  11 SRC_URI = "\
  12   http://repository.maemo.org/pool/maemo4.0/free/source/o/${PN}/${PN}_${PV}-1osso31.tar.gz \
  13   file://gnome-vfs-no-kerberos.patch;patch=1;pnum=0 \
  14   "
  15
  16
  17 EXTRA_OECONF = " \
  18         --disable-openssl \
  19         --enable-gnutls \
  20         --enable-avahi \
  21         --with-samba-includes=${STAGING_INCDIR} \
  22         --enable-more-warnings=no \
  23         "
  24
  25 do_configure_prepend() {
  26         # remove Werror from VFS_CFLAGS
  27         sed -i s:-Werror::g configure.in
  28
  29         # G_GNUC_FUNCTION is deprecated
  30         sed -i -e s,-DG_DISABLE_DEPRECATED,-DSED_ROCKS_DUDE, */Makefile.am
  31
  32         touch gtk-doc.make
  33 }
  34
  35 do_stage() {
  36   autotools_stage_all
  37 }
  38
  39 PACKAGES_DYNAMIC = "osso-gnome-vfs-plugin-*"
  40
  41 python populate_packages_prepend () {
  42         print bb.data.getVar('FILES_osso-gnome-vfs', d, 1)
  43
  44         plugindir = bb.data.expand('${libdir}/gnome-vfs-2.0/modules/', d)
  45         do_split_packages(d, plugindir, '^lib(.*)\.so$', 'osso-gnome-vfs-plugin-%s', 'OSSO GNOME VFS plugin for %s')
  46 }
  47
  48 FILES_${PN} += "${datadir}/dbus-1"
  49 FILES_${PN}-dbg += " ${libdir}/gnome-vfs-2.0/modules/.debug/lib*.so"
  50 FILES_${PN}-dev += " ${libdir}/gnome-vfs-2.0/include ${libdir}/gnome-vfs-2.0/modules/lib*.a ${libdir}/gnome-vfs-2.0/modules/lib*.la"
  51 FILES_${PN}-doc += " ${datadir}/gtk-doc"