code.vuplus.com Git - vuplus_openembedded/blob - packages/linux/linux_2.6.24.bb

   1 require linux.inc
   2
   3 # Mark archs/machines that this kernel supports
   4 DEFAULT_PREFERENCE = "-1"
   5 DEFAULT_PREFERENCE_gesbc-9302 = "1"
   6 DEFAULT_PREFERENCE_mpc8313e-rdb = "1"
   7 DEFAULT_PREFERENCE_simpad = "1"
   8 DEFAULT_PREFERENCE_atngw100 = "1"
   9 DEFAULT_PREFERENCE_at32stk1000 = "1"
  10 DEFAULT_PREFERENCE_ts72xx = "1"
  11
  12 PR = "r12"
  13
  14 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-2.6.24.tar.bz2 \
  15            http://kamikaze.waninkoko.info/patches/2.6.24/kamikaze1/broken-out/squashfs-lzma-2.6.24.patch;patch=1 \
  16            file://defconfig"
  17
  18 # Moved away temporarely until committed properly (work in progress).
  19 #           file://powerpc-clockres.patch;patch=1 \
  20 #           file://leds-cpu-activity.patch;patch=1 \
  21 #           file://leds-cpu-activity-powerpc.patch;patch=1 \
  22
  23 SRC_URI_append_simpad = "\
  24            file://linux-2.6.24-SIMpad-GPIO-MMC-mod.patch;patch=1 \
  25            file://linux-2.6.24-SIMpad-battery-old-way-but-also-with-sysfs.patch;patch=1 \
  26            file://linux-2.6.24-SIMpad-cs3-simpad.patch;patch=1 \
  27            file://linux-2.6.24-SIMpad-mq200.patch;patch=1 \
  28            file://linux-2.6.24-SIMpad-pcmcia.patch;patch=1 \
  29            file://linux-2.6.24-SIMpad-serial-gpio_keys-and-cs3-ro.patch;patch=1 \
  30            file://linux-2.6.24-SIMpad-ucb1x00-switches.patch;patch=1 \
  31            file://linux-2.6.24-SIMpad-ucb1x00-ts-supend-and-accuracy.patch;patch=1 \
  32            file://linux-2.6.24-SIMpad-hostap_cs-shared-irq.patch;patch=1 \
  33            file://linux-2.6.24-SIMpad-orinoco_cs-shared-irq.patch;patch=1 \
  34            file://linux-2.6.24-SIMpad-rtc-sa1100.patch;patch=1 \
  35            file://connectplus-remove-ide-HACK.patch;patch=1 \
  36            file://collie-kexec.patch;patch=1 \
  37            file://export_atags-r2.patch;patch=1 \
  38            "
  39
  40 SRC_URI_append_gesbc-9302 = " \
  41         file://0001-gesbc-nand.patch;patch=1 \
  42         file://0002-gesbc-eth-platform.patch;patch=1 \
  43         file://0005-ep93xx-reboot.patch;patch=1 \
  44         "
  45
  46 SRC_URI_append_mpc8313e-rdb = "\
  47         file://mpc831x-nand.patch;patch=1 \
  48         file://mpc8313e-rdb-leds.patch;patch=1 \
  49         file://mpc8313e-rdb-rtc.patch;patch=1 \
  50         file://mpc8313e-rdb-cardbus.patch;patch=1 \
  51         "
  52
  53 CMDLINE_gesbc-9302 = "console=ttyAM0 root=mtd5 rootfstype=jffs2 mtdparts=GESBC-NAND:64m(app),-(data)"
  54
  55 SRC_URI_append_cm-x270 = " \
  56         file://0001-cm-x270-match-type.patch;patch=1 \
  57         file://0002-ramdisk_load.patch;patch=1 \
  58         file://0003-mmcsd_large_cards-r0.patch;patch=1 \
  59         file://0004-cm-x270-nand-simplify-name.patch;patch=1 \
  60         file://0005-add-display-set-default-16bpp.patch;patch=1 \
  61         "
  62
  63 SRC_URI_avr32 = "http://avr32linux.org/twiki/pub/Main/LinuxPatches/linux-2.6.24.3.atmel.3.tar.bz2 \
  64                  file://defconfig"
  65 S_avr32 = "${WORKDIR}/linux-2.6.24.3.atmel.3"
  66
  67 SRC_URI_append_ts72xx = "\
  68         file://ep93xx-gpio-interrupt-debounce.diff;patch=1 \
  69         file://ep93xx-i2c-bus.diff;patch=1 \
  70         file://ep93xx-i2c.diff;patch=1 \
  71         file://ep93xx-leds.diff;patch=1 \
  72         file://ep93xx-serial-uartbaud.diff;patch=1 \
  73         file://ep93xx-serial-clocks.diff;patch=1 \
  74         file://ep93xx-timer-accuracy.diff;patch=1 \
  75         file://ep93xx-maverick-uniqid.patch;patch=1 \
  76         file://ep93xx-eth-phylib-framework.patch;patch=1 \
  77         file://ts72xx-nfbit-fix.patch;patch=1 \
  78         file://ts72xx-machine-id-fix.patch;patch=1 \
  79         file://ts72xx-watchdog.patch;patch=1 \
  80         file://ts72xx-use-cpld-reset.patch;patch=1 \
  81         file://ts72xx-rs485.patch;patch=1"
  82
  83 CMDLINE_cm-x270 = "console=${CMX270_CONSOLE_SERIAL_PORT},38400 monitor=1 mem=64M mtdparts=physmap-flash.0:256k(boot)ro,0x180000(kernel),-(root);cm-x270-nand:64m(app),-(data) rdinit=/sbin/init root=mtd3 rootfstype=jffs2"
  84
  85 FILES_kernel-image_gesbc-9302 = ""
  86
  87 python do_compulab_image() {
  88         import os
  89         import os.path
  90         import struct
  91
  92         machine = bb.data.getVar('MACHINE', d, 1)
  93         if machine == "cm-x270":
  94             deploy_dir = bb.data.getVar('DEPLOY_DIR_IMAGE', d, 1)
  95             kernel_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.bin')
  96             img_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270')
  97
  98             fo = open(img_file, 'wb')
  99
 100             image_data = open(kernel_file, 'rb').read()
 101
 102             # first write size into first 4 bytes
 103             size_s = struct.pack('i', len(image_data))
 104
 105             # truncate size if we are running on a 64-bit host
 106             size_s = size_s[:4]
 107
 108             fo.write(size_s)
 109             fo.write(image_data)
 110             fo.close()
 111
 112             os.chdir(deploy_dir)
 113             link_file = bb.data.expand('${KERNEL_IMAGE_SYMLINK_NAME}', d) + '.cmx270'
 114             img_file = bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270'
 115             try:
 116                 os.unlink(link_file)
 117             except:
 118                 pass
 119             os.symlink(img_file, link_file)
 120 }
 121
 122
 123 addtask compulab_image after do_deploy before do_package
 124