code.vuplus.com Git - vuplus_openembedded/blob - packages/images/fso-image.bb

   1 #------------------------------------------------------
   2 # freesmartphone.org Image Recipe
   3 #------------------------------------------------------
   4
   5 COMPATIBLE_MACHINE = "(om-gta01|om-gta02)"
   6 IMAGE_LINGUAS = ""
   7
   8 # getting the base system up
   9 BASE_INSTALL = "\
  10   ${MACHINE_TASK_PROVIDER} \
  11   netbase \
  12   sysfsutils \
  13   module-init-tools-depmod \
  14   rsync \
  15   screen \
  16   fbset \
  17   fbset-modes \
  18 "
  19
  20 # getting an X window system up
  21 X_INSTALL = "\
  22   e-wm \
  23   illume \
  24   illume-theme-freesmartphone \
  25   ${XSERVER} \
  26   xserver-kdrive-common \
  27   xserver-nodm-init \
  28   xauth \
  29   xhost \
  30   xset \
  31   xrandr \
  32   \
  33   fontconfig-utils \
  34   \
  35   ttf-dejavu-common \
  36   ttf-dejavu-sans \
  37   ttf-dejavu-serif \
  38   \
  39 "
  40
  41 # useful command line tools
  42 TOOLS_INSTALL = "\
  43 #  bash \
  44   dosfstools \
  45   htop \
  46   iptables \
  47   lsof \
  48   mickeydbus \
  49   mickeyterm \
  50   mtd-utils \
  51   nano \
  52   powertop \
  53   s3c24xx-gpio \
  54   sysstat \
  55 "
  56
  57 # audio
  58 AUDIO_INSTALL = "\
  59   alsa-oss \
  60   alsa-state \
  61   alsa-utils-aplay \
  62   alsa-utils-amixer \
  63   gst-meta-audio \
  64   gst-plugin-mad \
  65   gst-plugin-modplug \
  66   gst-plugin-sid \
  67   fso-sounds \
  68 "
  69
  70 GTK_INSTALL = "\
  71   openmoko-calculator2 \
  72   openmoko-terminal2 \
  73   gpe-scap \
  74   tangogps-fso \
  75 "
  76
  77 GAMES_INSTALL = "\
  78   numptyphysics \
  79 "
  80
  81 # FIXME these should rather be part of alsa-state,
  82 # once Om stabilizes them...
  83 AUDIO_INSTALL_append_om-gta01 = "\
  84   openmoko-alsa-scenarios \
  85 "
  86 AUDIO_INSTALL_append_om-gta02 = "\
  87   openmoko-alsa-scenarios \
  88 "
  89
  90 # python
  91 PYTHON_INSTALL = "\
  92   task-python-efl \
  93   python-codecs \
  94   python-gst \
  95 "
  96
  97 # zhone
  98 ZHONE_INSTALL = "\
  99   gsm0710muxd \
 100   frameworkd \
 101   zhone \
 102 "
 103
 104 IMAGE_INSTALL = "\
 105   ${BASE_INSTALL} \
 106   ${X_INSTALL} \
 107   ${GTK_INSTALL} \
 108   ${GAMES_INSTALL} \
 109   ${AUDIO_INSTALL} \
 110   ${TOOLS_INSTALL} \
 111   ${PYTHON_INSTALL} \
 112   ${ZHONE_INSTALL} \
 113 "
 114
 115 inherit image
 116
 117 # perform some convenience tweaks to the rootfs
 118 fso_rootfs_postprocess() {
 119     curdir=$PWD
 120     cd ${IMAGE_ROOTFS}
 121     # date/time
 122     date "+%m%d%H%M%Y" >./etc/timestamp
 123     # alias foo
 124     echo "alias pico=nano" >>./etc/profile
 125     echo "alias fso='cd /local/pkg/fso'" >>./etc/profile
 126     echo "alias ipkg='opkg'" >>./etc/profile
 127     # nfs
 128     mkdir -p ./local/pkg
 129     echo >>./etc/fstab
 130     echo "# NFS Host" >>./etc/fstab
 131     echo "192.168.0.200:/local/pkg /local/pkg nfs noauto,nolock,soft,rsize=32768,wsize=32768 0 0" >>./etc/fstab
 132     # fix .desktop files for illume
 133     desktop=`find ./usr/share/applications -name "*.desktop"`
 134     for file in $desktop; do
 135         echo "Categories=Office;" >>$file
 136     done
 137     # minimal gtk theme foo
 138     mkdir -p ./etc/gtk-2.0/
 139     echo 'gtk-font-name = "Sans 5"' >> ./etc/gtk-2.0/gtkrc
 140     cd $curdir
 141 }
 142
 143 ROOTFS_POSTPROCESS_COMMAND += "fso_rootfs_postprocess"