code.vuplus.com Git - vuplus_openembedded/blob - packages/linux/linux-ixp4xx_2.6.27.8.bb

   1 require linux.inc
   2 require linux-ixp4xx.inc
   3
   4 DEFAULT_PREFERENCE = "-1"
   5 DEFAULT_PREFERENCE_nslu2 = "1"
   6
   7 VANILLA_VERSION = "2.6.27"
   8 KERNEL_RELEASE = "2.6.27.8"
   9
  10 # If you use a rc, you will need to use this:
  11 #PV = "${VANILLA_VERSION}+${KERNEL_RELEASE}+svnr${SRCREV}"
  12
  13 PV = "${KERNEL_RELEASE}+svnr${SRCREV}"
  14 PR = "r1"
  15
  16 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
  17            ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;patch=1 \
  18            svn://svn.nslu2-linux.org/svnroot/kernel/trunk/patches;module=${VANILLA_VERSION};proto=http \
  19            file://fix-install.patch;patch=1 \
  20            file://defconfig-${KERNEL_RELEASE}"
  21
  22 S = "${WORKDIR}/linux-${VANILLA_VERSION}"
  23
  24 # Apply the patches from the nslu2-linux project (after the patches in SRC_URI)
  25 do_postpatch() {
  26         # Move away OE patches which have been already applied.
  27         [ -e patches ] && mv ${S}/patches ${S}/patches.oe
  28         [ -e .pc ]     && mv .pc .pc.oe
  29
  30         # Move the NSLU2 patches in place for quilt and apply them.
  31         mv ${WORKDIR}/${VANILLA_VERSION} ${S}/patches && cd ${S} && quilt push -av
  32
  33         # Store the NSLU2 patches
  34         mv ${S}/patches ${S}/patches.ixp4xx
  35         mv .pc .pc.ixp4xx
  36
  37         # And move back the OE patches
  38         [ -e patches.oe ] && mv ${S}/patches.oe ${S}/patches
  39         [ -e .pc.oe ]     && mv .pc.oe .pc
  40
  41         # Copy the defconfig into ${WORKDIR}
  42         mv ${WORKDIR}/defconfig-${KERNEL_RELEASE} ${WORKDIR}/defconfig
  43 }
  44
  45 addtask postpatch after do_patch before do_configure