code.vuplus.com Git - vuplus_openembedded/blob - packages/madwifi/madwifi-ng_r.inc

   1 DESCRIPTION = "Linux driver for 802.11a/b/g universal NIC cards using Atheros chip sets"
   2 SECTION = "base"
   3 PRIORITY = "optional"
   4 LICENSE = "GPL"
   5 RDEPENDS = "kernel (${KERNEL_VERSION})"
   6 DEPENDS = "virtual/kernel"
   7 PR="r4"
   8
   9 WACKELF_SRC_URI = ""
  10 WACKELF_SRC_URI_ixp4xx = " file://20-xscale-VFP-wackelf.patch;patch=1"
  11 WACKELF_SRC_URI_compulab-pxa270 = " file://20-xscale-VFP-wackelf.patch;patch=1"
  12
  13 SRC_URI = "http://snapshots.madwifi.org/${PN}/${PN}-${PV}.tar.gz \
  14            file://10-xscale-be-elf-copts.patch;patch=1 \
  15            file://10-xscale-le-elf-copts.patch;patch=1 \
  16            file://10-sh4-le-elf-copts.patch;patch=1 \
  17            ${WACKELF_SRC_URI}"
  18
  19 S = "${WORKDIR}/${PN}-${PV}"
  20
  21 inherit module-base
  22
  23 ARCH_efika="powerpc"
  24 ARCH_dht-walnut="ppc"
  25 ARCH_magicbox="ppc"
  26
  27 EXTRA_OEMAKE = "LDFLAGS= KERNELPATH=${STAGING_KERNEL_DIR} KERNELRELEASE=${KERNEL_VERSION} TOOLPREFIX=${TARGET_PREFIX}"
  28
  29 EXTRA_OEMAKE_prepend_ixp4xxle = "TARGET=xscale-le-elf "
  30 EXTRA_OEMAKE_prepend_ixp4xxbe = "TARGET=xscale-be-elf "
  31
  32
  33 do_compile() {
  34         oe_runmake all
  35 }
  36
  37 do_stage() {
  38         install -d ${STAGING_INCDIR}/${PN}/include
  39         install -d ${STAGING_INCDIR}/${PN}/net80211
  40         cp --dereference include/compat.h ${STAGING_INCDIR}/${PN}/include/
  41         cp --dereference net80211/*.h ${STAGING_INCDIR}/${PN}/net80211/
  42 }
  43
  44 do_install() {
  45         install -d ${D}${sbindir}
  46         oe_runmake DESTDIR=${D} BINDIR=${sbindir} install
  47 }
  48
  49 pkg_postinst() {
  50 if test "x$D" != "x"; then
  51        exit 1
  52 else
  53         depmod -ae
  54 fi
  55 }
  56
  57 PACKAGES = "${PN}-modules ${PN}-tools"
  58 FILES_${PN}-modules = "/lib/modules/"
  59 FILES_${PN}-tools = "/usr/"