code.vuplus.com Git - vuplus_openembedded/blob - packages/ixp4xx/ixp4xx-csr_1.5.bb

   1 # Intel ixp4xx access library software.  Note that this has an Intel
   2 # license which restricts its use.
   3 HOMEPAGE = "http://www.intel.com/design/network/products/npfamily/ixp420.htm"
   4 LICENSE = "http://www.intel.com/design/network/swsup/np_sla/ixp400.htm"
   5 LICENSE_HOMEPAGE = "http://www.intel.com/design/network/products/npfamily/ixp425swr1.htm"
   6 # You must download the following software to your OpenEmbedded downloads
   7 # directory before using this package:
   8 #
   9 #       ixp400AccessLibrary-1_5.zip
  10 #       ixp400NpeLibrary-1_5.zip
  11 #
  12 # To do this go to the LICENSE_HOMEPAGE above, register/login (using a
  13 # web browser which is supported by the login page), this will give you
  14 # access to the web page from which you can download the software - you
  15 # need the: "Intel® IXP400 Software and RedBoot* Boot Loader" and, from
  16 # this the "Intel Hardware Access Software" and "NPE Microcode" (both
  17 # versions 1.5, encryption is not required.)
  18 #
  19 # Store the files with the names given below in your downloads directory
  20 #
  21 SRC_URI = "http://www.intel.com/Please-Read-The-BB-File/ixp400AccessLibrary-1_5.zip"
  22 SRC_URI += "http://www.intel.com/Please-Read-The-BB-File/ixp400NpeLibrary-1_5.zip"
  23 SRC_URI += "file://2.6.patch;patch=1"
  24 DEPENDS = "ixp-osal"
  25 S = "${WORKDIR}/ixp400_xscale_sw"
  26 PR = "r1"
  27
  28 COMPATIBLE_HOST = "^armeb-linux.*"
  29 COMPATIBLE_MACHINE = "(nslu2|ixp4xx)"
  30
  31 inherit module
  32
  33 OSAL_PATH = "lib/linux/linuxbe/ixp400"
  34 # This is a somewhat arbitrary choice:
  35 OSAL_DIR = "${STAGING_KERNEL_DIR}/ixp_osal"
  36
  37 EXTRA_OEMAKE = "'CC=${KERNEL_CC}' \
  38                 'LD=${KERNEL_LD}' \
  39                 'AR=${AR}' \
  40                 'IX_XSCALE_SW=${S}' \
  41                 'IX_TARGET=linuxbe' \
  42                 'IX_MPHY=1' \
  43                 'IX_MPHYSINGLEPORT=1' \
  44                 'LINUX_SRC=${STAGING_KERNEL_DIR}' \
  45                 'LINUX_CROSS_COMPILE=${HOST_PREFIX}' \
  46                 'OSAL_DIR=${OSAL_DIR}' \
  47                 'OSAL_IMAGE=${OSAL_DIR}/${OSAL_PATH}/libosal.a' \
  48                 'OSAL_MODULE=${OSAL_DIR}/${OSAL_PATH}/ixp_osal.o' \
  49                 "
  50
  51 do_compile () {
  52         oe_runmake ixp400.ko
  53 }
  54
  55 do_stage () {
  56         install -d ${STAGING_INCDIR}/linux/ixp4xx-csr
  57         install -m 0644 src/include/*.h ${STAGING_INCDIR}/linux/ixp4xx-csr/
  58 }
  59
  60 do_install () {
  61         install -d ${D}${base_libdir}/modules/${KERNEL_VERSION}/drivers/ixp400
  62         install -m 0644 lib/linuxbe/ixp400.ko ${D}${base_libdir}/modules/${KERNEL_VERSION}/drivers/ixp400/
  63 }