code.vuplus.com Git - vuplus_openembedded/blob - packages/gcc/gcc_3.3.4.bb

   1 SECTION = "devel"
   2 PR = "r3"
   3 inherit autotools gettext
   4
   5 DESCRIPTION = "The GNU cc and gcc C compilers."
   6 HOMEPAGE = "http://www.gnu.org/software/gcc/"
   7 LICENSE = "GPL"
   8
   9 # libgcc libstdc++ libg2c are listed in our FILES_*, but are actually
  10 # packaged in the respective cross packages.
  11 PACKAGES = "${PN} ${PN}-symlinks \
  12             ${PN}-c++ ${PN}-c++-symlinks \
  13             ${PN}-f77 ${PN}-f77-symlinks \
  14             libstdc++-dev libg2c-dev \
  15             ${PN}-doc"
  16
  17 FILES_${PN} = "${bindir}/${TARGET_PREFIX}gcc \
  18                ${bindir}/${TARGET_PREFIX}cpp \
  19                ${bindir}/${TARGET_PREFIX}gcov \
  20                ${bindir}/${TARGET_PREFIX}gccbug \
  21                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/cc1 \
  22                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/collect2 \
  23                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/crt* \
  24                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/specs \
  25                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/lib* \
  26                ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/include"
  27
  28 FILES_${PN}-symlinks = "${bindir}/cc \
  29                         ${bindir}/gcc \
  30                         ${bindir}/cpp \
  31                         ${bindir}/gcov \
  32                         ${bindir}/gccbug"
  33
  34 FILES_${PN}-c++ = "${bindir}/${TARGET_PREFIX}g++ \
  35                    ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/cc1plus"
  36
  37 FILES_${PN}-c++-symlinks = "${bindir}/c++ \
  38                             ${bindir}/g++"
  39
  40 FILES_libgcc = "/lib/libgcc_s.so.*"
  41
  42 # Called from within gcc-cross, so libdir is set wrong
  43 #FILES_libstdc++ = "${libdir}/libstdc++.so.*"
  44 FILES_libstdc++ = "${libdir}/libstdc++.so.*"
  45
  46 FILES_libstdc++-dev = "${includedir}/c++/${PV} \
  47                        ${libdir}/libstdc++.so \
  48                        ${libdir}/libstdc++.la \
  49                        ${libdir}/libstdc++.a \
  50                        ${libdir}/libsupc++.la \
  51                        ${libdir}/libsupc++.a"
  52
  53 FILES_${PN}-doc = "${infodir} \
  54                    ${mandir} \
  55                    ${libdir}/gcc-lib/${TARGET_SYS}/${PV}/include/README"
  56
  57 SRC_URI = "${GNU_MIRROR}/gcc/releases/gcc-${PV}/gcc-${PV}.tar.bz2 \
  58            file://arm-gotoff.dpatch;patch=1;pnum=0 \
  59            file://arm-ldm.dpatch;patch=1;pnum=0 \
  60            file://arm-tune.patch;patch=1;pnum=0 \
  61            file://arm-ldm-peephole.patch;patch=1;pnum=0 \
  62            file://libibery-crosstool.patch;patch=1;pnum=1 \
  63            file://reverse-compare.patch;patch=1 \
  64            file://gcc34-15089.patch;patch=1 \
  65            file://gcc-uclibc-3.3-100-conf.patch;patch=1 \
  66            file://gcc-uclibc-3.3-110-conf.patch;patch=1 \
  67            file://gcc-uclibc-3.3-120-softfloat.patch;patch=1 \
  68            file://gcc-uclibc-3.3-200-code.patch;patch=1 \
  69            file://zecke-xgcc-cpp.patch;patch=1 \
  70            file://gcc-com.patch;patch=1 \
  71            file://bash3.patch;patch=1"
  72
  73 PREMIRRORS_prepend () {
  74 ${GNU_MIRROR}/gcc/releases/     ftp://gcc.gnu.org/pub/gcc/releases/
  75 ${GNU_MIRROR}/gcc/releases/     http://gcc.get-software.com/releases/
  76 }
  77
  78 S = "${WORKDIR}/gcc-${PV}"
  79 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  80
  81 EXTRA_OECONF = "${@['--enable-clocale=generic', ''][bb.data.getVar('USE_NLS', d, 1) != 'no']} \
  82                 --with-gnu-ld \
  83                 --enable-shared \
  84                 --enable-multilib \
  85                 --enable-target-optspace \
  86                 --enable-languages=c,c++,f77 \
  87                 --enable-threads=posix \
  88                 --enable-c99 \
  89                 --enable-long-long \
  90                 --enable-symvers=gnu \
  91                 --program-prefix=${TARGET_PREFIX} \
  92                 ${EXTRA_OECONF_PATHS} \
  93                 ${EXTRA_OECONF_DEP}"
  94
  95 EXTRA_OECONF_PATHS = "--with-local-prefix=${prefix}/local \
  96                       --with-gxx-include-dir=${includedir}/c++/${PV}"
  97
  98 EXTRA_OECONF_DEP = ""
  99 EXTRA_OECONF_uclibc = "--disable-__cxa_atexit"
 100 EXTRA_OECONF_glibc = "--enable-__cxa_atexit"
 101 EXTRA_OECONF += "${@get_gcc_fpu_setting(bb, d)}"
 102
 103 require gcc-fpu.inc
 104
 105 python __anonymous () {
 106     import bb, re
 107     if (re.match('linux-uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None):
 108         bb.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_uclibc}', d)
 109     elif (re.match('linux$', bb.data.getVar('TARGET_OS', d, 1)) != None):
 110         bb.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_glibc}', d)
 111 }
 112
 113 do_configure () {
 114         # Setup these vars for cross building only
 115         if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
 116                 export CC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
 117                 export GCC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
 118                 export CXX_FOR_TARGET="${CCACHE} ${HOST_PREFIX}g++"
 119                 export AS_FOR_TARGET="${HOST_PREFIX}as"
 120                 export LD_FOR_TARGET="${HOST_PREFIX}ld"
 121                 export NM_FOR_TARGET="${HOST_PREFIX}nm"
 122                 export AR_FOR_TARGET="${HOST_PREFIX}ar"
 123                 export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
 124         fi
 125         (cd ${S} && gnu-configize) || die "failure running gnu-configize"
 126         oe_runconf
 127 }
 128
 129 do_install () {
 130         autotools_do_install
 131
 132         # Cleanup some of the gcc-lib stuff
 133         rm -rf ${D}${libdir}/gcc-lib/${TARGET_SYS}/${PV}/install-tools
 134
 135         # Move libgcc_s into /lib
 136         mkdir -p ${D}${base_libdir}
 137         mv -f ${D}${libdir}/libgcc_s.so.* ${D}${base_libdir}
 138         rm -f ${D}${libdir}/libgcc_s.so
 139         ln -sf `echo ${libdir}/gcc-lib/${TARGET_SYS}/${PV} | tr -s / |
 140                 sed -e 's,^/,,' -e 's,[^/]*,..,g'`/lib/libgcc_s.so.? \
 141                 ${D}${libdir}/gcc-lib/${TARGET_SYS}/${PV}/libgcc_s.so
 142
 143         # Cleanup manpages..
 144         rm -rf ${D}${mandir}/man7
 145         mv ${D}${mandir}/man1/cpp.1 \
 146            ${D}${mandir}/man1/${TARGET_SYS}-cpp.1
 147         mv ${D}${mandir}/man1/gcov.1 \
 148            ${D}${mandir}/man1/${TARGET_SYS}-gcov.1
 149
 150         # We use libiberty from binutils
 151         rm -f ${D}${libdir}/libiberty.a
 152
 153         cd ${D}${bindir}
 154
 155         # We care about g++ not c++
 156         rm -f *c++
 157
 158         # We don't care about the gcc-<version> ones for this
 159         rm -f *gcc-?.?*
 160
 161         # These sometimes show up, they are strange, we remove them
 162         rm -f ${TARGET_ARCH}-*${TARGET_ARCH}-*
 163
 164         # Symlinks so we can use these trivially on the target
 165         ln -sf ${TARGET_SYS}-g77 g77
 166         ln -sf ${TARGET_SYS}-g++ g++
 167         ln -sf ${TARGET_SYS}-gcc gcc
 168         ln -sf g77 f77
 169         ln -sf g++ c++
 170         ln -sf gcc cc
 171 }