code.vuplus.com Git - vuplus_openembedded/blob - packages/glibc/glibc_2.3.3.bb

   1 require glibc.inc
   2
   3 PR = "r8"
   4
   5 DEFAULT_PREFERENCE_sh3 = "-99"
   6
   7 DEFAULT_PREFERENCE = "-1"
   8 DEFAULT_PREFERENCE_mipsel = "0"
   9
  10 GLIBC_ADDONS ?= "linuxthreads"
  11 GLIBC_EXTRA_OECONF ?= ""
  12
  13 #
  14 # For now, we will skip building of a gcc package if it is a uclibc one
  15 # and our build is not a uclibc one, and we skip a glibc one if our build
  16 # is a uclibc build.
  17 #
  18 # See the note in gcc/gcc_3.4.0.oe
  19 #
  20
  21 python __anonymous () {
  22     import bb, re
  23     uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
  24     if uc_os:
  25         raise bb.parse.SkipPackage("incompatible with target %s" %
  26                                    bb.data.getVar('TARGET_OS', d, 1))
  27 }
  28
  29 PACKAGES = "glibc catchsegv sln nscd ldd localedef glibc-utils glibc-dev glibc-doc glibc-locale libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
  30
  31 # nptl needs unwind support in gcc, which can't be built without glibc.
  32 PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
  33 PROVIDES += "virtual/libintl virtual/libiconv"
  34 DEPENDS = "${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
  35 INHIBIT_DEFAULT_DEPS = "1"
  36
  37 libc_baselibs = "/lib/libc* /lib/libm* /lib/ld* /lib/libpthread* /lib/libresolv* /lib/librt* /lib/libutil* /lib/libnsl* /lib/libnss_files* /lib/libnss_compat* /lib/libnss_dns* /lib/libdl* /lib/libanl* /lib/libBrokenLocale*"
  38
  39 FILES_${PN} = "${sysconfdir} ${libc_baselibs} /sbin/ldconfig ${libexecdir} ${datadir}/zoneinfo"
  40 FILES_ldd = "${bindir}/ldd"
  41 FILES_libsegfault = "/lib/libSegFault*"
  42 FILES_glibc-extra-nss = "/lib/libnss*"
  43 FILES_sln = "/sbin/sln"
  44 FILES_glibc-dev_append = " ${libdir}/*.o ${bindir}/rpcgen"
  45 FILES_nscd = "${sbindir}/nscd*"
  46 FILES_glibc-utils = "${bindir} ${sbindir}"
  47 FILES_glibc-gconv = "${libdir}/gconv"
  48 FILES_catchsegv = "${bindir}/catchsegv"
  49 DEPENDS_catchsegv = "libsegfault"
  50 FILES_glibc-pcprofile = "/lib/libpcprofile.so"
  51 FILES_glibc-thread-db = "/lib/libthread_db*"
  52 FILES_localedef = "${bindir}/localedef"
  53 RPROVIDES_glibc-dev += "libc-dev"
  54
  55 SRC_URI = "ftp://ftp.gnu.org/gnu/glibc/glibc-${PV}.tar.gz \
  56            ftp://ftp.gnu.org/pub/gnu/glibc/glibc-linuxthreads-${PV}.tar.gz \
  57            file://etc/ld.so.conf \
  58            file://generate-supported.mk"
  59
  60 S = "${WORKDIR}/glibc-${PV}"
  61 B = "${WORKDIR}/build-${TARGET_SYS}"
  62
  63 inherit autotools
  64
  65 EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
  66                 --without-cvs --disable-profile --disable-debug --without-gd \
  67                 --enable-clocale=gnu \
  68                 --enable-add-ons=${GLIBC_ADDONS} \
  69                 --with-headers=${CROSS_DIR}/${TARGET_SYS}/include \
  70                 ${GLIBC_EXTRA_OECONF}"
  71
  72 EXTRA_OECONF += "${@get_glibc_fpu_setting(bb, d)}"
  73
  74 glibc_do_unpack () {
  75         mv "${WORKDIR}/linuxthreads" "${WORKDIR}/linuxthreads_db" "${S}/"
  76 }
  77
  78 python do_unpack () {
  79         bb.build.exec_func('base_do_unpack', d)
  80         bb.build.exec_func('glibc_do_unpack', d)
  81 }
  82
  83 do_configure () {
  84 # override this function to avoid the autoconf/automake/aclocal/autoheader
  85 # calls for now
  86 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
  87 # version check and doesn't really help with anything
  88         if [ -z "`which rpcgen`" ]; then
  89                 echo "rpcgen not found.  Install glibc-devel."
  90                 exit 1
  91         fi
  92         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
  93         CPPFLAGS="" oe_runconf
  94 }
  95
  96 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
  97           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
  98           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
  99
 100 do_compile () {
 101         # this really is arm specific
 102         touch ${S}/sysdeps/arm/framestate.c
 103         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 104         unset LDFLAGS
 105         base_do_compile
 106         (
 107                 cd ${S}/sunrpc/rpcsvc
 108                 for r in ${rpcsvc}; do
 109                         h=`echo $r|sed -e's,\.x$,.h,'`
 110                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 111                 done
 112         )
 113 }
 114
 115 do_stage() {
 116         rm -f ${STAGING_LIBDIR}/libc.so.6
 117         oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
 118                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 119                    '${STAGING_LIBDIR}/libc.so.6' \
 120                    install-headers install-lib
 121
 122         install -d ${STAGING_INCDIR}/gnu \
 123                    ${STAGING_INCDIR}/bits \
 124                    ${STAGING_INCDIR}/rpcsvc
 125         install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
 126         install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
 127         install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
 128         for r in ${rpcsvc}; do
 129                 h=`echo $r|sed -e's,\.x$,.h,'`
 130                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
 131         done
 132         for i in libc.a libc_pic.a libc_nonshared.a; do
 133                 install -m 0644 ${B}/$i ${STAGING_LIBDIR}/ || die "failed to install $i"
 134         done
 135         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
 136         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so
 137
 138         rm -f ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6
 139         oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
 140                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 141                    '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
 142                    install-headers install-lib
 143
 144         install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
 145                    ${CROSS_DIR}/${TARGET_SYS}/include/bits \
 146                    ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
 147         install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
 148         install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
 149         install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
 150         for r in ${rpcsvc}; do
 151                 h=`echo $r|sed -e's,\.x$,.h,'`
 152                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
 153         done
 154
 155         for i in libc.a libc_pic.a libc_nonshared.a; do
 156                 install -m 0644 ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/ || die "failed to install $i"
 157         done
 158         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
 159         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
 160 }
 161
 162 require glibc-package.bbclass