code.vuplus.com Git - vuplus_openembedded/blob - packages/gnutls/gnutls.inc

   1 DESCRIPTION = "GNU Transport Layer Security Library"
   2 HOMEPAGE = "http://www.gnu.org/software/gnutls/"
   3 DEPENDS = "zlib libgcrypt lzo"
   4 LICENSE = "LGPL"
   5
   6 SRC_URI = "ftp://ftp.gnutls.org/pub/gnutls/gnutls-${PV}.tar.bz2"
   7
   8 inherit autotools binconfig pkgconfig
   9
  10 EXTRA_OECONF = "--with-included-opencdk --with-included-libtasn1"
  11
  12 # fix wrong dependency
  13 do_configure_prepend() {
  14     sed -i s,gcrypt,libgcrypt, lib/gnutls.pc.in
  15 }
  16
  17 do_stage() {
  18     oe_libinstall -C lib/.libs -so -a libgnutls ${STAGING_LIBDIR}
  19     oe_libinstall -C libextra/.libs -so -a libgnutls-extra ${STAGING_LIBDIR}
  20     oe_libinstall -C libextra/.libs -so -a libgnutls-openssl ${STAGING_LIBDIR}
  21     autotools_stage_includes
  22
  23     install -d ${STAGING_DATADIR}/aclocal
  24     cp ${S}/lib/libgnutls.m4 ${STAGING_DATADIR}/aclocal/
  25     cp ${S}/libextra/libgnutls-extra.m4 ${STAGING_DATADIR}/aclocal/
  26 }
  27
  28 PACKAGES =+ "${PN}-openssl ${PN}-extra ${PN}-bin ${PN}-xx"
  29
  30 FILES_${PN} = "${libdir}/libgnutls.so.*"
  31 FILES_${PN}-bin = "${bindir}/gnutls-serv \
  32                    ${bindir}/gnutls-cli \
  33                    ${bindir}/srptool \
  34                    ${bindir}/psktool \
  35                    ${bindir}/certtool \
  36                    ${bindir}/gnutls-srpcrypt"
  37
  38 FILES_${PN}-dev += "${bindir}/*-config ${bindir}/gnutls-cli-debug"
  39 FILES_${PN}-extra = "${libdir}/libgnutls-extra.so.*"
  40 FILES_${PN}-openssl = "${libdir}/libgnutls-openssl.so.*"
  41 FILES_${PN}-xx = "${libdir}/libgnutlsxx.so.*"