code.vuplus.com Git - vuplus_openembedded/blob - packages/krb/krb5_1.6.3.bb

   1 DESCRIPTION = "A network authentication protocol"
   2 HOMEPAGE = "http://web.mit.edu/Kerberos/"
   3 SECTION = "console/network"
   4 PR = "r3"
   5 LICENSE = "MIT"
   6 DEPENDS = "perl-native ncurses e2fsprogs-libs"
   7
   8 inherit autotools binconfig
   9
  10 SRC_URI = "http://web.mit.edu/kerberos/dist/krb5/1.6/krb5-1.6.3-signed.tar"
  11 S = "${WORKDIR}/${PN}-${PV}/src/"
  12
  13 # Will clean this up...
  14 EXTRA_OECONF += " krb5_cv_attr_constructor_destructor=yes ac_cv_func_regcomp=yes \
  15                     ac_cv_printf_positional=yes ac_cv_file__etc_environment=yes \
  16                     ac_cv_file__etc_TIMEZONE=no --with-system-et"
  17 CFLAGS_append += "-DDESTRUCTOR_ATTR_WORKS=1 -I${STAGING_INCDIR}/et"
  18 LDFLAGS_append += "-lpthread"
  19
  20 FILES_${PN}-doc += /usr/share/examples
  21
  22 do_configure() {
  23         tar xzf ${WORKDIR}/krb5-1.6.3.tar.gz -C ${WORKDIR}/
  24         oe_runconf
  25 }
  26
  27 do_install_append () {
  28         mv ${D}${bindir}/ftp ${D}${bindir}/ftp.${PN}
  29         mv ${D}${sbindir}/ftpd ${D}${sbindir}/ftpd.${PN}
  30         mv ${D}${bindir}/telnet ${D}${bindir}/telnet.${PN}
  31         mv ${D}${sbindir}/telnetd ${D}${sbindir}/telnetd.${PN}
  32 }
  33
  34 pkg_postinst_${PN} () {
  35 #!/bin/sh
  36         update-alternatives --install ${bindir}/ftp ftp ftp.${PN} 100
  37         update-alternatives --install ${sbindir}/ftpd ftpd ftpd.${PN} 100
  38         update-alternatives --install ${bindir}/telnet telnet telnet.${PN} 100
  39         update-alternatives --install ${sbindir}/telnetd telnetd telnetd.${PN} 100
  40 }
  41
  42 pkg_prerm_${PN} () {
  43 #!/bin/sh
  44         update-alternatives --remove ftp ftp.${PN} 100
  45         update-alternatives --remove ftpd ftpd.${PN} 100
  46         update-alternatives --remove telnet telnet.${PN} 100
  47         update-alternatives --remove telnetd telnetd.${PN} 100
  48 }
  49
  50 do_stage() {
  51         oe_libinstall -so -C util/support libkrb5support ${STAGING_LIBDIR}
  52         oe_libinstall -so -C util/et libcom_err ${STAGING_LIBDIR}
  53         oe_libinstall -so -C lib/crypto libk5crypto ${STAGING_LIBDIR}
  54         oe_libinstall -so -C lib/krb5 libkrb5 ${STAGING_LIBDIR}
  55         oe_libinstall -so -C lib/des425 libdes425 ${STAGING_LIBDIR}
  56         oe_libinstall -so -C lib/krb4 libkrb4 ${STAGING_LIBDIR}
  57         oe_libinstall -so -C lib/gssapi libgssapi_krb5 ${STAGING_LIBDIR}
  58         oe_libinstall -so -C lib/rpc libgssrpc ${STAGING_LIBDIR}
  59         oe_libinstall -so -C lib/kdb libkdb5 ${STAGING_LIBDIR}
  60         oe_libinstall -so -C lib/kadm5/clnt libkadm5clnt ${STAGING_LIBDIR}
  61         oe_libinstall -so -C lib/kadm5/srv libkadm5srv ${STAGING_LIBDIR}
  62
  63         install -d ${STAGING_INCDIR}/krb5
  64         for X in krb5.h locate_plugin.h
  65         do
  66                 install -m 0644 ${S}/include/krb5/$X ${STAGING_INCDIR}/krb5/$X
  67         done
  68
  69         install -d ${STAGING_INCDIR}/gssapi
  70         for X in gssapi_generic.h gssapi.h gssapi_krb5.h
  71         do
  72                 install -m 0644 ${S}/include/gssapi/$X ${STAGING_INCDIR}/gssapi/$X
  73         done
  74         install -m 0644 ${S}/lib/gssapi/mechglue/mechglue.h ${STAGING_INCDIR}/gssapi/mechglue.h
  75
  76         install -d ${STAGING_INCDIR}/kerberosIV
  77         for X in krb.h des.h mit-copyright.h krb_err.h kadm_err.h
  78         do
  79                 install -m 0644 ${S}/include/kerberosIV/$X ${STAGING_INCDIR}/kerberosIV/$X
  80         done
  81
  82         install -d ${STAGING_INCDIR}/gssrpc
  83         for X in auth.h auth_gss.h auth_gssapi.h auth_unix.h clnt.h netdb.h pmap_clnt.h pmap_prot.h pmap_rmt.h rename.h rpc.h rpc_msg.h svc.h svc_auth.h xdr.h types.h
  84         do
  85                 install -m 0644 ${S}/include/gssrpc/$X ${STAGING_INCDIR}/gssrpc/$X
  86         done
  87
  88         # com_err.h needs to be added here if you choose to use this builtin
  89         for X in krb5.h profile.h gssapi.h
  90         do
  91                 install -m 0644 ${S}/include/$X ${STAGING_INCDIR}/$X
  92         done
  93 }