code.vuplus.com Git - vuplus_openembedded/blob - packages/images/fso-image.bb

   1 #------------------------------------------------------
   2 # freesmartphone.org Image Recipe
   3 #------------------------------------------------------
   4
   5 IMAGE_LINGUAS = ""
   6
   7 # getting the base system up
   8 BASE_INSTALL = "\
   9   ${MACHINE_TASK_PROVIDER} \
  10   netbase \
  11   sysfsutils \
  12   module-init-tools-depmod \
  13   rsync \
  14   screen \
  15   fbset \
  16   fbset-modes \
  17 "
  18
  19 # getting an X window system up
  20 X_INSTALL = "\
  21   e-wm \
  22   illume \
  23   illume-theme-freesmartphone \
  24   ${XSERVER} \
  25   xserver-kdrive-common \
  26   xserver-nodm-init \
  27   xauth \
  28   xhost \
  29   xset \
  30   xrandr \
  31   \
  32   fontconfig-utils \
  33   \
  34   ttf-dejavu-common \
  35   ttf-dejavu-sans \
  36   ttf-dejavu-serif \
  37   \
  38 "
  39
  40 # useful command line tools
  41 TOOLS_INSTALL = "\
  42 #  bash \
  43   dosfstools \
  44   htop \
  45   iptables \
  46   lsof \
  47   mickeydbus \
  48   mickeyterm \
  49   mtd-utils \
  50   nano \
  51   powertop \
  52   s3c24xx-gpio \
  53   sysstat \
  54 "
  55
  56 # audio
  57 AUDIO_INSTALL = "\
  58   alsa-oss \
  59   alsa-state \
  60   alsa-utils-aplay \
  61   alsa-utils-amixer \
  62   gst-meta-audio \
  63   gst-plugin-mad \
  64   gst-plugin-modplug \
  65   gst-plugin-sid \
  66   fso-sounds \
  67 "
  68
  69 GTK_INSTALL = "\
  70   openmoko-calculator2 \
  71   openmoko-terminal2 \
  72   gpe-scap \
  73   tangogps-fso \
  74 "
  75
  76 GAMES_INSTALL = "\
  77   numptyphysics \
  78 "
  79
  80 # FIXME these should rather be part of alsa-state,
  81 # once Om stabilizes them...
  82 AUDIO_INSTALL_append_om-gta01 = "\
  83   openmoko-alsa-scenarios \
  84 "
  85 AUDIO_INSTALL_append_om-gta02 = "\
  86   openmoko-alsa-scenarios \
  87 "
  88
  89 # python
  90 PYTHON_INSTALL = "\
  91   task-python-efl \
  92   python-codecs \
  93   python-gst \
  94 "
  95
  96 # zhone
  97 ZHONE_INSTALL = "\
  98   gsm0710muxd \
  99   frameworkd \
 100   zhone \
 101 "
 102
 103 IMAGE_INSTALL = "\
 104   ${BASE_INSTALL} \
 105   ${X_INSTALL} \
 106   ${GTK_INSTALL} \
 107   ${GAMES_INSTALL} \
 108   ${AUDIO_INSTALL} \
 109   ${TOOLS_INSTALL} \
 110   ${PYTHON_INSTALL} \
 111   ${ZHONE_INSTALL} \
 112 "
 113
 114 inherit image
 115
 116 # perform some convenience tweaks to the rootfs
 117 fso_rootfs_postprocess() {
 118     curdir=$PWD
 119     cd ${IMAGE_ROOTFS}
 120     # date/time
 121     date "+%m%d%H%M%Y" >./etc/timestamp
 122     # alias foo
 123     echo "alias pico=nano" >>./etc/profile
 124     echo "alias fso='cd /local/pkg/fso'" >>./etc/profile
 125     echo "alias ipkg='opkg'" >>./etc/profile
 126     # nfs
 127     mkdir -p ./local/pkg
 128     echo >>./etc/fstab
 129     echo "# NFS Host" >>./etc/fstab
 130     echo "192.168.0.200:/local/pkg /local/pkg nfs noauto,nolock,soft,rsize=32768,wsize=32768 0 0" >>./etc/fstab
 131     # fix .desktop files for illume
 132     desktop=`find ./usr/share/applications -name "*.desktop"`
 133     for file in $desktop; do
 134         echo "Categories=Office;" >>$file
 135     done
 136     # minimal gtk theme foo
 137     mkdir -p ./etc/gtk-2.0/
 138     echo 'gtk-font-name = "Sans 5"' >> ./etc/gtk-2.0/gtkrc
 139     cd $curdir
 140 }
 141
 142 ROOTFS_POSTPROCESS_COMMAND += "fso_rootfs_postprocess"