code.vuplus.com Git - vuplus_openembedded/blob - packages/gcc/gcc-package-sdk.inc

   1 INHIBIT_PACKAGE_STRIP ?= ""
   2 OLD_INHIBIT_PACKAGE_STRIP := "${INHIBIT_PACKAGE_STRIP}"
   3 INHIBIT_PACKAGE_STRIP = "1"
   4
   5 # Having anything auto depending on gcc-cross-sdk is a really bad idea...
   6 EXCLUDE_FROM_SHLIBS = "1"
   7
   8 PACKAGES = "${PN} ${PN}-doc"
   9
  10 FILES_${PN} = "\
  11     ${bindir}/* \
  12     ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/cc1${EXEEXT} \
  13     ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/collect2${EXEEXT} \
  14     ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/f771${EXEEXT} \
  15     ${libexecdir}/gcc/${TARGET_SYS}/${BINV}/cc1plus${EXEEXT} \
  16     ${gcclibdir}/${TARGET_SYS}/${BINV}/*.o \
  17     ${gcclibdir}/${TARGET_SYS}/${BINV}/specs \
  18     ${gcclibdir}/${TARGET_SYS}/${BINV}/lib* \
  19     ${gcclibdir}/${TARGET_SYS}/${BINV}/include* \
  20     ${includedir}/c++/${BINV} \
  21     ${prefix}/${TARGET_SYS}/bin/* \
  22     ${prefix}/${TARGET_SYS}/lib/* \
  23     ${prefix}/${TARGET_SYS}/usr/include/* \
  24     "
  25 FILES_${PN}-doc = "\
  26     ${infodir} \
  27     ${mandir} \
  28     ${gcclibdir}/${TARGET_SYS}/${BINV}/include/README \
  29     "
  30
  31 do_install () {
  32         oe_runmake 'DESTDIR=${D}' install
  33
  34         # Cleanup some of the ${libdir}{,exec}/gcc stuff ...
  35         rm -r ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/install-tools
  36         rm -r ${D}${libexecdir}/gcc/${TARGET_SYS}/${BINV}/install-tools
  37
  38         # We care about g++ not c++
  39         rm -f ${D}${bindir}/*c++${EXEEXT}
  40
  41         # We don't care about the gcc-<version> copies
  42         rm -f ${D}${bindir}/*gcc-?.?*${EXEEXT}
  43
  44         # We use libiberty from binutils
  45         rm -f ${D}${prefix}/${TARGET_SYS}/lib/libiberty.a
  46         rm -f ${D}${libdir}/libiberty.a
  47
  48         # Create the ${prefix}/${TARGET_SYS}/bin/* symlinks
  49         install -d ${D}${prefix}/${TARGET_SYS}/bin/
  50         for l in ${D}${bindir}/*; do
  51                 ln -sf "${bindir}/`basename $l`" "${D}${prefix}/${TARGET_SYS}/bin/`basename $l | sed -e 's,${TARGET_PREFIX},,'`"
  52         done
  53         ln -sf "${bindir}/${TARGET_PREFIX}gcc${EXEEXT}" "${D}${prefix}/${TARGET_SYS}/bin/cc${EXEEXT}"
  54
  55         # Manually run the target stripper since we won't get it run by
  56         # the packaging.
  57         if [ "x${OLD_INHIBIT_PACKAGE_STRIP}" != "x1" ]; then
  58                 ${TARGET_PREFIX}strip ${D}${prefix}/${TARGET_SYS}/lib/libstdc++.so.*
  59                 ${TARGET_PREFIX}strip ${D}${prefix}/${TARGET_SYS}/lib/libg2c.so.* || true
  60                 ${TARGET_PREFIX}strip ${D}${prefix}/${TARGET_SYS}/lib/libgcc_s.so.*
  61         fi
  62 }