code.vuplus.com Git - vuplus_openembedded/blob - packages/libopie/libopie2.inc

   1 DESCRIPTION = "Base libraries for the Open Palmtop Integrated Environment"
   2 HOMEPAGE = "http://opie.handhelds.org"
   3 SECTION = "opie/libs"
   4 LICENSE = "LGPL"
   5 I18N_FILES = "libopiecore2.ts libopiesecurity2.ts"
   6 DEPENDS = "libqpe-opie libpcap sqlite3 bluez-libs"
   7 PROVIDES = "libopiecore2 libopiedb2 libopiemm2 libopiesecurity2 libopienet2 libopiepim2 libopieui2"
   8
   9 S = "${WORKDIR}/libopie2"
  10
  11 inherit opie
  12
  13 PARALLEL_MAKE = ""
  14
  15 #FIXME: Add machine specific bits here. Best use oe_machinstall and read from a given file
  16
  17 EXTRA_QMAKEVARS_POST += 'DEFINES+=OPIE_NEW_MALLOC \
  18                         DEFINES+="OPIE_SOUND_FRAGMENT_SHIFT=16" \
  19                         DEFINES+=OPIE_NO_ERASE_RECT_HACKFIX \
  20                         LIBS+=-L${S} LIBS+="-Wl,-rpath-link,${S}"'
  21
  22 #NOTE: We no longer enable the sqlite PIM backend here, since a) using it means no sync and b) it's too large for 16MB images
  23 EXTRA_QMAKEVARS_PRE += 'ENABLE_SQL_PIM_BACKEND=n'
  24
  25 MODULES = "opiecore opiedb opiemm opienet opiepim opiesecurity opieui opiebluez"
  26 LIBS    = "core2    db2    mm2    net2    pim2    security2    ui2 bluez2"
  27 PRIVATE = "opimcontactsortvector.h opimoccurrence_p.h opimsortvector.h opimtodosortvector.h vobject_p.h opimeventsortvector.h"
  28
  29 # uclibc doesn't have backtrace()
  30 python __anonymous () {
  31     import bb, re
  32     if (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None):
  33         bb.data.setVar("EXTRA_QMAKEVARS_POST_append", " DEFINES+=OPIE_NO_BACKTRACE ", d)
  34 }
  35
  36 do_compile() {
  37         install -d ${STAGING_INCDIR}/opie2
  38         install -d ${STAGING_INCDIR}/opie2/private
  39         for module in ${MODULES}
  40         do
  41             cd $module
  42             for i in `find . -name "*.h"`
  43             do
  44                 install -m 0644 $i ${STAGING_INCDIR}/opie2/`basename $i`
  45             done
  46             cd ..
  47         done
  48
  49         for header in ${PRIVATE}
  50         do
  51                 install -m 0644 opiepim/private/$header ${STAGING_INCDIR}/opie2/private/
  52         done
  53
  54         oe_runmake MOC=${STAGING_BINDIR_NATIVE}/moc UIC=${STAGING_BINDIR_NATIVE}/uic DESTDIR=${S}
  55 }
  56
  57 do_stage() {
  58         for f in ${LIBS}
  59         do
  60                 oe_libinstall -so libopie$f ${STAGING_LIBDIR}/
  61         done
  62         install -m 0644 ${WORKDIR}/include.pro ${OPIEDIR}/include.pro
  63         # special case for uic-created header files
  64         install -m 0644 opiepim/ui/opimrecurrencebase.h ${STAGING_INCDIR}/opie2/
  65         install -m 0644 opieui/otimepickerbase.h ${STAGING_INCDIR}/opie2/
  66         install -m 0644 opiepim/core/opimtemplatebase.h ${STAGING_INCDIR}/opie2/
  67 }
  68
  69 do_install() {
  70         install -d ${D}${palmtopdir}/lib
  71         for f in ${LIBS}
  72         do
  73                 oe_libinstall -so libopie$f ${D}${palmtopdir}/lib
  74         done
  75 }
  76
  77 PACKAGES = "libopiecore2 libopiedb2 libopiesecurity2 libopiemm2 libopienet2 libopiepim2 libopieui2 libopiebluez2"
  78
  79 DESCRIPTION_libopiecore2 = "Opie Development Platform 1.x Core Library"
  80 FILES_libopiecore2 = "${palmtopdir}/lib/libopiecore2.so*"
  81 DESCRIPTION_libopiedb2 = "Opie Development Platform 1.x Database Library"
  82 FILES_libopiedb2 = "${palmtopdir}/lib/libopiedb2.so*"
  83 DESCRIPTION_libopiemm2 = "Opie Development Platform 1.x Multimedia Library"
  84 FILES_libopiemm2 = "${palmtopdir}/lib/libopiemm2.so*"
  85 DESCRIPTION_libopienet2 = "Opie Development Platform 1.x Network Library"
  86 FILES_libopienet2 = "${palmtopdir}/lib/libopienet2.so*"
  87 DESCRIPTION_libopiepim2 = "Opie Development Platform 1.x PIM Library"
  88 FILES_libopiepim2 = "${palmtopdir}/lib/libopiepim2.so*"
  89 DESCRIPTION_libopieui2 = "Opie Development Platform 1.x User Interface Library"
  90 FILES_libopieui2 = "${palmtopdir}/lib/libopieui2.so*"
  91 DESCRIPTION_libopiesecurity2 = "Opie Development Platform 1.x Security Library"
  92 FILES_libopiesecurity2 = "${palmtopdir}/lib/libopiesecurity2.so*"
  93 DESCRIPTION_libopiebluez2 = "Opie Development Platform 1.x Bluetooth Library"
  94 FILES_libopiebluez2 = "${palmtopdir}/lib/libopiebluez2.so*"
  95