code.vuplus.com Git - vuplus_openembedded/blob - packages/glibc/glibc_2.4.bb

   1 DESCRIPTION = "GNU C Library"
   2 HOMEPAGE = "http://www.gnu.org/software/libc/libc.html"
   3 LICENSE = "LGPL"
   4 SECTION = "libs"
   5 PRIORITY = "required"
   6 PR = "r12"
   7
   8 #add the hosts that are confirmed to be working to COMPATIBLE_HOSTi
   9 COMPATIBLE_HOST = '(i.86.*-linux|sh.*-linux)'
  10 DEFAULT_PREFERENCE_arm = "-1"
  11
  12 # the -isystem in bitbake.conf screws up glibc do_stage
  13 BUILD_CPPFLAGS = "-I${STAGING_DIR}/${BUILD_SYS}/include"
  14 TARGET_CPPFLAGS = "-I${STAGING_DIR}/${TARGET_SYS}/include"
  15
  16
  17 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/glibc-2.4"
  18
  19 GLIBC_ADDONS ?= "ports,nptl,libidn"
  20 GLIBC_EXTRA_OECONF ?= ""
  21
  22 GLIBC_BROKEN_LOCALES = "sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN"
  23
  24 #
  25 # For now, we will skip building of a gcc package if it is a uclibc one
  26 # and our build is not a uclibc one, and we skip a glibc one if our build
  27 # is a uclibc build.
  28 #
  29 # See the note in gcc/gcc_3.4.0.oe
  30 #
  31
  32 python __anonymous () {
  33     import bb, re
  34     uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
  35     if uc_os:
  36         raise bb.parse.SkipPackage("incompatible with target %s" %
  37                                    bb.data.getVar('TARGET_OS', d, 1))
  38 }
  39
  40 # nptl needs unwind support in gcc, which can't be built without glibc.
  41 PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
  42 PROVIDES += "virtual/libintl virtual/libiconv"
  43 DEPENDS = "${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
  44 RDEPENDS_${PN}-dev = "linux-libc-headers-dev"
  45 INHIBIT_DEFAULT_DEPS = "1"
  46
  47 #          file://noinfo.patch;patch=1
  48 #          file://ldconfig.patch;patch=1;pnum=0
  49 #          file://arm-machine-gmon.patch;patch=1;pnum=0 \
  50 #          \
  51 #          file://arm-ioperm.patch;patch=1;pnum=0 \
  52 #          file://ldd.patch;patch=1;pnum=0 \
  53 SRC_URI = "ftp://ftp.gnu.org/pub/gnu/glibc/glibc-2.4.tar.bz2 \
  54            ftp://ftp.gnu.org/pub/gnu/glibc/glibc-ports-2.4.tar.bz2 \
  55            ftp://ftp.gnu.org/pub/gnu/glibc/glibc-libidn-2.4.tar.bz2 \
  56            file://arm-memcpy.patch;patch=1 \
  57            file://arm-longlong.patch;patch=1 \
  58            file://fhs-linux-paths.patch;patch=1 \
  59            file://dl-cache-libcmp.patch;patch=1 \
  60            file://ldsocache-varrun.patch;patch=1 \
  61            file://nptl-crosscompile.patch;patch=1 \
  62            file://glibc-2.4-compile.patch;patch=1 \
  63            file://glibc-2.4-openat-3.patch;patch=1 \
  64            file://fixup-aeabi-syscalls.patch;patch=1 \
  65            file://zecke-sane-readelf.patch;patch=1 \
  66            file://arm_eabi_ipc_fix.patch;patch=1 \
  67            file://generic-bits_select.h \
  68            file://generic-bits_types.h \
  69            file://generic-bits_typesizes.h \
  70            file://generic-bits_time.h \
  71            file://etc/ld.so.conf \
  72            file://generate-supported.mk"
  73
  74
  75 # Build fails on sh3 and sh4 without additional patches
  76 SRC_URI_append_sh3 = " file://no-z-defs.patch;patch=1"
  77 SRC_URI_append_sh4 = " file://no-z-defs.patch;patch=1"
  78
  79 S = "${WORKDIR}/glibc-2.4"
  80 B = "${WORKDIR}/build-${TARGET_SYS}"
  81
  82 inherit autotools
  83
  84 EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
  85                 --without-cvs --disable-profile --disable-debug --without-gd \
  86                 --enable-clocale=gnu \
  87                 --enable-add-ons=${GLIBC_ADDONS} \
  88                 --with-headers=${STAGING_INCDIR} \
  89                 --without-selinux \
  90                 ${GLIBC_EXTRA_OECONF}"
  91
  92 EXTRA_OECONF += "${@get_glibc_fpu_setting(bb, d)}"
  93
  94 do_munge() {
  95         # Integrate ports and libidn into tree
  96         mv ${WORKDIR}/glibc-ports-${PV} ${S}/ports
  97         mv ${WORKDIR}/glibc-libidn-${PV} ${S}/libidn
  98
  99         # Ports isn't really working... Fix it
 100         # Some of this is rather dirty, but it seems to be the only
 101         # quick way to get this cruft to compile
 102         rm -rf ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
 103         ln -s nptl ${S}/ports/sysdeps/unix/sysv/linux/arm/linuxthreads
 104         cp ${S}/sysdeps/unix/sysv/linux/i386/bits/wchar.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 105         cp ${S}/sysdeps/wordsize-32/bits/wordsize.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 106         cp ${WORKDIR}/generic-bits_select.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/select.h
 107         cp ${WORKDIR}/generic-bits_types.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/types.h
 108         cp ${WORKDIR}/generic-bits_typesizes.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/typesizes.h
 109         cp ${WORKDIR}/generic-bits_time.h ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/time.h
 110         # Copy in generic stuff for not yet implemented headers
 111         for i in ${S}/bits/*.h; do
 112                 F=`basename $i`
 113                 [ "$F" = "local_lim.h" ] && continue
 114                 [ "$F" = "errno.h" ] && continue
 115                 test -e ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/$F || test -e ${S}/ports/sysdeps/arm/bits/$F || test -e ${S}/sysdeps/unix/sysv/linux/bits/$F || test -e ${S}/sysdeps/ieee754/bits/$F || cp $i ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/
 116         done
 117         # This is harmful; we need to get the one from nptl/sysdeps/pthreads
 118         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/libc-lock.h
 119         # Obsoleted by sysdeps/arm/{fpu,eabi}/bits/fenv.h
 120         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/fenv.h
 121         # Obsoleted by sysdeps/gnu/bits/utmp.h
 122         rm -f ${S}/ports/sysdeps/unix/sysv/linux/arm/bits/utmp.h
 123 }
 124
 125 addtask munge before do_patch after do_unpack
 126
 127
 128 do_configure () {
 129 # override this function to avoid the autoconf/automake/aclocal/autoheader
 130 # calls for now
 131 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
 132 # version check and doesn't really help with anything
 133         if [ -z "`which rpcgen`" ]; then
 134                 echo "rpcgen not found.  Install glibc-devel."
 135                 exit 1
 136         fi
 137         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
 138         CPPFLAGS="" oe_runconf
 139 }
 140
 141 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
 142           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
 143           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
 144
 145 do_compile () {
 146         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 147         unset LDFLAGS
 148         base_do_compile
 149         (
 150                 cd ${S}/sunrpc/rpcsvc
 151                 for r in ${rpcsvc}; do
 152                         h=`echo $r|sed -e's,\.x$,.h,'`
 153                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 154                 done
 155         )
 156 }
 157
 158 do_stage() {
 159         rm -f ${STAGING_LIBDIR}/libc.so.6
 160         oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
 161                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 162                    '${STAGING_LIBDIR}/libc.so.6' \
 163                    install-headers install-lib
 164
 165         install -d ${STAGING_INCDIR}/gnu \
 166                    ${STAGING_INCDIR}/bits \
 167                    ${STAGING_INCDIR}/rpcsvc
 168         install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
 169         install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
 170         install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
 171         for r in ${rpcsvc}; do
 172                 h=`echo $r|sed -e's,\.x$,.h,'`
 173                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
 174         done
 175         for i in libc.a libc_pic.a libc_nonshared.a; do
 176                 install -m 0644 ${B}/$i ${STAGING_LIBDIR}/ || die "failed to install $i"
 177         done
 178         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
 179         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so
 180
 181         rm -f ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6
 182         oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
 183                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 184                    '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
 185                    install-headers install-lib
 186
 187         install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
 188                    ${CROSS_DIR}/${TARGET_SYS}/include/bits \
 189                    ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
 190         install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
 191         install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
 192         install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
 193         for r in ${rpcsvc}; do
 194                 h=`echo $r|sed -e's,\.x$,.h,'`
 195                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
 196         done
 197
 198         for i in libc.a libc_pic.a libc_nonshared.a; do
 199                 install -m 0644 ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/ || die "failed to install $i"
 200         done
 201         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
 202         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
 203 }
 204
 205 require glibc-package.bbclass