code.vuplus.com Git - vuplus_openembedded/blob - packages/linux/linux_2.6.24.bb

   1 require linux.inc
   2
   3 # Mark archs/machines that this kernel supports
   4 DEFAULT_PREFERENCE = "-1"
   5 DEFAULT_PREFERENCE_gesbc-9302 = "1"
   6 DEFAULT_PREFERENCE_cm-x270 = "1"
   7 DEFAULT_PREFERENCE_mpc8313e-rdb = "1"
   8 DEFAULT_PREFERENCE_simpad = "1"
   9 DEFAULT_PREFERENCE_atngw100 = "1"
  10 DEFAULT_PREFERENCE_at32stk1000 = "1"
  11
  12 DEPENDS_append_mpc8313e-rdb = " dtc-native"
  13
  14 PR = "r9"
  15
  16 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-2.6.24.tar.bz2 \
  17            http://kamikaze.waninkoko.info/patches/2.6.24/kamikaze1/broken-out/squashfs-lzma-2.6.24.patch;patch=1 \
  18            file://defconfig"
  19
  20 # Moved away temporarely until committed properly (work in progress).
  21 #           file://powerpc-clockres.patch;patch=1 \
  22 #           file://leds-cpu-activity.patch;patch=1 \
  23 #           file://leds-cpu-activity-powerpc.patch;patch=1 \
  24
  25 SRC_URI_append_simpad = "\
  26            file://linux-2.6.24-SIMpad-GPIO-MMC-mod.patch;patch=1 \
  27            file://linux-2.6.24-SIMpad-battery-old-way-but-also-with-sysfs.patch;patch=1 \
  28            file://linux-2.6.24-SIMpad-cs3-simpad.patch;patch=1 \
  29            file://linux-2.6.24-SIMpad-mq200.patch;patch=1 \
  30            file://linux-2.6.24-SIMpad-pcmcia.patch;patch=1 \
  31            file://linux-2.6.24-SIMpad-serial-gpio_keys-and-cs3-ro.patch;patch=1 \
  32            file://linux-2.6.24-SIMpad-ucb1x00-switches.patch;patch=1 \
  33            file://linux-2.6.24-SIMpad-ucb1x00-ts-supend-and-accuracy.patch;patch=1 \
  34            file://linux-2.6.24-SIMpad-hostap_cs-shared-irq.patch;patch=1 \
  35            file://linux-2.6.24-SIMpad-orinoco_cs-shared-irq.patch;patch=1 \
  36            file://linux-2.6.24-SIMpad-rtc-sa1100.patch;patch=1 \
  37            file://collie-kexec.patch;patch=1 \
  38            file://export_atags-r2.patch;patch=1 \
  39            "
  40
  41 SRC_URI_append_gesbc-9302 = " \
  42         file://0001-gesbc-nand.patch;patch=1 \
  43         file://0002-gesbc-eth-platform.patch;patch=1 \
  44         file://0005-ep93xx-reboot.patch;patch=1 \
  45         "
  46
  47 SRC_URI_append_mpc8313e-rdb = "\
  48         file://mpc831x-nand.patch;patch=1 \
  49         file://mpc8313e-rdb-leds.patch;patch=1 \
  50         file://mpc8313e-rdb-rtc.patch;patch=1"
  51
  52 CMDLINE_gesbc-9302 = "console=ttyAM0 root=mtd5 rootfstype=jffs2 mtdparts=GESBC-NAND:64m(app),-(data)"
  53
  54 SRC_URI_append_cm-x270 = " \
  55         file://0001-cm-x270-match-type.patch;patch=1 \
  56         file://0002-ramdisk_load.patch;patch=1 \
  57         file://0003-mmcsd_large_cards-r0.patch;patch=1 \
  58         file://0004-cm-x270-nand-simplify-name.patch;patch=1 \
  59         file://0005-add-display-set-default-16bpp.patch;patch=1 \
  60         "
  61
  62 SRC_URI_avr32 = "http://avr32linux.org/twiki/pub/Main/LinuxPatches/linux-2.6.24.3.atmel.3.tar.bz2 \
  63                  file://defconfig"
  64 S_avr32 = "${WORKDIR}/linux-2.6.24.3.atmel.3"
  65
  66
  67 CMDLINE_cm-x270 = "console=${CMX270_CONSOLE_SERIAL_PORT},38400 monitor=1 mem=64M mtdparts=physmap-flash.0:256k(boot)ro,0x180000(kernel),-(root);cm-x270-nand:64m(app),-(data) rdinit=/sbin/init root=mtd3 rootfstype=jffs2"
  68
  69 FILES_kernel-image_gesbc-9302 = ""
  70
  71 DEVICETREE_mpc8313e-rdb = "arch/${ARCH}/boot/dts/mpc8313erdb.dts"
  72 DEVICETREE_FLAGS_mpc8313e-rdb = "-R 8 -S 0x3000"
  73 python do_compulab_image() {
  74         import os
  75         import os.path
  76         import struct
  77
  78         machine = bb.data.getVar('MACHINE', d, 1)
  79         if machine == "cm-x270":
  80             deploy_dir = bb.data.getVar('DEPLOY_DIR_IMAGE', d, 1)
  81             kernel_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.bin')
  82             img_file = os.path.join(deploy_dir, bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270')
  83
  84             fo = open(img_file, 'wb')
  85
  86             image_data = open(kernel_file, 'rb').read()
  87
  88             # first write size into first 4 bytes
  89             size_s = struct.pack('i', len(image_data))
  90
  91             # truncate size if we are running on a 64-bit host
  92             size_s = size_s[:4]
  93
  94             fo.write(size_s)
  95             fo.write(image_data)
  96             fo.close()
  97
  98             os.chdir(deploy_dir)
  99             link_file = bb.data.expand('${KERNEL_IMAGE_SYMLINK_NAME}', d) + '.cmx270'
 100             img_file = bb.data.expand('${KERNEL_IMAGE_BASE_NAME}', d) + '.cmx270'
 101             try:
 102                 os.unlink(link_file)
 103             except:
 104                 pass
 105             os.symlink(img_file, link_file)
 106 }
 107
 108
 109 do_devicetree_image() {
 110         if test -n "${DEVICETREE}" ; then
 111             dtc -I dts -O dtb ${DEVICETREE_FLAGS} -o ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb ${DEVICETREE}
 112
 113             cd ${DEPLOY_DIR_IMAGE}
 114             rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 115             ln -sf ${KERNEL_IMAGE_BASE_NAME}.dtb ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 116         fi
 117 }
 118
 119 addtask compulab_image after do_deploy before do_package
 120 addtask devicetree_image after do_deploy before do_package
 121