code.vuplus.com Git - vuplus_openembedded/blob - packages/lirc/lirc_0.8.0.bb

   1 DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls."
   2 DESCRIPTION_append_lirc = " This package contains the lirc daemon, libraries and tools."
   3 DESCRIPTION_append_lirc-x = " This package contains lirc tools for X11."
   4 DESCRIPTION_append_lirc-exec = " This package contains a daemon that runs programs on IR signals."
   5 DESCRIPTION_append_lirc-remotes = " This package contains some config files for remotes."
   6 DESCRIPTION_append_lirc-nslu2example = " This package contains a working config for RC5 remotes and a modified NSLU2."
   7 SECTION = "console/network"
   8 PRIORITY = "optional"
   9 HOMEPAGE = "http://www.lirc.org"
  10 LICENSE = "GPL"
  11 DEPENDS = "virtual/kernel virtual/libx11 libxau libsm libice"
  12 DEPENDS_nslu2 = "virtual/kernel lirc-modules"
  13 RDEPENDS = "lirc-modules"
  14 RDEPENDS_lirc-x = "lirc"
  15 RDEPENDS_lirc-exec = "lirc"
  16 RDEPENDS_lirc-nslu2example = "lirc lirc-exec"
  17 RRECOMMENDS_lirc = "lirc-exec"
  18 PR = "r4"
  19
  20 SRC_URI = "${SOURCEFORGE_MIRROR}/lirc/lirc-${PV}.tar.gz \
  21            file://lircd.init file://lircmd.init file://lircexec.init"
  22 SRC_URI_append_nslu2 = " file://lircd.conf_nslu2 file://lircrc_nslu2"
  23
  24 S = "${WORKDIR}/lirc-${PV}"
  25
  26 inherit autotools module-base update-rc.d
  27
  28 INITSCRIPT_PACKAGES = "lirc lirc-exec"
  29 INITSCRIPT_NAME = "lircd"
  30 INITSCRIPT_PARAMS = "defaults 20"
  31 INITSCRIPT_NAME_lirc-exec = "lircexec"
  32 INITSCRIPT_PARAMS_lirc-exec = "defaults 21"
  33
  34 require lirc-config.inc
  35
  36 EXTRA_OEMAKE = 'SUBDIRS="daemons tools"'
  37
  38 do_stage() {
  39         oe_libinstall -so -C tools liblirc_client ${STAGING_LIBDIR}
  40         install -d ${STAGING_INCDIR}/lirc/
  41         install -m 0644 tools/lirc_client.h ${STAGING_INCDIR}/lirc/
  42 }
  43
  44 do_install_append() {
  45         install -d ${D}${sysconfdir}/init.d
  46         install ${WORKDIR}/lircd.init ${D}${sysconfdir}/init.d/lircd
  47         install ${WORKDIR}/lircexec.init ${D}${sysconfdir}/init.d/lircexec
  48         install -d ${D}${datadir}/lirc/
  49         cp -pPR ${S}/remotes ${D}${datadir}/lirc/
  50         rm -rf ${D}/dev
  51 }
  52
  53 do_install_append_nslu2() {
  54         install -d ${D}${sysconfdir}
  55         install ${WORKDIR}/lircd.conf_nslu2 ${D}${sysconfdir}/lircd.conf
  56         install ${WORKDIR}/lircrc_nslu2 ${D}${sysconfdir}/lircrc
  57 }
  58
  59 PACKAGES =+ "lirc-x lirc-exec lirc-remotes"
  60 PACKAGES_prepend_nslu2 = "lirc-nslu2example "
  61
  62 FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug"
  63 FILES_${PN} = "${bindir} ${sbindir} ${libdir} ${sysconfdir}/init.d"
  64 FILES_lirc-x = "${bindir}/irxevent ${bindir}/xmode2"
  65 FILES_lirc-exec = "${bindir}/irexec ${sysconfdir}/init.d/lircexec"
  66 FILES_lirc-remotes = "${datadir}/lirc/remotes"
  67 FILES_lirc-nslu2example = "${sysconfdir}/lircd.conf ${sysconfdir}/lircrc"
  68 CONFFILES_lirc-nslu2example = "${FILES_lirc-nslu2example}"