code.vuplus.com Git - vuplus_openembedded/blob - packages/images/fso-image.bb

   1 #------------------------------------------------------
   2 # freesmartphone.org Image Recipe
   3 #------------------------------------------------------
   4
   5 IMAGE_LINGUAS = ""
   6
   7 # getting the base system up
   8 BASE_INSTALL = "\
   9   ${MACHINE_TASK_PROVIDER} \
  10   netbase \
  11   sysfsutils \
  12   module-init-tools-depmod \
  13   rsync \
  14   screen \
  15   fbset \
  16   fbset-modes \
  17 "
  18
  19 # getting an X window system up
  20 X_INSTALL = "\
  21   matchbox-wm \
  22   ${XSERVER} \
  23   xserver-kdrive-common \
  24   xserver-nodm-init \
  25   xauth \
  26   xhost \
  27   xset \
  28   xrandr \
  29   \
  30   fontconfig-utils \
  31   \
  32   ttf-dejavu-common \
  33   ttf-dejavu-sans \
  34   ttf-dejavu-serif \
  35   \
  36 "
  37
  38 # useful command line tools
  39 TOOLS_INSTALL = "\
  40 #  bash \
  41   htop \
  42   mickeyterm \
  43   mplayer \
  44   nano \
  45   powertop \
  46   s3c24xx-gpio \
  47 "
  48
  49 # audio
  50 AUDIO_INSTALL = "\
  51   alsa-oss \
  52   alsa-state \
  53   alsa-utils-aplay \
  54   gst-meta-audio \
  55   gst-plugin-mad \
  56   gst-plugin-modplug \
  57   gst-plugin-sid \
  58   fso-sounds \
  59 "
  60
  61 # FIXME these should rather be part of alsa-state,
  62 # once Om stabilizes them...
  63 AUDIO_INSTALL_append_om-gta01 = "\
  64   openmoko-alsa-scenarios \
  65 "
  66 AUDIO_INSTALL_append_om-gta02 = "\
  67   openmoko-alsa-scenarios \
  68 "
  69
  70 # python
  71 PYTHON_INSTALL = "\
  72   task-python-efl \
  73   python-codecs \
  74   python-gst \
  75 "
  76
  77 # zhone
  78 ZHONE_INSTALL = "\
  79   gsm0710muxd \
  80   frameworkd \
  81   zhone \
  82 "
  83
  84 IMAGE_INSTALL = "\
  85   ${BASE_INSTALL} \
  86   ${X_INSTALL} \
  87   ${AUDIO_INSTALL} \
  88   ${TOOLS_INSTALL} \
  89   ${PYTHON_INSTALL} \
  90   ${ZHONE_INSTALL} \
  91 "
  92
  93 inherit image
  94
  95 # perform some convenience tweaks to the rootfs
  96 mickey_rootfs_postprocess() {
  97     curdir=$PWD
  98     cd ${IMAGE_ROOTFS}
  99     date "+%m%d%H%M%Y" >./etc/timestamp
 100     echo "alias pico=nano" >>./etc/profile
 101     echo "alias fso='cd /local/pkg/fso'" >>./etc/profile
 102     echo "alias ipkg='opkg'" >>./etc/profile
 103     mkdir -p ./local/pkg
 104     echo >>./etc/fstab
 105     echo "# NFS Host" >>./etc/fstab
 106     echo "192.168.0.200:/local/pkg /local/pkg nfs noauto,nolock,soft,rsize=32768,wsize=32768 0 0" >>./etc/fstab
 107     cd $curdir
 108 }
 109
 110 ROOTFS_POSTPROCESS_COMMAND += "mickey_rootfs_postprocess"