code.vuplus.com Git - vuplus_openembedded/blob - packages/libowl/libowl_svn.bb

   1 # This recipe builds libowl and then stages the header and static lib;
   2 # it intentionally does not stage the shared lib and create a package.
   3 #
   4 # Libowl is currently a 'cut and paste' library; this package makes our
   5 # life a touch easier by not having to patch the source directly into
   6 # applications; instead we add -lowl to the linker cmdline. Also, when
   7 # we eventually make libowl into a normal shared library, this package
   8 # will make that transition rather simple.
   9
  10 DESCRIPTION = "OpenedHand Widget Library"
  11 HOMEPAGE = "http://www.o-hand.com"
  12 LICENSE = "LGPL"
  13 SECTION = "libs"
  14 DEPENDS = "gtk+"
  15 PV = "0.0+svnr${SRCREV}"
  16 FILE_PR = "r3"
  17
  18 PACKAGES = ""
  19
  20 SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=${PN};proto=http"
  21
  22 S = "${WORKDIR}/${PN}"
  23
  24 inherit autotools pkgconfig
  25
  26 do_compile_prepend() {
  27         # have to unstage the library first so that the tests build
  28         rm -f ${STAGING_LIBDIR}/libowl*
  29         rm -f ${STAGING_INCDIR}/owl*
  30 }
  31
  32 do_stage() {
  33         headers=`eval ls libowl/owl*.h`
  34         for header in $headers; do
  35                 hdr_base=`eval basename $header`
  36                 install -m 644 $header ${STAGING_INCDIR}/$hdr_base
  37         done
  38         install -m 644 libowl/.libs/libowl.a ${STAGING_LIBDIR}/
  39 }