code.vuplus.com Git - vuplus_openembedded/blob - packages/glibc/glibc-initial.inc

   1 SECTION = "libs"
   2 DEPENDS = "linux-libc-headers"
   3 PROVIDES = "virtual/${TARGET_PREFIX}libc-initial"
   4 FILESPATH = "${@base_set_filespath([ '${FILE_DIRNAME}/glibc-2.4', '${FILE_DIRNAME}/glibc', '${FILE_DIRNAME}/files', '${FILE_DIRNAME}' ], d)}"
   5
   6 PACKAGES = ""
   7 PACKAGES_DYNAMIC = ""
   8
   9 do_configure () {
  10         sed -ie 's,{ (exit 1); exit 1; }; },{ (exit 0); }; },g' ${S}/configure
  11         chmod +x ${S}/configure
  12         CC="${BUILD_CC}" CPP="${BUILD_CPP}" LD="${BUILD_LD}" ${S}/configure --host=${TARGET_SYS} --build=${BUILD_SYS} \
  13                 --without-cvs --disable-sanity-checks \
  14                 --with-headers=${STAGING_DIR_TARGET}${layout_includedir} \
  15                 --enable-hacker-mode
  16         if grep -q GLIBC_2.3 ${S}/ChangeLog; then
  17                 # glibc-2.3.x passes cross options to $(CC) when generating errlist-compat.c, which fails without a real cross-compiler.
  18                 # Fortunately, we don't need errlist-compat.c, since we just need .h files,
  19                 # so work around this by creating a fake errlist-compat.c and satisfying its dependencies.
  20                 # Another workaround might be to tell configure to not use any cross options to $(CC).
  21                 # The real fix would be to get install-headers to not generate errlist-compat.c.
  22                 make sysdeps/gnu/errlist.c
  23                 mkdir -p stdio-common
  24                 touch stdio-common/errlist-compat.c
  25         fi
  26 }
  27
  28 do_compile () {
  29         :
  30 }
  31
  32 do_stage () {
  33         oe_runmake cross-compiling=yes install_root=${STAGING_DIR_HOST} includedir='${layout_includedir}' prefix='${layout_prefix}' install-headers
  34
  35         # Two headers -- stubs.h and features.h -- aren't installed by install-headers,
  36         # so do them by hand.  We can tolerate an empty stubs.h for the moment.
  37         # See e.g. http://gcc.gnu.org/ml/gcc/2002-01/msg00900.html
  38         mkdir -p ${STAGING_INCDIR}/gnu
  39         touch ${STAGING_INCDIR}/gnu/stubs.h
  40         cp ${S}/include/features.h ${STAGING_INCDIR}/features.h
  41
  42         if [ -e ${B}/bits/stdio_lim.h ]; then
  43                 cp ${B}/bits/stdio_lim.h  ${STAGING_INCDIR}/bits/
  44         fi
  45 }
  46
  47 do_install () {
  48         :
  49 }