code.vuplus.com Git - vuplus_openembedded/blob - packages/libpcre/libpcre_7.6.bb

   1 DESCRIPTION = "Perl-compatible regular expression library. PCRE has its own native \
   2 API, but a set of 'wrapper' functions that are based on the POSIX API \
   3 are also supplied in the library libpcreposix. Note that this just \
   4 provides a POSIX calling interface to PCRE; the regular expressions \
   5 themselves still follow Perl syntax and semantics. The header file for \
   6 the POSIX-style functions is called pcreposix.h."
   7 SECTION = "devel"
   8 FILE_PR = "r3"
   9 LICENSE = "BSD"
  10 SRC_URI = "${SOURCEFORGE_MIRROR}/pcre/pcre-${PV}.tar.bz2 \
  11            file://pcre-cross.patch;patch=1"
  12 S = "${WORKDIR}/pcre-${PV}"
  13
  14 PROVIDES = "pcre"
  15
  16 inherit autotools binconfig
  17
  18 PARALLEL_MAKE = ""
  19
  20 LEAD_SONAME = "libpcre.so"
  21 CFLAGS_append = " -D_REENTRANT"
  22 CXXFLAGS_powerpc += "-lstdc++"
  23 EXTRA_OECONF = " --with-link-size=2 --enable-newline-is-lf --with-match-limit=10000000 --enable-rebuild-chartables --enable-utf8"
  24
  25 do_compile () {
  26         # stop libtool from trying to link with host libraries - fix from #33
  27         # this resolve build problem on amd64 - #1015
  28         if [ -e ${S}/${TARGET_SYS}-libtool ] ; then
  29                 sed -i 's:-L\$:-L${STAGING_LIBDIR} -L\$:' ${S}/${TARGET_SYS}-libtool
  30         else
  31                 ln -sf ${S}/libtool ${S}/${TARGET_SYS}-libtool
  32                 sed -i 's:-L\$:-L${STAGING_LIBDIR} -L\$:' ${S}/${TARGET_SYS}-libtool
  33         fi
  34
  35         # The generation of dftables can lead to timestamp problems with ccache
  36         # because the generated config.h seems newer.  It is sufficient to ensure that the
  37         # attempt to build dftables inside make will actually work (foo_FOR_BUILD is
  38         # only used for this).
  39         oe_runmake CC_FOR_BUILD="${BUILD_CC}" CFLAGS_FOR_BUILD="-DLINK_SIZE=2 -I${S}/include" LINK_FOR_BUILD="${BUILD_CC} -L${S}/lib"
  40 }
  41
  42 do_stage () {
  43         oe_libinstall -a -so libpcre ${STAGING_LIBDIR}
  44         oe_libinstall -a -so libpcreposix ${STAGING_LIBDIR}
  45         install -m 0644 pcre.h ${STAGING_INCDIR}/
  46         install -m 0644 pcreposix.h ${STAGING_INCDIR}/
  47         install -d ${STAGING_BINDIR_NATIVE}
  48         install -m 0755 ${S}/dftables ${STAGING_BINDIR_NATIVE}/
  49 }
  50
  51 FILES_${PN} = "${libdir}/lib*.so.*"
  52 FILES_${PN}-dev += "${bindir}/*"