code.vuplus.com Git - vuplus_openembedded/blob - packages/images/fso-image.bb

   1 #------------------------------------------------------
   2 # freesmartphone.org Image Recipe
   3 #------------------------------------------------------
   4
   5 IMAGE_LINGUAS = ""
   6
   7 # getting the base system up
   8 BASE_INSTALL = "\
   9   ${MACHINE_TASK_PROVIDER} \
  10   netbase \
  11   sysfsutils \
  12   module-init-tools-depmod \
  13   rsync \
  14   screen \
  15   fbset \
  16   fbset-modes \
  17 "
  18
  19 # getting an X window system up
  20 X_INSTALL = "\
  21   e-wm \
  22   illume \
  23   illume-theme-freesmartphone \
  24   ${XSERVER} \
  25   xserver-kdrive-common \
  26   xserver-nodm-init \
  27   xauth \
  28   xhost \
  29   xset \
  30   xrandr \
  31   \
  32   fontconfig-utils \
  33   \
  34   ttf-dejavu-common \
  35   ttf-dejavu-sans \
  36   ttf-dejavu-serif \
  37   \
  38 "
  39
  40 # useful command line tools
  41 TOOLS_INSTALL = "\
  42 #  bash \
  43   dosfstools \
  44   htop \
  45   iptables \
  46   lsof \
  47   mickeydbus \
  48   mickeyterm \
  49   mtd-utils \
  50   nano \
  51   powertop \
  52   s3c24xx-gpio \
  53 "
  54
  55 # audio
  56 AUDIO_INSTALL = "\
  57   alsa-oss \
  58   alsa-state \
  59   alsa-utils-aplay \
  60   gst-meta-audio \
  61   gst-plugin-mad \
  62   gst-plugin-modplug \
  63   gst-plugin-sid \
  64   fso-sounds \
  65 "
  66
  67 GTK_INSTALL = "\
  68   openmoko-calculator2 \
  69   openmoko-terminal2 \
  70   gpe-scap \
  71   tangogps \
  72 "
  73
  74 # FIXME these should rather be part of alsa-state,
  75 # once Om stabilizes them...
  76 AUDIO_INSTALL_append_om-gta01 = "\
  77   openmoko-alsa-scenarios \
  78 "
  79 AUDIO_INSTALL_append_om-gta02 = "\
  80   openmoko-alsa-scenarios \
  81 "
  82
  83 # python
  84 PYTHON_INSTALL = "\
  85   task-python-efl \
  86   python-codecs \
  87   python-gst \
  88 "
  89
  90 # zhone
  91 ZHONE_INSTALL = "\
  92   gsm0710muxd \
  93   frameworkd \
  94   zhone \
  95 "
  96
  97 IMAGE_INSTALL = "\
  98   ${BASE_INSTALL} \
  99   ${X_INSTALL} \
 100   ${GTK_INSTALL} \
 101   ${AUDIO_INSTALL} \
 102   ${TOOLS_INSTALL} \
 103   ${PYTHON_INSTALL} \
 104   ${ZHONE_INSTALL} \
 105 "
 106
 107 inherit image
 108
 109 # perform some convenience tweaks to the rootfs
 110 fso_rootfs_postprocess() {
 111     curdir=$PWD
 112     cd ${IMAGE_ROOTFS}
 113     # date/time
 114     date "+%m%d%H%M%Y" >./etc/timestamp
 115     # alias foo
 116     echo "alias pico=nano" >>./etc/profile
 117     echo "alias fso='cd /local/pkg/fso'" >>./etc/profile
 118     echo "alias ipkg='opkg'" >>./etc/profile
 119     # nfs
 120     mkdir -p ./local/pkg
 121     echo >>./etc/fstab
 122     echo "# NFS Host" >>./etc/fstab
 123     echo "192.168.0.200:/local/pkg /local/pkg nfs noauto,nolock,soft,rsize=32768,wsize=32768 0 0" >>./etc/fstab
 124     # fix .desktop files for illume
 125     desktop=`find ./usr/share/applications -name "*.desktop"`
 126     for file in $desktop; do
 127         echo "Categories=Office;" >>$file
 128     done
 129     # minimal gtk theme foo
 130     mkdir -p ./etc/gtk-2.0/
 131     echo 'gtk-font-name = "Sans 5"' >> ./etc/gtk-2.0/gtkrc
 132     cd $curdir
 133 }
 134
 135 ROOTFS_POSTPROCESS_COMMAND += "fso_rootfs_postprocess"